@spec decimal_format_metadata(String.t(), Cldr.backend()) ::
  {:ok, Cldr.Number.Format.Meta.t()} | {:error, String.t()}

Returns the metadata representing the given format.

Return the precision (number of digits) of a number

This function delegates to Cldr.Digits.number_of_digits/1

Example

iex> Cldr.Number.precision 1.234
4

@spec to_approx_string(number() | Decimal.t(), Cldr.backend(), Keyword.t() | map()) ::
  {:ok, String.t()} | {:error, {module(), String.t()}}

Formats a number and applies the :approximately format for a locale and number system.

Arguments

• number is an integer, float or Decimal to be formatted

• backend is any Cldr backend. That is, any module that contains use Cldr

• options is a keyword list defining how the number is to be formatted. See Cldr.Number.to_string/3 for a description of the available options.

Example

iex> Cldr.Number.to_approx_string 1234, TestBackend.Cldr
{:ok, "~1,234"}

@spec to_at_least_string(number() | Decimal.t(), Cldr.backend(), Keyword.t() | map()) ::
  {:ok, String.t()} | {:error, {module(), String.t()}}

Formats a number and applies the :at_least format for a locale and number system.

Arguments

• number is an integer, float or Decimal to be formatted

• backend is any Cldr backend. That is, any module that contains use Cldr

• options is a keyword list defining how the number is to be formatted. See Cldr.Number.to_string/3 for a description of the available options.

Example

iex> Cldr.Number.to_at_least_string 1234, TestBackend.Cldr
{:ok, "1,234+"}

@spec to_at_most_string(number() | Decimal.t(), Cldr.backend(), Keyword.t() | map()) ::
  {:ok, String.t()} | {:error, {module(), String.t()}}

Formats a number and applies the :at_most format for a locale and number system.

Arguments

• number is an integer, float or Decimal to be formatted

• backend is any Cldr backend. That is, any module that contains use Cldr

• options is a keyword list defining how the number is to be formatted. See Cldr.Number.to_string/3 for a description of the available options.

Example

iex> Cldr.Number.to_at_most_string 1234, TestBackend.Cldr
{:ok, "≤1,234"}

@spec to_number_system(number(), atom(), Cldr.backend()) ::
  String.t() | {:error, {module(), String.t()}}

Converts a number from the latin digits 0..9 into another number system. Returns {:ok, string} or {:error, reason}.

• number is an integer, float. Decimal is supported only for :numeric number systems, not :algorithmic. See Cldr.Number.System.to_system/3 for further information.

• system is any number system returned by Cldr.known_number_systems/0

Examples

iex> Cldr.Number.to_number_system 123, :hant, TestBackend.Cldr
{:ok, "一百二十三"}

iex> Cldr.Number.to_number_system 123, :hebr, TestBackend.Cldr
{:ok, "קכ״ג"}

@spec to_number_system!(number(), atom(), Cldr.backend()) :: String.t() | no_return()

Converts a number from the latin digits 0..9 into another number system. Returns the converted number or raises an exception on error.

• number is an integer, float. Decimal is supported only for :numeric number systems, not :algorithmic. See Cldr.Number.System.to_system/3 for further information.

• system is any number system returned by Cldr.Number.System.known_number_systems/0

Example

iex> Cldr.Number.to_number_system! 123, :hant, TestBackend.Cldr
"一百二十三"

@spec to_range_string(Range.t(), Cldr.backend(), Keyword.t() | map()) ::
  {:ok, String.t()} | {:error, {module(), String.t()}}

Formats the first and last numbers of a range and applies the :range format for a locale and number system.

Arguments

• number is an integer, float or Decimal to be formatted

• backend is any Cldr backend. That is, any module that contains use Cldr

• options is a keyword list defining how the number is to be formatted. See Cldr.Number.to_string/3 for a description of the available options.

Example

iex> Cldr.Number.to_range_string 1234..5678, TestBackend.Cldr
{:ok, "1,234–5,678"}

@spec to_string(
  number() | Decimal.t() | String.t(),
  Cldr.backend() | Keyword.t() | map(),
  Keyword.t() | map()
) :: {:ok, String.t()} | {:error, {atom(), String.t()}}

