Kubernetes custom scheduler interface. Built on top of Reconciler.

The only function that needs to be implemented is select_node_for_pod/2. All others defined by behaviour have default implementations.

Examples

Will schedule each unschedule pod with spec.schedulerName=cheap-node to a node with a label cheap=true. nodes is a stream that can be lazily filtered:

defmodule CheapNodeScheduler do
  use Bonny.Server.Scheduler, name: "cheap-node"

  @impl Bonny.Server.Scheduler
  def select_node_for_pod(_pod, nodes) do
    nodes
    |> Stream.filter(fn(node) ->
      is_cheap = K8s.Resource.label(node, "cheap")
      is_cheap == "true"
    end)
    |> Enum.take(1)
    |> List.first
  end
end

CheapNodeScheduler.start_link()

Will schedule each unschedule pod with spec.schedulerName=random-node to a random node:

defmodule RandomNodeScheduler do
  use Bonny.Server.Scheduler, name: "random-node"

  @impl Bonny.Server.Scheduler
  def select_node_for_pod(_pod, nodes) do
    Enum.random(nodes)
  end
end

RandomNodeScheduler.start_link()

Override nodes/0 default implementation (pods/0 can be overridden too). Schedules pod on a random GPU node:

defmodule GpuScheduler do
  use Bonny.Server.Scheduler, name: "gpu-node"

  @impl Bonny.Server.Scheduler
  def select_node_for_pod(_pod, nodes) do
    Enum.random(nodes)
  end

  @impl Bonny.Server.Scheduler
  def nodes() do
    label = "my.label.on.gpu.instances"
    conn = Bonny.Config.conn()

    op = K8s.Client.list("v1", :nodes)
    K8s.Client.stream(conn, op, params: %{labelSelector: label})
  end
end

GpuScheduler.start_link()