A DSL to define a routing algorithm that works with Plug.

It provides a set of macros to generate routes. For example:

defmodule AppRouter do
  use Plug.Router

  plug :match
  plug :dispatch

  get "/hello" do
    send_resp(conn, 200, "world")
  end

  match _ do
    send_resp(conn, 404, "oops")
  end
end

Each route receives a conn variable containing a Plug.Conn struct and it needs to return a connection, as per the Plug spec. A catch-all match is recommended to be defined as in the example above, otherwise routing fails with a function clause error.

The router is itself a plug, which means it can be invoked as:

AppRouter.call(conn, AppRouter.init([]))

Each Plug.Router has a plug pipeline, defined by Plug.Builder, and by default it requires two plugs: :match and :dispatch. :match is responsible for finding a matching route which is then forwarded to :dispatch. This means users can easily hook into the router mechanism and add behaviour before match, before dispatch, or after both. All of the options given to use Plug.Router are forwarded to Plug.Builder. See the Plug.Builder module for more information on the plug macro and on the available options.

Routes

get "/hello" do
  send_resp(conn, 200, "world")
end

In the example above, a request will only match if it is a GET request and the route is "/hello". The supported HTTP methods are get, post, put, patch, delete and options.

A route can also specify parameters which will then be available in the function body:

get "/hello/:name" do
  send_resp(conn, 200, "hello #{name}")
end

The :name parameter will also be available in the function body as conn.params["name"] and conn.path_params["name"].

Routes allow for globbing which will match the remaining parts of a route and can be available as a parameter in the function body. Also note that a glob can't be followed by other segments:

get "/hello/*_rest" do
  send_resp(conn, 200, "matches all routes starting with /hello")
end

get "/hello/*glob" do
  send_resp(conn, 200, "route after /hello: #{inspect glob}")
end

Finally, a general match function is also supported:

match "/hello" do
  send_resp(conn, 200, "world")
end

A match will match any route regardless of the HTTP method. Check match/3 for more information on how route compilation works and a list of supported options.

Parameter Parsing

Handling request data can be done through the Plug.Parsers plug. It provides support for parsing URL-encoded, form-data, and JSON data as well as providing a behaviour that others parsers can adopt.

Here is an example of Plug.Parsers can be used in a Plug.Router router to parse the JSON-encoded body of a POST request:

defmodule AppRouter do
  use Plug.Router

  plug :match
  plug Plug.Parsers, parsers: [:json],
                     pass:  ["application/json"],
                     json_decoder: Jason
  plug :dispatch

  post "/hello" do
    IO.inspect conn.body_params # Prints JSON POST body
    send_resp(conn, 200, "Success!")
  end
end

It is important that Plug.Parsers is placed before the :dispatch plug in the pipeline, otherwise the matched clause route will not receive the parsed body in its Plug.Conn argument when dispatched.

Plug.Parsers can also be plugged between :match and :dispatch (like in the example above): this means that Plug.Parsers will run only if there is a matching route. This can be useful to perform actions such as authentication before parsing the body, which should only be parsed if a route matches afterwards.

Error handling

In case something goes wrong in a request, the router by default will crash, without returning any response to the client. This behaviour can be configured in two ways, by using two different modules:

• Plug.ErrorHandler - allows the developer to customize exactly which page is sent to the client via the handle_errors/2 function;

• Plug.Debugger - automatically shows debugging and request information about the failure. This module is recommended to be used only in a development environment.

Here is an example of how both modules could be used in an application:

defmodule AppRouter do
  use Plug.Router

  if Mix.env == :dev do
    use Plug.Debugger
  end

  use Plug.ErrorHandler

  plug :match
  plug :dispatch

  get "/hello" do
    send_resp(conn, 200, "world")
  end

  defp handle_errors(conn, %{kind: _kind, reason: _reason, stack: _stack}) do
    send_resp(conn, conn.status, "Something went wrong")
  end
end

Passing data between routes and plugs

It is also possible to assign data to the Plug.Conn that will be available to any plug invoked after the :match plug. This is very useful if you want a matched route to customize how later plugs will behave.

You can use :assigns (which contains user data) or :private (which contains library/framework data) for this. For example:

get "/hello", assigns: %{an_option: :a_value} do
  send_resp(conn, 200, "world")
end

In the example above, conn.assigns[:an_option] will be available to all plugs invoked after :match. Such plugs can read from conn.assigns (or conn.private) to configure their behaviour based on the matched route.

Routes compilation

All routes are compiled to a match function that receives three arguments: the method, the request path split on / and the connection. Consider this example:

match "/foo/bar", via: :get do
  send_resp(conn, 200, "hello world")
end

It is compiled to:

defp match("GET", ["foo", "bar"], conn) do
  send_resp(conn, 200, "hello world")
end

This means guards can be given to match:

match "/foo/bar/:baz" when size(baz) <= 3, via: :get do
  send_resp(conn, 200, "hello world")
end

After a match is found, the block given as do/end is stored as a function in the connection. This function is then retrieved and invoked in the dispatch plug.

Routes options

Sometimes you may want to customize how a route behaves during dispatch. This can be done by accessing the opts variable inside the route:

defmodule AppRouter do
  use Plug.Router

  plug :match
  plug :dispatch, content: "hello world"

  get "/hello" do
    send_resp(conn, 200, opts[:content])
  end

  match _ do
    send_resp(conn, 404, "oops")
  end
end

This is particularly useful when used with Plug.Builder.builder_opts/0. builder_opts/0 allows us to pass options received when initializing AppRouter to a specific plug, such as dispatch itself. So if instead of:

plug :dispatch, content: "hello world"

we do:

plug :dispatch, builder_opts()

now the content can be given when starting the router, like this:

Plug.Cowboy.http AppRouter, [content: "hello world"]

Or as part of a pipeline like this:

plug AppRouter, content: "hello world"

In a nutshell, builder_opts() allows us to pass the options given when initializing the router to a dispatch.

Telemetry

The router emits the following telemetry events:

• [:plug, :router_dispatch, :start] - dispatched before dispatching to a matched route

  • Measurement: %{system_time: System.system_time}
  • Metadata: %{conn: Plug.Conn.t, route: binary, router: module}

• [:plug, :router_dispatch, :exception] - dispatched after exceptions on dispatching a route

  • Measurement: %{duration: native_time}
  • Metadata: %{conn: Plug.Conn.t, route: binary, router: module}

• [:plug, :router_dispatch, :stop] - dispatched after successfully dispatching a matched route

  • Measurement: %{duration: native_time}
  • Metadata: %{conn: Plug.Conn.t, route: binary, router: module}