Ecto.Schema

Defines a schema for a model.

A schema is a struct with associated metadata that is persisted to a repository. Every schema model is also a struct, that means that you work with models just like you would work with structs.

Example

defmodule User do
  use Ecto.Schema

  schema "users" do
    field :name, :string
    field :age, :integer, default: 0
    has_many :posts, Post
  end
end

By default, a schema will generate both a primary key named id of type :integer and belongs_to associations will generate foreign keys of type :integer too. Those setting can be configured below.

Schema attributes

The schema supports some attributes to be set before hand, configuring the defined schema.

Those attributes are:

The advantage of defining configure the schema via those attributes is that they can be set with a macro to configure application wide defaults. For example, if you would like to use uuid's in all of your application models, you can do:

# Define a module to be used as base
defmodule MyApp.Model do
  defmacro __using__(_) do
    quote do
      use Ecto.Model
      @primary_key {:id, :uuid, []}
      @foreign_key_type :uuid
    end
  end
end

# Now use MyApp.Model to define new models
defmodule MyApp.Comment do
  use MyApp.Model

  schema "comments" do
    belongs_to :post, MyApp.Post
  end
end

Any models using MyApp.Model will get the :id field with type :uuid as primary key.

The belongs_to association on MyApp.Comment will also define a :post_id field with :uuid type that references the :id of the MyApp.Post model.

Types and casting

When defining the schema, types need to be given. Types are split in two categories, primitive types and custom types.

Primitive types

The primitive types are:

Ecto type Elixir type Literal syntax in query
:integer integer 1, 2, 3
:float float 1.0, 2.0, 3.0
:boolean boolean true, false
:string UTF-8 encoded string "hello"
:binary binary <<int, int, int, ...>>
:uuid 16 byte binary uuid(binary_or_string)
{:array, inner_type} list [value, value, value, ...]
:decimal Decimal
:datetime {{year, month, day}, {hour, min, sec}}
:date {year, month, day}
:time {hour, min, sec}

Custom types

Sometimes the primitive types in Ecto are too primitive. For example, :uuid relies on the underling binary representation instead of representing itself as a readable string. That's when Ecto.UUID comes in.

Ecto.UUID is a custom type. A custom type is a module that implements the Ecto.Type behaviour. By default, Ecto provides the following custom types:

Custom type Ecto type Elixir type
Ecto.UUID :uuid "uuid-string"
Ecto.DateTime :datetime %Ecto.DateTime{}
Ecto.Date :date %Ecto.Date{}
Ecto.Time :time %Ecto.Time{}

Ecto allow developers to provide their own types too. Read the Ecto.Type documentation for more information.

Casting

When directly manipulating the struct, it is the responsibility of the developer to ensure the field values have the proper type. For example, you can create a weather struct with an invalid value for temp_lo:

iex> weather = %Weather{temp_lo: "0"}
iex> weather.temp_lo
"0"

However, if you attempt to persist the struct above, an error will be raised since Ecto validates the types when building the query.

Therefore, when working and manipulating external data, it is recommended the usage of Ecto.Changeset's that are able to filter and properly cast external data. In fact, Ecto.Changeset and custom types provide a powerful combination to extend Ecto types and queries.

Finally, models can also have virtual fields by passing the virtual: true option. These fields are not persisted to the database and can optionally not be type checked by declaring type :any.

Reflection

Any schema module will generate the __schema__ function that can be used for runtime introspection of the schema:

Furthermore, both __struct__ and __changeset__ functions are defined so structs and changeset functionalities are available.

Source

Summary

association(name, association, opts \\ [])

Defines an association

belongs_to(name, queryable, opts \\ [])

Indicates a one-to-one association with another model

field(name, type \\ :string, opts \\ [])

Defines a field on the model schema with given name and type

has_many(name, queryable, opts \\ [])

Indicates a one-to-many association with another model

has_one(name, queryable, opts \\ [])

Indicates a one-to-one association with another model

schema(source, list2)

Defines a schema with a source name and field definitions

timestamps(opts \\ [])

Generates :inserted_at and :updated_at timestamp fields

Macros

association(name, association, opts \\ [])

Defines an association.

This macro is used by belongs_to/3, has_one/3 and has_many/3 to define associations. However, custom association mechanisms can be provided by developers and hooked in via this macro.

Read more about custom associations in Ecto.Associations.

Source
belongs_to(name, queryable, opts \\ [])

Indicates a one-to-one association with another model.

The current model belongs to zero or one records of the other model. The other model often has a has_one or a has_many field with the reverse association.

You should use belongs_to in the table that contains the foreign key. Imagine a company <-> manager relationship. If the company contains the manager_id in the underlying database table, we say the company belongs to manager.

In fact, when you invoke this macro, a field with the name of foreign key is automatically defined in the schema for you.

