Elixir

v1.7.4

Elixir

Elixir v1.7.4 GenServer behaviour View Source

A behaviour module for implementing the server of a client-server relation.

A GenServer is a process like any other Elixir process and it can be used to keep state, execute code asynchronously and so on. The advantage of using a generic server process (GenServer) implemented using this module is that it will have a standard set of interface functions and include functionality for tracing and error reporting. It will also fit into a supervision tree.

Example

The GenServer behaviour abstracts the common client-server interaction. Developers are only required to implement the callbacks and functionality they are interested in.

Let’s start with a code example and then explore the available callbacks. Imagine we want a GenServer that works like a stack, allowing us to push and pop items:

defmodule Stack do
  use GenServer

  # Callbacks

  @impl true
  def init(stack) do
    {:ok, stack}
  end

  @impl true
  def handle_call(:pop, _from, [head | tail]) do
    {:reply, head, tail}
  end

  @impl true
  def handle_cast({:push, item}, state) do
    {:noreply, [item | state]}
  end
end

# Start the server
{:ok, pid} = GenServer.start_link(Stack, [:hello])

# This is the client
GenServer.call(pid, :pop)
#=> :hello

GenServer.cast(pid, {:push, :world})
#=> :ok

GenServer.call(pid, :pop)
#=> :world

We start our Stack by calling start_link/2, passing the module with the server implementation and its initial argument (a list representing the stack containing the item :hello). We can primarily interact with the server by sending two types of messages. call messages expect a reply from the server (and are therefore synchronous) while cast messages do not.

Every time you do a GenServer.call/3, the client will send a message that must be handled by the handle_call/3 callback in the GenServer. A cast/2 message must be handled by handle_cast/2.

Client / Server APIs

Although in the example above we have used GenServer.start_link/3 and friends to directly start and communicate with the server, most of the time we don’t call the GenServer functions directly. Instead, we wrap the calls in new functions representing the public API of the server.

Here is a better implementation of our Stack module:

defmodule Stack do
  use GenServer

  # Client

  def start_link(default) when is_list(default) do
    GenServer.start_link(__MODULE__, default)
  end

  def push(pid, item) do
    GenServer.cast(pid, {:push, item})
  end

  def pop(pid) do
    GenServer.call(pid, :pop)
  end

  # Server (callbacks)

  @impl true
  def init(stack) do
    {:ok, stack}
  end

  @impl true
  def handle_call(:pop, _from, [head | tail]) do
    {:reply, head, tail}
  end

  @impl true
  def handle_cast({:push, item}, state) do
    {:noreply, [item | state]}
  end
end

In practice, it is common to have both server and client functions in the same module. If the server and/or client implementations are growing complex, you may want to have them in different modules.

use GenServer and callbacks

There are 7 callbacks to be implemented when you use a GenServer. The only required callback is init/1.

use GenServer also defines a child_spec/1 function, allowing the defined module to be put under a supervision tree. The generated child_spec/1 can be customized with the following options:

  • :id - the child specification identifier, defaults to the current module
  • :start - how to start the child process (defaults to calling __MODULE__.start_link/1)
  • :restart - when the child should be restarted, defaults to :permanent
  • :shutdown - how to shut down the child

For example:

use GenServer, restart: :transient, shutdown: 10_000

See the Supervisor docs for more information.

Name registration

Both start_link/3 and start/3 support the GenServer to register a name on start via the :name option. Registered names are also automatically cleaned up on termination. The supported values are:

  • an atom - the GenServer is registered locally with the given name using Process.register/2.

  • {:global, term} - the GenServer is registered globally with the given term using the functions in the :global module.

  • {:via, module, term} - the GenServer is registered with the given mechanism and name. The :via option expects a module that exports register_name/2, unregister_name/1, whereis_name/1 and send/2. One such example is the :global module which uses these functions for keeping the list of names of processes and their associated PIDs that are available globally for a network of Elixir nodes. Elixir also ships with a local, decentralized and scalable registry called Registry for locally storing names that are generated dynamically.

For example, we could start and register our Stack server locally as follows:

# Start the server and register it locally with name MyStack
{:ok, _} = GenServer.start_link(Stack, [:hello], name: MyStack)

# Now messages can be sent directly to MyStack
GenServer.call(MyStack, :pop) #=> :hello

Once the server is started, the remaining functions in this module (call/3, cast/2, and friends) will also accept an atom, or any {:global, ...} or {:via, ...} tuples. In general, the following formats are supported:

  • a PID
  • an atom if the server is locally registered
  • {atom, node} if the server is locally registered at another node
  • {:global, term} if the server is globally registered
  • {:via, module, name} if the server is registered through an alternative registry

If there is an interest to register dynamic names locally, do not use atoms, as atoms are never garbage-collected and therefore dynamically generated atoms won’t be garbage-collected. For such cases, you can set up your own local registry by using the Registry module.

Receiving “regular” messages

The goal of a GenServer is to abstract the “receive” loop for developers, automatically handling system messages, supporting code change, synchronous calls and more. Therefore, you should never call your own “receive” inside the GenServer callbacks as doing so will cause the GenServer to misbehave.

Besides the synchronous and asynchronous communication provided by call/3 and cast/2, “regular” messages sent by functions such as Kernel.send/2, Process.send_after/4 and similar, can be handled inside the handle_info/2 callback.

handle_info/2 can be used in many situations, such as handling monitor DOWN messages sent by Process.monitor/1. Another use case for handle_info/2 is to perform periodic work, with the help of Process.send_after/4:

defmodule MyApp.Periodically do
  use GenServer

  def start_link do
    GenServer.start_link(__MODULE__, %{})
  end

  @impl true
  def init(state) do
    schedule_work() # Schedule work to be performed on start
    {:ok, state}
  end

  @impl true
  def handle_info(:work, state) do
    # Do the desired work here
    schedule_work() # Reschedule once more
    {:noreply, state}
  end

  defp schedule_work() do
    Process.send_after(self(), :work, 2 * 60 * 60 * 1000) # In 2 hours
  end
end

When (not) to use a GenServer

So far, we have learned that a GenServer can be used as a supervised process that handles sync and async calls. It can also handle system messages, such as periodic messages and monitoring events. GenServer processes may also be named.

A GenServer, or a process in general, must be used to model runtime characteristics of your system. A GenServer must never be used for code organization purposes.

In Elixir, code organization is done by modules and functions, processes are not necessary. For example, imagine you are implementing a calculator and you decide to put all the calculator operations behind a GenServer:

def add(a, b) do
  GenServer.call(__MODULE__, {:add, a, b})
end

def handle_call({:add, a, b}, _from, state) do
  {:reply, a + b, state}
end

def handle_call({:subtract, a, b}, _from, state) do
  {:reply, a - b, state}
end

This is an anti-pattern not only because it convolutes the calculator logic but also because you put the calculator logic behind a single process that will potentially become a bottleneck in your system, especially as the number of calls grow. Instead just define the functions directly:

def add(a, b) do
  a + b
end

def subtract(a, b) do
  a - b
end

If you don’t need a process, then you don’t need a process. Use processes only to model runtime properties, such as mutable state, concurrency and failures, never for code organization.

Debugging with the :sys module

GenServers, as special processes, can be debugged using the :sys module. Through various hooks, this module allows developers to introspect the state of the process and trace system events that happen during its execution, such as received messages, sent replies and state changes.

Let’s explore the basic functions from the :sys module used for debugging:

  • :sys.get_state/2 - allows retrieval of the state of the process. In the case of a GenServer process, it will be the callback module state, as passed into the callback functions as last argument.
  • :sys.get_status/2 - allows retrieval of the status of the process. This status includes the process dictionary, if the process is running or is suspended, the parent PID, the debugger state, and the state of the behaviour module, which includes the callback module state (as returned by :sys.get_state/2). It’s possible to change how this status is represented by defining the optional GenServer.format_status/2 callback.
  • :sys.trace/3 - prints all the system events to :stdio.
  • :sys.statistics/3 - manages collection of process statistics.
  • :sys.no_debug/2 - turns off all debug handlers for the given process. It is very important to switch off debugging once we’re done. Excessive debug handlers or those that should be turned off, but weren’t, can seriously damage the performance of the system.
  • :sys.suspend/2 - allows to suspend a process so that it only replies to system messages but no other messages. A suspended process can be reactivated via :sys.resume/2.