Returns a number formatted into a string according to a format pattern and options.

Arguments

• number is an integer, float or Decimal to be formatted

• backend is any Cldr backend. That is, any module that contains use Cldr

• options is a keyword list defining how the number is to be formatted. The valid options are:

Options

• format: the format style or a format string defining how the number is formatted. See Cldr.Number.Format for how format strings can be constructed. See Cldr.Number.Format.format_styles_for/3 to return available format styles for a locale. The default format is :standard.

• If :format is set to :long or :short then the formatting depends on whether :currency is specified. If not specified then the number is formatted as :decimal_long or :decimal_short. If :currency is specified the number is formatted as :currency_long or :currency_short and :fractional_digits is set to 0 as a default.

• If :format is set to :currency_long_with_symbol then a format composed of :currency_long with the locale's currency format is used.

• :format may also be a format defined by CLDR's Rules Based Number Formats (RBNF). Further information is found in the module Cldr.Rbnf. The most commonly used formats in this category are to spell out the number in a the locales language. The applicable formats are :spellout, :spellout_year, :ordinal. A number can also be formatted as roman numbers by using the format :roman or :roman_lower.

• currency: is the currency for which the number is formatted. If currency is set and no :format is set, :format will be set to :currency as well. Currency may be any ISO 4217 currency code returned by Cldr.Currency.known_currencies/0 or a ISO 24165 digital token identifier (crypto currency).

• currency_symbol: Allows overriding a currency symbol. The alternatives are:

  • :iso the ISO currency code will be used instead of the default currency symbol.
  • :narrow uses the narrow symbol defined for the locale. The same narrow symbol can be defined for more than one currency and therefore this should be used with care. If no narrow symbol is defined, the standard symbol is used.
  • :symbol uses the standard symbol defined in CLDR. A symbol is unique for each currency and can be safely used.
  • :standard (the default and recommended) uses the CLDR-defined symbol based upon the currency format for the locale.
  • "string" uses string as the currency symbol

• :cash: a boolean which indicates whether a number being formatted as a :currency is to be considered a cash value or not. Currencies can be rounded differently depending on whether :cash is true or false. *This option is deprecated in favour of currency_digits: :cash. Ignored if the currency is a digital token.

• :currency_digits indicates which of the rounding and digits should be used. The options are :accounting which is the default, :cash or :iso. Ignored if the currency is a digital token.

• :rounding_mode: determines how a number is rounded to meet the precision of the format requested. The available rounding modes are :down, :half_up, :half_even, :ceiling, :floor, :half_down, :up. The default is :half_even.

• :number_system: determines which of the number systems for a locale should be used to define the separators and digits for the formatted number. If number_system is an atom then number_system is interpreted as a number system. See Cldr.Number.System.number_systems_for/2. If the :number_system is binary then it is interpreted as a number system name. See Cldr.Number.System.number_system_names_for/2. The default is :default.

• :locale: determines the locale in which the number is formatted. See Cldr.known_locale_names/0. The default isCldr.get_locale/0 which is the locale currently in affect for this Process and which is set by Cldr.put_locale/1.

• If :fractional_digits is set to a positive integer value then the number will be rounded to that number of digits and displayed accordingly - overriding settings that would be applied by default. For example, currencies have fractional digits defined reflecting each currencies minor unit. Setting :fractional_digits will override that setting.

• If :maximum_integer_digits is set to a positive integer value then the number is left truncated before formatting. For example if the number 1234 is formatted with the option maximum_integer_digits: 2, the number is truncated to 34 and formatted.

• If :round_nearest is set to a positive integer value then the number will be rounded to nearest increment of that value - overriding settings that would be applied by default.

• :minimum_grouping_digits overrides the CLDR definition of minimum grouping digits. For example in the locale es the number 1345 is formatted by default as 1345 because the locale defines the minimium_grouping_digits as 2. If minimum_grouping_digits: 1 is set as an option the number is formatted as 1.345. The :minimum_grouping_digits is added to the grouping defined by the number format. If the sum of these two digits is greater than the number of digits in the integer (or fractional) part of the number then no grouping is performed.