Options

  • :foreign_key - Sets the foreign key field name, defaults to the name of the association suffixed by _id. For example, belongs_to :company will define foreign key of :company_id

  • :references - Sets the key on the other model to be used for the association, defaults to: :id

  • :auto_field - When false, does not automatically define a :foreign_key field, implying the user is defining the field manually elsewhere

  • :type - Sets the type of automtically defined :foreign_key. Defaults to: :integer and be set per schema via @foreign_key_type

All other options are forwarded to the underlying foreign key definition and therefore accept the same options as field/3.

Examples

defmodule Comment do
  use Ecto.Model
  schema "comments" do
    # This automatically defines a post_id field too
    belongs_to :post, Post
  end
end

# The post can come preloaded on the comment record
[comment] = Repo.all(from(c in Comment, where: c.id == 42, preload: :post))
comment.post #=> %Post{...}
Source
field(name, type \\ :string, opts \\ [])

Defines a field on the model schema with given name and type.

Options

  • :default - Sets the default value on the schema and the struct
  • :virtual - When true, the field is not persisted
  • :read_after_writes - When true, the field is always read back from the repository after inserts and updates
Source
has_many(name, queryable, opts \\ [])

Indicates a one-to-many association with another model.

The current model has zero or more records of the other model. The other model often has a belongs_to field with the reverse association.

Options

  • :foreign_key - Sets the foreign key, this should map to a field on the other model, defaults to the underscored name of the current model suffixed by _id

  • :references - Sets the key on the current model to be used for the association, defaults to the primary key on the model

  • :through - If this association must be defined in terms of existing associations. Read below for more information

Examples

defmodule Post do
  use Ecto.Model
  schema "posts" do
    has_many :comments, Comment
  end
end

# Get all comments for a given post
post = Repo.get(Post, 42)
comments = Repo.all assoc(post, :comments)

# The comments can come preloaded on the post struct
[post] = Repo.all(from(p in Post, where: p.id == 42, preload: :comments))
post.comments #=> [%Comment{...}, ...]

hasmany/hasone :through

Ecto also supports defining associations in terms of other associations via the :through option. Let's see an example:

defmodule Post do
  use Ecto.Model
  schema "posts" do
    has_many :comments, Comment
    has_one :permalink, Permalink
    has_many :comments_authors, through: [:comments, :author]
  end
end

defmodule Comment do
  use Ecto.Model
  schema "comments" do
    belongs_to :author, Author
    belongs_to :post, Post
    has_one :post_permalink, through: [:post, :permalink]
  end
end

In the example above, we have defined a has_many :through association named :comments_authors. A :through association always expect a list and the first element of the list must be a previously defined association in the current module. For example, :comments_authors first points to :comments in the same module (Post), which then points to :author in the next model Comment.

This :through associations will return all authors for all comments that belongs to that post:

# Get all comments for a given post
post = Repo.get(Post, 42)
authors = Repo.all assoc(post, :comments_authors)

:through associations are read-only as they are useful to avoid repetition allowing the developer to easily retrieve data that is often seem together but stored across different tables.

:through associations can also be preloaded. In such cases, not only the :through association is preloaded but all intermediate steps are preloaded too:

[post] = Repo.all(from(p in Post, where: p.id == 42, preload: :comments_authors))
post.comments_authors #=> [%Author{...}, ...]

# The comments for each post will be preloaded too
post.comments #=> [%Comment{...}, ...]

# And the author for each comment too
hd(post.comments).authors #=> [%Author{...}, ...]

Finally, :through can be used with multiple associations (not only 2) and with associations of any kind, including belongs_to and others :through associations. When the :through association is expected to return one or no item, has_one :through should be used instead, as in the example at the beginning of this section:

# How we defined the association above
has_one :post_permalink, through: [:post, :permalink]

# Get a preloaded comment
[comment] = Repo.all(Comment) |> Repo.preload(:post_permalink)
comment.post_permalink #=> %Permalink{...}
Source
has_one(name, queryable, opts \\ [])

Indicates a one-to-one association with another model.

The current model has zero or one records of the other model. The other model often has a belongs_to field with the reverse association.

Options

  • :foreign_key - Sets the foreign key, this should map to a field on the other model, defaults to the underscored name of the current model suffixed by _id

  • :references - Sets the key on the current model to be used for the association, defaults to the primary key on the model

  • :through - If this association must be defined in terms of existing associations. Read the section in has_many/3 for more information

Examples

defmodule Post do
  use Ecto.Model
  schema "posts" do
    has_one :permalink, Permalink
  end
end

# The permalink can come preloaded on the post struct
[post] = Repo.all(from(p in Post, where: p.id == 42, preload: :permalink))
post.permalink #=> %Permalink{...}
Source
schema(source, list2)

Defines a schema with a source name and field definitions.

Source
timestamps(opts \\ [])

Generates :inserted_at and :updated_at timestamp fields.

When using Ecto.Model, the fields generated by this macro will automatically be set to the current time when inserting and updating values in a repository.

Options

  • :type - the timestamps type, defaults to Ecto.DateTime. Can also be set via the @timestamps_type attribute
  • :inserted_at - the name of the column for insertion times or false
  • :updated_at - the name of the column for update times or false
Source