Let’s see how we could use those functions for debugging the stack server we defined earlier.

iex> {:ok, pid} = Stack.start_link([])
iex> :sys.statistics(pid, true) # turn on collecting process statistics
iex> :sys.trace(pid, true) # turn on event printing
iex> Stack.push(pid, 1)
*DBG* <0.122.0> got cast {push,1}
*DBG* <0.122.0> new state [1]
:ok
iex> :sys.get_state(pid)
[1]
iex> Stack.pop(pid)
*DBG* <0.122.0> got call pop from <0.80.0>
*DBG* <0.122.0> sent 1 to <0.80.0>, new state []
1
iex> :sys.statistics(pid, :get)
{:ok,
 [start_time: {{2016, 7, 16}, {12, 29, 41}},
  current_time: {{2016, 7, 16}, {12, 29, 50}},
  reductions: 117, messages_in: 2, messages_out: 0]}
iex> :sys.no_debug(pid) # turn off all debug handlers
:ok
iex> :sys.get_status(pid)
{:status, #PID<0.122.0>, {:module, :gen_server},
 [["$initial_call": {Stack, :init, 1},            # pdict
   "$ancestors": [#PID<0.80.0>, #PID<0.51.0>]],
  :running,                                       # :running | :suspended
  #PID<0.80.0>,                                   # parent
  [],                                             # debugger state
  [header: 'Status for generic server <0.122.0>', # module status
   data: [{'Status', :running}, {'Parent', #PID<0.80.0>},
     {'Logged events', []}], data: [{'State', [1]}]]]}

Learn more

If you wish to find out more about GenServers, the Elixir Getting Started guide provides a tutorial-like introduction. The documentation and links in Erlang can also provide extra insight.

Link to this section Summary

Types

debug()

Debug options supported by the start* functions

from()

Tuple describing the client of a call request

name()

The GenServer name

on_start()

Return values of start* functions

option()

Option values used by the start* functions

options()

Options used by the start* functions

server()

The server reference

Functions

abcast(nodes \\ [node() | Node.list()], name, request)

Casts all servers locally registered as name at the specified nodes

call(server, request, timeout \\ 5000)

Makes a synchronous call to the server and waits for its reply

cast(server, request)

Sends an asynchronous request to the server

multi_call(nodes \\ [node() | Node.list()], name, request, timeout \\ :infinity)

Calls all servers locally registered as name at the specified nodes

reply(client, reply)

Replies to a client

start(module, args, options \\ [])

Starts a GenServer process without links (outside of a supervision tree)

start_link(module, args, options \\ [])

Starts a GenServer process linked to the current process

stop(server, reason \\ :normal, timeout \\ :infinity)

Synchronously stops the server with the given reason

whereis(server)

Returns the pid or {name, node} of a GenServer process, or nil if no process is associated with the given server

Callbacks

code_change(old_vsn, state, extra)

Invoked to change the state of the GenServer when a different version of a module is loaded (hot code swapping) and the state’s term structure should be changed

format_status(reason, pdict_and_state)

Invoked in some cases to retrieve a formatted version of the GenServer status

handle_call(request, from, state)

Invoked to handle synchronous call/3 messages. call/3 will block until a reply is received (unless the call times out or nodes are disconnected)

handle_cast(request, state)

Invoked to handle asynchronous cast/2 messages

handle_continue(continue, state)

Invoked to handle continue instructions

handle_info(msg, state)

Invoked to handle all other messages

init(args)

Invoked when the server is started. start_link/3 or start/3 will block until it returns

terminate(reason, state)

Invoked when the server is about to exit. It should do any cleanup required

Link to this section Types

Link to this type debug() View Source 
debug() :: [:trace | :log | :statistics | {:log_to_file, Path.t()}]

Debug options supported by the start* functions

Link to this type from() View Source 
from() :: {pid(), tag :: term()}

Tuple describing the client of a call request.

pid is the PID of the caller and tag is a unique term used to identify the call.

Link to this type name() View Source 
name() :: atom() | {:global, term()} | {:via, module(), term()}

The GenServer name

Link to this type on_start() View Source 
on_start() ::
  {:ok, pid()} | :ignore | {:error, {:already_started, pid()} | term()}

Return values of start* functions

Link to this type option() View Source 
option() ::
  {:debug, debug()}
  | {:name, name()}
  | {:timeout, timeout()}
  | {:spawn_opt, Process.spawn_opt()}

Option values used by the start* functions

Link to this type options() View Source 
options() :: [option()]

Options used by the start* functions

Link to this type server() View Source 
server() :: pid() | name() | {atom(), node()}

The server reference

Link to this section Functions

Link to this function abcast(nodes \\ [node() | Node.list()], name, request) View Source 
abcast([node()], name :: atom(), term()) :: :abcast

Casts all servers locally registered as name at the specified nodes.

This function returns immediately and ignores nodes that do not exist, or where the server name does not exist.

See multi_call/4 for more information.

Link to this function call(server, request, timeout \\ 5000) View Source 
call(server(), term(), timeout()) :: term()

Makes a synchronous call to the server and waits for its reply.

The client sends the given request to the server and waits until a reply arrives or a timeout occurs. handle_call/3 will be called on the server to handle the request.

server can be any of the values described in the “Name registration” section of the documentation for this module.

Timeouts

timeout is an integer greater than zero which specifies how many milliseconds to wait for a reply, or the atom :infinity to wait indefinitely. The default value is 5000. If no reply is received within the specified time, the function call fails and the caller exits. If the caller catches the failure and continues running, and the server is just late with the reply, it may arrive at any time later into the caller’s message queue. The caller must in this case be prepared for this and discard any such garbage messages that are two-element tuples with a reference as the first element.

Link to this function cast(server, request) View Source 
cast(server(), term()) :: :ok

Sends an asynchronous request to the server.

This function always returns :ok regardless of whether the destination server (or node) exists. Therefore it is unknown whether the destination server successfully handled the message.

handle_cast/2 will be called on the server to handle the request. In case the server is on a node which is not yet connected to the caller one, the call is going to block until a connection happens. This is different than the behaviour in OTP’s :gen_server where the message is sent by another process in this case, which could cause messages to other nodes to arrive out of order.

Link to this function multi_call(nodes \\ [node() | Node.list()], name, request, timeout \\ :infinity) View Source 
multi_call([node()], name :: atom(), term(), timeout()) ::
  {replies :: [{node(), term()}], bad_nodes :: [node()]}

Calls all servers locally registered as name at the specified nodes.

First, the request is sent to every node in nodes; then, the caller waits for the replies. This function returns a two-element tuple {replies, bad_nodes} where:

  • replies - is a list of {node, reply} tuples where node is the node that replied and reply is its reply
  • bad_nodes - is a list of nodes that either did not exist or where a server with the given name did not exist or did not reply

nodes is a list of node names to which the request is sent. The default value is the list of all known nodes (including this node).

To avoid that late answers (after the timeout) pollute the caller’s message queue, a middleman process is used to do the actual calls. Late answers will then be discarded when they arrive to a terminated process.

Examples

Assuming the Stack GenServer mentioned in the docs for the GenServer module is registered as Stack in the :"foo@my-machine" and :"bar@my-machine" nodes:

GenServer.multi_call(Stack, :pop)
#=> {[{:"foo@my-machine", :hello}, {:"bar@my-machine", :world}], []}
Link to this function reply(client, reply) View Source 
reply(from(), term()) :: :ok

Replies to a client.

This function can be used to explicitly send a reply to a client that called call/3 or multi_call/4 when the reply cannot be specified in the return value of handle_call/3.

client must be the from argument (the second argument) accepted by handle_call/3 callbacks. reply is an arbitrary term which will be given back to the client as the return value of the call.

Note that reply/2 can be called from any process, not just the GenServer that originally received the call (as long as that GenServer communicated the from argument somehow).

This function always returns :ok.

Examples 

def handle_call(:reply_in_one_second, from, state) do
  Process.send_after(self(), {:reply, from}, 1_000)
  {:noreply, state}
end

def handle_info({:reply, from}, state) do
  GenServer.reply(from, :one_second_has_passed)
  {:noreply, state}
end
Link to this function start(module, args, options \\ []) View Source 
start(module(), any(), options()) :: on_start()

Starts a GenServer process without links (outside of a supervision tree).

See start_link/3 for more information.

Link to this function start_link(module, args, options \\ []) View Source 
start_link(module(), any(), options()) :: on_start()

Starts a GenServer process linked to the current process.

This is often used to start the GenServer as part of a supervision tree.

Once the server is started, the init/1 function of the given module is called with args as its arguments to initialize the server. To ensure a synchronized start-up procedure, this function does not return until init/1 has returned.

Note that a GenServer started with start_link/3 is linked to the parent process and will exit in case of crashes from the parent. The GenServer will also exit due to the :normal reasons in case it is configured to trap exits in the init/1 callback.

Options

  • :name - used for name registration as described in the “Name registration” section in the documentation for GenServer

  • :timeout - if present, the server is allowed to spend the given number of milliseconds initializing or it will be terminated and the start function will return {:error, :timeout}

  • :debug - if present, the corresponding function in the :sys module is invoked

  • :spawn_opt - if present, its value is passed as options to the underlying process as in Process.spawn/4

Return values

If the server is successfully created and initialized, this function returns {:ok, pid}, where pid is the PID of the server. If a process with the specified server name already exists, this function returns {:error, {:already_started, pid}} with the PID of that process.

If the init/1 callback fails with reason, this function returns {:error, reason}. Otherwise, if it returns {:stop, reason} or :ignore, the process is terminated and this function returns {:error, reason} or :ignore, respectively.

Link to this function stop(server, reason \\ :normal, timeout \\ :infinity) View Source 
stop(server(), reason :: term(), timeout()) :: :ok

Synchronously stops the server with the given reason.

The terminate/2 callback of the given server will be invoked before exiting. This function returns :ok if the server terminates with the given reason; if it terminates with another reason, the call exits.

This function keeps OTP semantics regarding error reporting. If the reason is any other than :normal, :shutdown or {:shutdown, _}, an error report is logged.

Link to this function whereis(server) View Source 
whereis(server()) :: pid() | {atom(), node()} | nil

Returns the pid or {name, node} of a GenServer process, or nil if no process is associated with the given server.

Examples

For example, to lookup a server process, monitor it and send a cast to it:

process = GenServer.whereis(server)
monitor = Process.monitor(process)
GenServer.cast(process, :hello)

Link to this section Callbacks

Link to this callback code_change(old_vsn, state, extra) View Source (optional) 
code_change(old_vsn, state :: term(), extra :: term()) ::
  {:ok, new_state :: term()} | {:error, reason :: term()} | {:down, term()}
when old_vsn: term()

Invoked to change the state of the GenServer when a different version of a module is loaded (hot code swapping) and the state’s term structure should be changed.

old_vsn is the previous version of the module (defined by the @vsn attribute) when upgrading. When downgrading the previous version is wrapped in a 2-tuple with first element :down. state is the current state of the GenServer and extra is any extra data required to change the state.

Returning {:ok, new_state} changes the state to new_state and the code change is successful.

Returning {:error, reason} fails the code change with reason reason and the state remains as the previous state.

If code_change/3 raises the code change fails and the loop will continue with its previous state. Therefore this callback does not usually contain side effects.

This callback is optional.

Link to this callback format_status(reason, pdict_and_state) View Source (optional) 
format_status(reason, pdict_and_state :: list()) :: term()
when reason: :normal | :terminate

Invoked in some cases to retrieve a formatted version of the GenServer status.

This callback can be useful to control the appearance of the status of the GenServer. For example, it can be used to return a compact representation of the GenServer’s state to avoid having large state terms printed.

pdict_and_state is a two-elements list [pdict, state] where pdict is a list of {key, value} tuples representing the current process dictionary of the GenServer and state is the current state of the GenServer.

Link to this callback handle_call(request, from, state) View Source (optional) 
handle_call(request :: term(), from(), state :: term()) ::
  {:reply, reply, new_state}
  | {:reply, reply, new_state, timeout() | :hibernate | {:continue, term()}}
  | {:noreply, new_state}
  | {:noreply, new_state, timeout() | :hibernate, {:continue, term()}}
  | {:stop, reason, reply, new_state}
  | {:stop, reason, new_state}
when reply: term(), new_state: term(), reason: term()

Invoked to handle synchronous call/3 messages. call/3 will block until a reply is received (unless the call times out or nodes are disconnected).

request is the request message sent by a call/3, from is a 2-tuple containing the caller’s PID and a term that uniquely identifies the call, and state is the current state of the GenServer.

Returning {:reply, reply, new_state} sends the response reply to the caller and continues the loop with new state new_state.

Returning {:reply, reply, new_state, timeout} is similar to {:reply, reply, new_state} except handle_info(:timeout, new_state) will be called after timeout milliseconds if no messages are received.

Returning {:reply, reply, new_state, :hibernate} is similar to {:reply, reply, new_state} except the process is hibernated and will continue the loop once a message is in its message queue. If a message is already in the message queue this will be immediately. Hibernating a GenServer causes garbage collection and leaves a continuous heap that minimises the memory used by the process.

Returning {:reply, reply, new_state, {:continue, continue}} is similar to {:reply, reply, new_state} except handle_continue/2 will be invoked immediately after with the value continue as first argument.

Hibernating should not be used aggressively as too much time could be spent garbage collecting. Normally it should only be used when a message is not expected soon and minimising the memory of the process is shown to be beneficial.

Returning {:noreply, new_state} does not send a response to the caller and continues the loop with new state new_state. The response must be sent with reply/2.

There are three main use cases for not replying using the return value:

  • To reply before returning from the callback because the response is known before calling a slow function.
  • To reply after returning from the callback because the response is not yet available.
  • To reply from another process, such as a task.

When replying from another process the GenServer should exit if the other process exits without replying as the caller will be blocking awaiting a reply.

Returning {:noreply, new_state, timeout | :hibernate | {:continue, continue}} is similar to {:noreply, new_state} except a timeout, hibernation or continue occurs as with a :reply tuple.

Returning {:stop, reason, reply, new_state} stops the loop and terminate/2 is called with reason reason and state new_state. Then the reply is sent as the response to call and the process exits with reason reason.

Returning {:stop, reason, new_state} is similar to {:stop, reason, reply, new_state} except a reply is not sent.

This callback is optional. If one is not implemented, the server will fail if a call is performed against it.

Link to this callback handle_cast(request, state) View Source (optional) 
handle_cast(request :: term(), state :: term()) ::
  {:noreply, new_state}
  | {:noreply, new_state, timeout() | :hibernate | {:continue, term()}}
  | {:stop, reason :: term(), new_state}
when new_state: term()

Invoked to handle asynchronous cast/2 messages.

request is the request message sent by a cast/2 and state is the current state of the GenServer.

Returning {:noreply, new_state} continues the loop with new state new_state.

Returning {:noreply, new_state, timeout} is similar to {:noreply, new_state} except handle_info(:timeout, new_state) will be called after timeout milliseconds if no messages are received.

Returning {:noreply, new_state, :hibernate} is similar to {:noreply, new_state} except the process is hibernated before continuing the loop. See handle_call/3 for more information.

Returning {:noreply, new_state, {:continue, continue}} is similar to {:noreply, new_state} except handle_continue/2 will be invoked immediately after with the value continue as first argument.

Returning {:stop, reason, new_state} stops the loop and terminate/2 is called with the reason reason and state new_state. The process exits with reason reason.

This callback is optional. If one is not implemented, the server will fail if a cast is performed against it.

Link to this callback handle_continue(continue, state) View Source (optional) 
handle_continue(continue :: term(), state :: term()) ::
  {:noreply, new_state}
  | {:noreply, new_state, timeout() | :hibernate | {:continue, term()}}
  | {:stop, reason :: term(), new_state}
when new_state: term()

Invoked to handle continue instructions.

It is useful for performing work after initialization or for splitting the work in a callback in multiple steps, updating the process state along the way.

Return values are the same as handle_cast/2.

This callback is optional. If one is not implemented, the server will fail if a continue instruction is used.

This callback is only supported on Erlang/OTP 21+.

Link to this callback handle_info(msg, state) View Source (optional) 
handle_info(msg :: :timeout | term(), state :: term()) ::
  {:noreply, new_state}
  | {:noreply, new_state, timeout() | :hibernate | {:continue, term()}}
  | {:stop, reason :: term(), new_state}
when new_state: term()

Invoked to handle all other messages.

msg is the message and state is the current state of the GenServer. When a timeout occurs the message is :timeout.

Return values are the same as handle_cast/2.

This callback is optional. If one is not implemented, the received message will be logged.

Link to this callback init(args) View Source 
init(args :: term()) ::
  {:ok, state}
  | {:ok, state, timeout() | :hibernate | {:continue, term()}}
  | :ignore
  | {:stop, reason :: any()}
when state: any()

Invoked when the server is started. start_link/3 or start/3 will block until it returns.

args is the argument term (second argument) passed to start_link/3.

Returning {:ok, state} will cause start_link/3 to return {:ok, pid} and the process to enter its loop.

Returning {:ok, state, timeout} is similar to {:ok, state} except handle_info(:timeout, state) will be called after timeout milliseconds if no messages are received within the timeout.

Returning {:ok, state, :hibernate} is similar to {:ok, state} except the process is hibernated before entering the loop. See handle_call/3 for more information on hibernation.

Returning {:ok, state, {:continue, continue}} is similar to {:ok, state} except that immediately after entering the loop the handle_continue/2 callback will be invoked with the value continue as first argument.

Returning :ignore will cause start_link/3 to return :ignore and the process will exit normally without entering the loop or calling terminate/2. If used when part of a supervision tree the parent supervisor will not fail to start nor immediately try to restart the GenServer. The remainder of the supervision tree will be started and so the GenServer should not be required by other processes. It can be started later with Supervisor.restart_child/2 as the child specification is saved in the parent supervisor. The main use cases for this are:

  • The GenServer is disabled by configuration but might be enabled later.
  • An error occurred and it will be handled by a different mechanism than the Supervisor. Likely this approach involves calling Supervisor.restart_child/2 after a delay to attempt a restart.

Returning {:stop, reason} will cause start_link/3 to return {:error, reason} and the process to exit with reason reason without entering the loop or calling terminate/2.

Link to this callback terminate(reason, state) View Source (optional) 
terminate(reason, state :: term()) :: term()
when reason: :normal | :shutdown | {:shutdown, term()}

Invoked when the server is about to exit. It should do any cleanup required.

reason is exit reason and state is the current state of the GenServer. The return value is ignored.

terminate/2 is called if a callback (except init/1) does one of the following:

If part of a supervision tree, a GenServer’s Supervisor will send an exit signal when shutting it down. The exit signal is based on the shutdown strategy in the child’s specification. If it is :brutal_kill the GenServer is killed and so terminate/2 is not called. However if it is a timeout the Supervisor will send the exit signal :shutdown and the GenServer will have the duration of the timeout to call terminate/2 - if the process is still alive after the timeout it is killed.

If the GenServer receives an exit signal (that is not :normal) from any process when it is not trapping exits it will exit abruptly with the same reason and so not call terminate/2. Note that a process does NOT trap exits by default and an exit signal is sent when a linked process exits or its node is disconnected.

Therefore it is not guaranteed that terminate/2 is called when a GenServer exits. For such reasons, we usually recommend important clean-up rules to happen in separated processes either by use of monitoring or by links themselves. There is no cleanup needed when the GenServer controls a port (e.g. :gen_tcp.socket) or File.io_device/0, because these will be closed on receiving a GenServer’s exit signal and do not need to be closed manually in terminate/2.

If reason is not :normal, :shutdown, nor {:shutdown, term} an error is logged.

This callback is optional.