The Command macro allows you to define a command that encapsulates a struct definition, data validation, dependency validation, and dispatching of the command.

Options

• require_all_fields (:boolean) - If true, all fields will be required. Defaults to true
• dispatcher (:atom) - A module that defines a dispatch/2.
• default_event_values (:boolean) - If true, events created using derive_event/1 or derive_event/2, will inherit default values from their command fields. Defaults to true.

Examples

defmodule CreateUser do
  use Cqrs.Command

  field :email, :string
  field :name, :string

  internal_field :id, :binary_id

  @impl true
  def handle_validate(command, _opts) do
    Ecto.Changeset.validate_format(command, :email, ~r/@/)
  end

  @impl true
  def after_validate(%{email: email} = command) do
    Map.put(command, :id, UUID.uuid5(:oid, email))
  end

  @impl true
  def handle_dispatch(_command, _opts) do
    {:ok, :dispatched}
  end
end

Creation

iex> {:error, errors} = CreateUser.new()
...> errors
%{email: ["can't be blank"], name: ["can't be blank"]}

iex> {:ok, %CreateUser{email: email, name: name, id: id}} = CreateUser.new(email: "chris@example.com", name: "chris")
...> %{email: email, name: name, id: id}
%{email: "chris@example.com", id: "052c1984-74c9-522f-858f-f04f1d4cc786", name: "chris"}

iex> %CreateUser{id: "052c1984-74c9-522f-858f-f04f1d4cc786"} = CreateUser.new!(email: "chris@example.com", name: "chris")

Dispatching

iex> {:error, {:invalid_command, errors}} =
...> CreateUser.new(name: "chris", email: "wrong")
...> |> CreateUser.dispatch()
...> errors
%{email: ["has invalid format"]}

iex> CreateUser.new(name: "chris", email: "chris@example.com")
...> |> CreateUser.dispatch()
{:ok, :dispatched}

Event derivation

You can derive events directly from a command.

see derive_event/2

defmodule DeactivateUser do
  use Cqrs.Command

  field :id, :binary_id

  derive_event UserDeactivated
end

Usage with Commanded

defmodule Commanded.Application do
  use Commanded.Application,
    otp_app: :my_app,
    default_dispatch_opts: [
      consistency: :strong,
      returning: :execution_result
    ],
    event_store: [
      adapter: Commanded.EventStore.Adapters.EventStore,
      event_store: MyApp.EventStore
    ]
end

defmodule DeactivateUser do
  use Cqrs.Command, dispatcher: Commanded.Application

  field :id, :binary_id

  derive_event UserDeactivated
end

iex> {:ok, event} = DeactivateUser.new(id: "052c1984-74c9-522f-858f-f04f1d4cc786")
...> |> DeactivateUser.dispatch()
...>  %{id: event.id, version: event.version}
%{id: "052c1984-74c9-522f-858f-f04f1d4cc786", version: 1}