• :wrapper is a 2-arity function that will be called for each number component with parameters string and tag where tag is one of :number, :currency_symbol, :currency_space, :literal, :quote, :percent, :permille, :minus or :plus. The function must return either a string or a Phoenix safe string such as that returned by Phoenix.HTML.Tag.content_tag/3. The function can be used to wrap format elements in HTML or other tags.

Locale extensions affecting formatting

A locale identifier can specify options that affect number formatting. These options are:

• nu: defines the number system to be used if none is specified by the :number_system option to to_string/2

This key is part of the u extension and that document should be consulted for details on how to construct a locale identifier with these extensions.

Wrapping format elements

Wrapping elements is particularly useful when formatting a number with a currency symbol and the requirement is to have different HTML formatting applied to the symbol than the number. For example:

iex> Cldr.Number.to_string(100, format: :currency, currency: :USD, wrapper: fn
...>   string, :currency_symbol -> "<span class=\"symbol\">" <> string <> "</span>"
...>   string, :number -> "<span class=\"number\">" <> string <> "</span>"
...>   string, :currency_space -> "<span>" <> string <> "</span>"
...>   string, _other -> string
...> end)
{:ok, "<span class=\"symbol\">$</span><span class=\"number\">100.00</span>"}

It is also possible and recommended to use the Phoenix.HTML.Tag.content_tag/3 function if wrapping HTML tags since these will ensure HTML entities are correctly encoded. For example:

iex> Cldr.Number.to_string(100, format: :currency, currency: :USD, wrapper: fn
...>   string, :currency_symbol -> Phoenix.HTML.Tag.content_tag(:span, string, class: "symbol")
...>   string, :number -> Phoenix.HTML.Tag.content_tag(:span, string, class: "number")
...>   string, :currency_space -> Phoenix.HTML.Tag.content_tag(:span, string)
...>   string, _other -> string
...> end)
{:ok, "<span class=\"symbol\">$</span><span class=\"number\">100.00</span>"}

When formatting a number the format is parsed into format elements that might include a currency symbol, a literal string, inserted text between a currency symbol and the currency amount, a percent sign, the number itself and several other elements. In some cases it is helpful to be apply specific formatting to each element. This can be achieved by specifying a :wrapper option. This option takes a 2-arity function as an argument. For each element of the format the wrapper function is called with two parameters: the format element as a string and an atom representing the element type. The wrapper function is required to return a string that is then inserted in the final formatted number.

Returns

• {:ok, string} or

• {:error, {exception, message}}

Examples

iex> Cldr.Number.to_string 12345, TestBackend.Cldr
{:ok, "12,345"}

iex> Cldr.Number.to_string 12345, TestBackend.Cldr, locale: "fr"
{:ok, "12 345"}

iex> Cldr.Number.to_string 1345.32, TestBackend.Cldr, currency: :EUR, locale: "es", minimum_grouping_digits: 1
{:ok, "1.345,32 €"}

iex> Cldr.Number.to_string 1345.32, TestBackend.Cldr, currency: :EUR, locale: "es"
{:ok, "1345,32 €"}

iex> Cldr.Number.to_string 12345, TestBackend.Cldr, locale: "fr", currency: "USD"
{:ok, "12 345,00 $US"}

iex> Cldr.Number.to_string 12345, TestBackend.Cldr, format: "#E0"
{:ok, "1.2345E4"}

iex> Cldr.Number.to_string 12345, TestBackend.Cldr, format: :accounting, currency: "THB"
{:ok, "THB 12,345.00"}

iex> Cldr.Number.to_string -12345, TestBackend.Cldr, format: :accounting, currency: "THB"
{:ok, "(THB 12,345.00)"}

iex> Cldr.Number.to_string 12345, TestBackend.Cldr, format: :accounting, currency: "THB",
...> locale: "th"
{:ok, "฿12,345.00"}

iex> Cldr.Number.to_string 12345, TestBackend.Cldr, format: :accounting, currency: "THB",
...> locale: "th", number_system: :native
{:ok, "฿๑๒,๓๔๕.๐๐"}

iex> Cldr.Number.to_string 1244.30, TestBackend.Cldr, format: :long
{:ok, "1 thousand"}

