Behaviour to define a process manager.

A process manager is responsible for coordinating one or more aggregates. It handles events and dispatches commands in response. Process managers have state that can be used to track which aggregates are being orchestrated.

Use the Commanded.ProcessManagers.ProcessManager macro in your process manager module and implement the callback functions defined in the behaviour:

• interested?/1
• handle/2
• apply/2
• error/3

Example

defmodule ExampleProcessManager do
  use Commanded.ProcessManagers.ProcessManager,
    name: "ExampleProcessManager",
    router: ExampleRouter

  def interested?(%AnEvent{...}) do
    # ...
  end

  def handle(%ExampleProcessManager{...}, %AnEvent{...}) do
    # ...
  end

  def apply(%ExampleProcessManager{...}, %AnEvent{...}) do
    # ...
  end

  def error({:error, failure}, %ExampleCommand{}, _failure_context) do
    # retry, skip, ignore, or stop process manager on error dispatching command
  end
end

Start the process manager (or configure as a worker inside a Supervisor)

{:ok, process_manager} = ExampleProcessManager.start_link()

Error handling

You can define an error/3 callback function to handle any errors returned by commands dispatched from your process manager. The function is passed the command dispatch error (e.g. {:error, :failure}), the failed command, and a failure context. See Commanded.ProcessManagers.FailureContext for details.

Use pattern matching on the error and/or failed command to explicitly handle certain errors or commands. You can choose to retry, skip, ignore, or stop the process manager after a command dispatch error.

The default behaviour, if you don’t provide an error/3 callback, is to stop the process manager using the exact error reason returned from the command dispatch. You should supervise your process managers to ensure they are restarted on error.

Example

defmodule ExampleProcessManager do
  use Commanded.ProcessManagers.ProcessManager,
    name: "ExampleProcessManager",
    router: ExampleRouter

  # stop process manager after three failures
  def error({:error, _failure}, _failed_command, %{context: %{failures: failures}})
    when failures >= 2
  do
    {:stop, :too_many_failures}
  end

  # retry command, record failure count in context map
  def error({:error, _failure}, _failed_command, %{context: context}) do
    context = Map.update(context, :failures, 1, fn failures -> failures + 1 end)

    {:retry, context}
  end
end

Consistency

For each process manager you can define its consistency, as one of either :strong or :eventual.

This setting is used when dispatching commands and specifying the consistency option.

When you dispatch a command using :strong consistency, after successful command dispatch the process will block until all process managers configured to use :strong consistency have processed the domain events created by the command.

The default setting is :eventual consistency. Command dispatch will return immediately upon confirmation of event persistence, not waiting for any process managers.

Example

defmodule ExampleProcessManager do
  use Commanded.ProcessManagers.ProcessManager,
    name: "ExampleProcessManager",
    router: BankRouter
    consistency: :strong

  # ...
end

Please read the Process managers guide for more details.