Specifies a provider API that loads configuration during boot.

Config providers are typically used during releases to load external configuration while the system boots. This is done by starting the VM with the minimum amount of applications running, then invoking all of the providers, and then restarting the system. This requires a mutable configuration file on disk, as the results of the providers are written to the file system. For more information on runtime configuration, see mix release.

Multiple config files

One common use of config providers is to specify multiple configuration files in a release. Elixir ships with one provider, called Config.Reader, which is capable of handling Elixir's built-in config files.

For example, imagine you want to list some basic configuration on Mix's built-in config/runtime.exs file, but you also want some additional configuration files. To do so, you can do this in your mix.exs:

releases: [
  demo: [
    config_providers: [
      {Config.Reader, {:system, "RELEASE_ROOT", "/extra_config.exs"}}
    ]
  ]
]

You can place this extra_config.exs file in your release in multiple ways:

1. If it is available on the host when assembling the release, you can place it on "rel/overlays/extra_config.exs" and it will be automatically copied to the release root

2. If it is available on the target during deployment, you can simply copy it to the release root as a step in your deployment

Now once the system boots, it will load both config/runtime.exs and extra_config.exs early in the boot process.

Custom config provider

You can also implement custom config providers, similar to how Config.Reader works. For example, imagine you need to load some configuration from a JSON file and load that into the system. Said configuration provider would look like:

defmodule JSONConfigProvider do
  @behaviour Config.Provider

  # Let's pass the path to the JSON file as config
  def init(path) when is_binary(path), do: path

  def load(config, path) do
    # We need to start any app we may depend on.
    {:ok, _} = Application.ensure_all_started(:jason)

    json = path |> File.read!() |> Jason.decode!()

    Config.Reader.merge(
      config,
      my_app: [
        some_value: json["my_app_some_value"],
        another_value: json["my_app_another_value"],
      ]
    )
  end
end

Then, when specifying your release, you can specify the provider in the release configuration:

releases: [
  demo: [
    config_providers: [
      {JSONConfigProvider, "/etc/config.json"}
    ]
  ]
]