iex> Cldr.Number.to_string 1244.30, TestBackend.Cldr, format: :long, currency: "USD"
{:ok, "1,244 US dollars"}

iex> Cldr.Number.to_string 1244.30, TestBackend.Cldr, format: :short
{:ok, "1K"}

iex> Cldr.Number.to_string 1244.30, TestBackend.Cldr, format: :short, currency: "EUR"
{:ok, "€1K"}

iex> Cldr.Number.to_string 1234, TestBackend.Cldr, format: :spellout
{:ok, "one thousand two hundred thirty-four"}

iex> Cldr.Number.to_string 1234, TestBackend.Cldr, format: :spellout_verbose
{:ok, "one thousand two hundred and thirty-four"}

iex> Cldr.Number.to_string 1989, TestBackend.Cldr, format: :spellout_year
{:ok, "nineteen eighty-nine"}

iex> Cldr.Number.to_string 123, TestBackend.Cldr, format: :ordinal
{:ok, "123rd"}

iex> Cldr.Number.to_string 123, TestBackend.Cldr, format: :roman
{:ok, "CXXIII"}

iex> Cldr.Number.to_string 123, TestBackend.Cldr, locale: "th-u-nu-thai"
{:ok, "๑๒๓"}

Errors

An error tuple {:error, {exception, reason}} will be returned if an error is detected. The two most likely causes of an error return are:

• A format cannot be compiled. In this case the error tuple will look like:

    iex> Cldr.Number.to_string(12345, TestBackend.Cldr, format: "0#")
    {:error, {Cldr.FormatCompileError,
      "Decimal format compiler: syntax error before: \"#\""}}

• The format style requested is not defined for the locale and number_system. This happens typically when the number system is :algorithmic rather than the more common :numeric. In this case the error return looks like:

    iex> Cldr.Number.to_string(1234, TestBackend.Cldr, locale: "he", number_system: "hebr", format: :percent)
    {:error, {Cldr.UnknownFormatError,
    "The locale :he with number system :hebr does not define a format :percent"}}

@spec to_string!(
  number() | Decimal.t() | String.t(),
  Cldr.backend() | Keyword.t() | map(),
  Keyword.t() | map()
) :: String.t() | no_return()

Same as the execution of to_string/2 but raises an exception if an error would be returned.

Options

• number is an integer, float or Decimal to be formatted

• options is a keyword list defining how the number is to be formatted. See Cldr.Number.to_string/2

Returns

• a formatted number as a string or

• raises an exception

Examples

iex> Cldr.Number.to_string! 12345, TestBackend.Cldr
"12,345"

iex> Cldr.Number.to_string! 12345, TestBackend.Cldr, locale: "fr"
"12 345"

@spec validate_number_system(
  Cldr.Locale.locale_name() | Cldr.LanguageTag.t(),
  Cldr.Number.System.system_name() | Cldr.Number.System.types(),
  Cldr.backend()
) :: {:ok, Cldr.Number.System.system_name()} | {:error, {module(), String.t()}}

Return a valid number system from a provided locale and number system name or type.

The number system or number system type must be valid for the given locale. If a number system type is provided, the underlying number system is returned.

Arguments

• locale is any valid locale name returned by Cldr.known_locale_names/1 or a Cldr.LanguageTag struct returned by Cldr.Locale.new!/2

• system_name is any number system name returned by Cldr.known_number_systems/0 or a number system type returned by Cldr.known_number_system_types/0

• backend is any module that includes use Cldr and therefore is a Cldr backend module

Examples

iex> Cldr.Number.validate_number_system :en, :latn, TestBackend.Cldr
{:ok, :latn}

iex> Cldr.Number.validate_number_system :en, :default, TestBackend.Cldr
{:ok, :latn}

iex> Cldr.Number.validate_number_system :en, :unknown, TestBackend.Cldr
{:error,
 {Cldr.UnknownNumberSystemError, "The number system :unknown is unknown"}}

iex> Cldr.Number.validate_number_system "zz", :default, TestBackend.Cldr
{:error, {Cldr.InvalidLanguageError, "The language \"zz\" is invalid"}}