Defines a single ascii codepoint in the given ranges.

ranges is a list containing one of:

• a min..max range expressing supported codepoints
• a codepoint integer expressing a supported codepoint
• {:not, min..max} expressing not supported codepoints
• {:not, codepoint} expressing a not supported codepoint

Examples

defmodule MyParser do
  import NimbleParsec

  defparsec :digit_and_lowercase,
            empty()
            |> ascii_char([?0..?9])
            |> ascii_char([?a..?z])
end

MyParser.digit_and_lowercase("1a")
#=> {:ok, [?1, ?a], "", %{}, {1, 0}, 2}

MyParser.digit_and_lowercase("a1")
#=> {:error, "expected a byte in the range ?0..?9, followed by a byte in the range ?a..?z", "a1", %{}, 1, 1}

Defines an ascii string combinator with of exact length or min and max length.

The ranges specify the allowed characters in the ascii string. See ascii_char/2 for more information.

If you want a string of unknown size, use ascii_string(ranges, min: 1). If you want a literal string, use string/2.

Examples

defmodule MyParser do
  import NimbleParsec

  defparsec :two_lowercase_letters, ascii_string([?a..?z], 2)
end

MyParser.two_lowercase_letters("abc")
#=> {:ok, ["ab"], "c", %{}, {1, 0}, 2}

Puts the result of the given combinator as the first element of a tuple with the byte_offset as second element.

byte_offset is a non-negative integer.

Chooses one of the given combinators.

Expects at leasts two choices.

Beware! Char combinators

Note both utf8_char/2 and ascii_char/2 allow multiple ranges to be given. Therefore, instead this:

choice([
  ascii_char([?a..?z]),
  ascii_char([?A..?Z]),
])

One should simply prefer:

ascii_char([?a..?z, ?A..?Z])

As the latter is compiled more efficiently by NimbleParsec.

Beware! Always successful combinators

If a combinator that always succeeds is given as a choice, that choice will always succeed which may lead to unused function warnings since any further choice won’t ever be attempted. For example, because repeat/2 always succeeds, the string/2 combinator below it won’t ever run:

choice([
  repeat(ascii_char([?0..?9])),
  string("OK")
])

Instead of repeat/2, you may want to use times/3 with the flags :min and :max.

Concatenates two combinators.

Examples

defmodule MyParser do
  import NimbleParsec

  defparsec :digit_upper_lower_plus,
            concat(
              concat(ascii_char([?0..?9]), ascii_char([?A..?Z])),
              concat(ascii_char([?a..?z]), ascii_char([?+..?+]))
            )
end

MyParser.digit_upper_lower_plus("1Az+")
#=> {:ok, [?1, ?A, ?z, ?+], "", %{}, {1, 0}, 4}

Inspects the combinator state given to to_debug with the given opts.

Defines a combinator with the given name and opts.

It is similar to defparsec/3 except it does not define an entry-point parsing function, just the combinator function to be used with parsec/2.

Defines a parser (and a combinator) with the given name and opts.

The parser is a function that receives two arguments, the binary to be parsed and a set of options. You can consult the documentation of the generated parser function for more information.

This function will also define a combinator that can be used as parsec(name) when building other parsers. See parsec/2 for more information on invoking compiled combinators.

Beware!

defparsec/3 is executed during compilation. This means you can’t invoke a function defined in the same module. The following will error because the date function has not yet been defined:

defmodule MyParser do
  import NimbleParsec

  def date do
    integer(4)
    |> ignore(string("-"))
    |> integer(2)
    |> ignore(string("-"))
    |> integer(2)
  end

  defparsec :date, date()
end

This can be solved in different ways. You may simply compose a long parser using variables. For example:

defmodule MyParser do
  import NimbleParsec

  date =
    integer(4)
    |> ignore(string("-"))
    |> integer(2)
    |> ignore(string("-"))
    |> integer(2)

  defparsec :date, date
end

Alternatively, you may define a Helpers module with many convenience combinators, and then invoke them in your parser module:

defmodule MyParser.Helpers do
  import NimbleParsec

  def date do
    integer(4)
    |> ignore(string("-"))
    |> integer(2)
    |> ignore(string("-"))
    |> integer(2)
  end
end

defmodule MyParser do
  import NimbleParsec
  import MyParser.Helpers

  defparsec :date, date()
end

The approach of using helper modules is the favorite way of composing parsers in NimbleParsec.

Options

• :inline - when true, inlines clauses that work as redirection for other clauses. It is disabled by default because of a bug in Elixir v1.5 and v1.6 where unused functions that are inlined cause a compilation error

• :debug - when true, writes generated clauses to :stderr for debugging

Defines a private parser (and a combinator) with the given name and opts.

The same as defparsec/3 but the parsing function is private.

Duplicates the combinator to_duplicate n times.

Returns an empty combinator.

An empty combinator cannot be compiled on its own.

Ignores the output of combinator given in to_ignore.

Examples

defmodule MyParser do
  import NimbleParsec

  defparsec :ignorable, string("T") |> ignore() |> integer(2, 2)
end

MyParser.ignorable("T12")
#=> {:ok, [12], "", %{}, {1, 0}, 2}

Defines an integer combinator with of exact length or min and max length.

If you want an integer of unknown size, use integer(min: 1).

This combinator does not parse the sign and is always on base 10.

Examples

With exact length:

defmodule MyParser do
  import NimbleParsec

  defparsec :two_digits_integer, integer(2)
end

MyParser.two_digits_integer("123")
#=> {:ok, [12], "3", %{}, {1, 0}, 2}

MyParser.two_digits_integer("1a3")
#=> {:error, "expected a two digits integer", "1a3", %{}, {1, 0}, 0}

With min and max:

defmodule MyParser do
  import NimbleParsec

  defparsec :two_digits_integer, integer(min: 2, max: 4)
end

MyParser.two_digits_integer("123")
#=> {:ok, [123], "", %{}, {1, 0}, 2}

MyParser.two_digits_integer("1a3")
#=> {:error, "expected a two digits integer", "1a3", %{}, {1, 0}, 0}

If the size of the integer has a min and max close to each other, such as from 2 to 4 or from 1 to 2, using choice may emit more efficient code:

choice([integer(4), integer(3), integer(2)])

Note you should start from bigger to smaller.

Adds a label to the combinator to be used in error reports.

Examples

defmodule MyParser do
  import NimbleParsec

  defparsec :digit_and_lowercase,
            empty()
            |> ascii_char([?0..?9])
            |> ascii_char([?a..?z])
            |> label("digit followed by lowercase letter")
end

MyParser.digit_and_lowercase("1a")
#=> {:ok, [?1, ?a], "", %{}, {1, 0}, 2}

MyParser.digit_and_lowercase("a1")
#=> {:error, "expected a digit followed by lowercase letter", "a1", %{}, {1, 0}, 0}

Puts the result of the given combinator as the first element of a tuple with the line as second element.

line is a tuple where the first element is the current line and the second element is the byte offset immediately after the newline.

Looks ahead the rest of the binary to be parsed alongside the context.

call is either a {module, function, args} representing a remote call, a {function, args} representing a local call or an atom function representing {function, []}.

The function given in call will receive 4 additional arguments. The rest of the parsed binary, the parser context, the current line and the current offset will be prepended to the given args. The args will be injected at the compile site and therefore must be escapable via Macro.escape/1.

The call must return a tuple {acc, context} with list of results to be added to the accumulator in reverse order as first argument and a context as second argument. It may also return {:error, reason} to stop processing.

Examples

defmodule MyParser do
  import NimbleParsec

  defparsec :letters_no_zero,
            ascii_char([?a..?z])
            |> times(min: 3)
            |> lookahead(:error_when_next_is_0)

  defp error_when_next_is_0(<<?0, _::binary>>, context, _line, _offset) do
    {:error, "next is 0"}
  end

  defp error_when_next_is_0(_rest, context, _line, _offset) do
    {[], context}
  end
end

MyParser.letters_no_zero("abc")
#=> {:ok, ["99-98-97"], "", %{}, {1, 0}, 3}

MyParser.letters_no_zero("abc1")
#=> {:ok, ["99-98-97"], "1", %{}, {1, 0}, 3}

MyParser.letters_no_zero("abc0")
#=> {:error, "next is zero", "0", %{}, {1, 0}, 3}

Maps over the combinator results with the remote or local function in call.

call is either a {module, function, args} representing a remote call, a {function, args} representing a local call or an atom function representing {function, []}.

Each parser result will be invoked individually for the call. Each result be prepended to the given args. The args will be injected at the compile site and therefore must be escapable via Macro.escape/1.

See traverse/3 for a low level version of this function.

Examples

defmodule MyParser do
  import NimbleParsec

  defparsec :letters_to_string_chars,
            ascii_char([?a..?z])
            |> ascii_char([?a..?z])
            |> ascii_char([?a..?z])
            |> map({Integer, :to_string, []})
end

MyParser.letters_to_string_chars("abc")
#=> {:ok, ["97", "98", "99"], "", %{}, {1, 0}, 3}

Marks the given combinator as optional.

It is equivalent to choice([optional, empty()]).

Invokes an already compiled combinator with name name in the same module.

Every parser defined via defparsec/3 or defparsecp/3 can be used as combinators. However, the defparsec/3 and defparsecp/3 functions also define an entry-point parsing function, as implied by their names. If you want to define a combinator with the sole purpose of using it in combinator, use defcombinatorp/3 instead.

Use cases

parsec/2 is useful to implement recursive definitions.

Note while parsec/2 can be used to compose smaller combinators, the favorite mechanism for doing composition is via regular functions and not via parsec/2. Let’s see a practical example. Imagine that you have this module:

defmodule MyParser do
  import NimbleParsec

  date =
    integer(4)
    |> ignore(string("-"))
    |> integer(2)
    |> ignore(string("-"))
    |> integer(2)

  time =
    integer(2)
    |> ignore(string(":"))
    |> integer(2)
    |> ignore(string(":"))
    |> integer(2)
    |> optional(string("Z"))

  defparsec :datetime, date |> ignore(string("T")) |> concat(time), debug: true
end

Now imagine that you want to break date and time apart into helper functions, as you use them in other occasions. Generally speaking, you should NOT do this:

defmodule MyParser do
  import NimbleParsec

  defcombinatorp :date,
                 integer(4)
                 |> ignore(string("-"))
                 |> integer(2)
                 |> ignore(string("-"))
                 |> integer(2)

  defcombinatorp :time,
                 integer(2)
                 |> ignore(string(":"))
                 |> integer(2)
                 |> ignore(string(":"))
                 |> integer(2)
                 |> optional(string("Z"))

  defparsec :datetime,
            parsec(:date) |> ignore(string("T")) |> concat(parsec(:time))
end

The reason why the above is not recommended is because each parsec/2 combinator ends-up adding a stacktrace entry during parsing, which affects the ability of NimbleParsec to optimize code. If the goal is to compose combinators, you can do so with modules and functions:

defmodule MyParser.Helpers do
  import NimbleParsec

  def date do
    integer(4)
    |> ignore(string("-"))
    |> integer(2)
    |> ignore(string("-"))
    |> integer(2)
  end

  def time do
    integer(2)
    |> ignore(string(":"))
    |> integer(2)
    |> ignore(string(":"))
    |> integer(2)
    |> optional(string("Z"))
  end
end

defmodule MyParser.Helpers do
  import NimbleParsec
  import MyParser.Helpers

  defparsec :datetime,
            date() |> ignore(string("T")) |> concat(time())
end

The implementation above will be able to compile to the most efficient format as possible without forcing new stacktrace entries.

The only situation where you should use parsec/2 for composition is when a large parser is used over and over again in a way compilation times are high. In this sense, you can use parsec/2 to improve compilation time at the cost of runtime performance. By using parsec/2, the tree size built at compile time will be reduced although runtime performance is degraded as every time this function is invoked it introduces a stacktrace entry.

Examples

A very limited but recursive XML parser could be written as follows:

defmodule SimpleXML do
  import NimbleParsec

  tag = ascii_string([?a..?z, ?A..?Z], min: 1)
  text = ascii_string([not: ?<], min: 1)

  opening_tag =
    ignore(string("<"))
    |> concat(tag)
    |> ignore(string(">"))

  closing_tag =
    ignore(string("</"))
    |> concat(tag)
    |> ignore(string(">"))

  defparsec :xml,
            opening_tag
            |> repeat_until(choice([parsec(:xml), text]), [string("</")])
            |> concat(closing_tag)
            |> wrap()
end

SimpleXML.xml("<foo>bar</foo>")
#=> {:ok, [["foo", "bar", "foo"]], "", %{}, {1, 0}, 14}

In the example above, defparsec/3 has defined the entry-point parsing function as well as a combinator which we have invoked with parsec(:xml).

In many cases, however, you want to define recursive combinators without the entry-point parsing function. We can do this by replacing defparsec/3 by defcombinatorp:

defcombinatorp :xml,
               opening_tag
               |> repeat_until(choice([parsec(:xml), text]), [string("</")])
               |> concat(closing_tag)
               |> wrap()

Note that now you can no longer invoke SimpleXML.xml(xml) as there is no associating parsing function. Eventually you will have to define a defparsec/3 or defparsecp/3, that invokes the combinator above via parsec/3.

Invokes while to emit the AST that will repeat to_repeat while the AST code returns {:cont, context}.

In case repetition should stop, while must return {:halt, context}.

while is a {module, function, args} and it will receive 4 additional arguments. The AST representations of the binary to be parsed, context, line and offset will be prended to args. while is invoked at compile time and is useful in combinators that avoid injecting runtime dependencies.

Invokes call to emit the AST that traverses the to_traverse combinator results.

call is a {module, function, args} and it will receive 5 additional arguments. The AST representation of the rest of the parsed binary, the parser results, context, line and offset will be prepended to args. call is invoked at compile time and is useful in combinators that avoid injecting runtime dependencies.

The call must return a list of results to be added to the accumulator. Notice the received results are in reverse order and must be returned in reverse order too.

The number of elements returned does not need to be the same as the number of elements given.

Reduces over the combinator results with the remote or local function in call.

call is either a {module, function, args} representing a remote call, a {function, args} representing a local call or an atom function representing {function, []}.

The parser results to be reduced will be prepended to the given args. The args will be injected at the compile site and therefore must be escapable via Macro.escape/1.

See traverse/3 for a low level version of this function.

Examples

defmodule MyParser do
  import NimbleParsec

  defparsec :letters_to_reduced_chars,
            ascii_char([?a..?z])
            |> ascii_char([?a..?z])
            |> ascii_char([?a..?z])
            |> reduce({Enum, :join, ["-"]})
end

MyParser.letters_to_reduced_chars("abc")
#=> {:ok, ["97-98-99"], "", %{}, {1, 0}, 3}

Allow the combinator given on to_repeat to appear zero or more times.

Beware! Since repeat/2 allows zero entries, it cannot be used inside choice/2, because it will always succeed and may lead to unused function warnings since any further choice won’t ever be attempted. For example, because repeat/2 always succeeds, the string/2 combinator below it won’t ever run:

choice([
  repeat(ascii_char([?a..?z])),
  string("OK")
])

Instead of repeat/2, you may want to use times/3 with the flags :min and :max.

Examples

defmodule MyParser do
  import NimbleParsec

  defparsec :repeat_lower, repeat(ascii_char([?a..?z]))
end

MyParser.repeat_lower("abcd")
#=> {:ok, [?a, ?b, ?c, ?d], "", %{}, {1, 0}, 4}

MyParser.repeat_lower("1234")
#=> {:ok, [], "1234", %{}, {1, 0}, 0}

Repeats to_repeat until one of the combinators in choices match.

Each of the combinators given in choice must be optimizable into a single pattern, otherwise this function will refuse to compile. Use repeat_while/3 for a general mechanism for repeating.

Examples

defmodule MyParser do
  import NimbleParsec

  defparsec :string_with_quotes,
            ascii_char([?"])
            |> repeat_until(
              choice([
                ~S(\") |> string() |> replace(?"),
                utf8_char([])
              ]),
              [ascii_char([?"])]
            )
            |> ascii_char([?"])
            |> reduce({List, :to_string, []})

end

MyParser.string_with_quotes(~S("string with quotes \" inside"))
{:ok, ["\"string with quotes \" inside\""], "", %{}, {1, 0}, 30}

Repeats while the given remote or local function while returns {:cont, context}.

In case repetition should stop, while must return {:halt, context}.

while is either a {module, function, args} representing a remote call, a {function, args} representing a local call or an atom function representing {function, []}.

The function given in while will receive 4 additional arguments. The rest of the binary to be parsed, the parser context, the current line and the current offset will be prepended to the given args. The args will be injected at the compile site and therefore must be escapable via Macro.escape/1.

Examples

defmodule MyParser do
  import NimbleParsec

  defparsec :string_with_quotes,
            ascii_char([?"])
            |> repeat_while(
              choice([
                ~S(\") |> string() |> replace(?"),
                utf8_char([])
              ]),
              {:not_quote, []}
            )
            |> ascii_char([?"])
            |> reduce({List, :to_string, []})

  defp not_quote(<<?", _::binary>>, context, _, _), do: {:halt, context}
  defp not_quote(_, context, _, _), do: {:cont, context}
end

MyParser.string_with_quotes(~S("string with quotes \" inside"))
{:ok, ["\"string with quotes \" inside\""], "", %{}, {1, 0}, 30}

Replaces the output of combinator given in to_replace by a single value.

The value will be injected at the compile site and therefore must be escapable via Macro.escape/1.

Examples

defmodule MyParser do
  import NimbleParsec

  defparsec :replaceable, string("T") |> replace("OTHER") |> integer(2, 2)
end

MyParser.replaceable("T12")
#=> {:ok, ["OTHER", 12], "", %{}, {1, 0}, 2}

Defines a string binary value.

Examples

defmodule MyParser do
  import NimbleParsec

  defparsec :string_t, string("T")
end

MyParser.string_t("T")
#=> {:ok, ["T"], "", %{}, {1, 0}, 1}

MyParser.string_t("not T")
#=> {:error, "expected a string \"T\"", "not T", %{}, {1, 0}, 0}

Tags the result of the given combinator in to_tag in a tuple with tag as first element.

Examples

defmodule MyParser do
  import NimbleParsec

  defparsec integer(min: 1) |> tag(:integer)
end

MyParser.integer("1234")
#=> {:ok, [integer: [1234]], "", %{}, {1, 0}, 4}

Notice, however, that the integer result is wrapped in a list, because the parser is expected to emit multiple tokens. When you are sure that only a single token is emitted, you should use unwrap_and_tag/3.

Allow the combinator given on to_repeat to appear at least, at most or exactly a given amout of times.

Examples

defmodule MyParser do
  import NimbleParsec

  defparsec :minimum_lower, times(ascii_char([?a..?z]), min: 2)
end

MyParser.minimum_lower("abcd")
#=> {:ok, [?a, ?b, ?c, ?d], "", %{}, {1, 0}, 4}

MyParser.minimum_lower("ab12")
#=> {:ok, [?a, ?b], "12", %{}, {1, 0}, 2}

MyParser.minimum_lower("a123")
#=> {:ok, [], "a123", %{}, {1, 0}, 0}

Traverses the combinator results with the remote or local function call.

call is either a {module, function, args} representing a remote call, a {function, args} representing a local call or an atom function representing {function, []}.

The function given in call will receive 5 additional arguments. The rest of the parsed binary, the parser results to be traversed, the parser context, the current line and the current offset will be prepended to the given args. The args will be injected at the compile site and therefore must be escapable via Macro.escape/1.

The call must return a tuple {acc, context} with list of results to be added to the accumulator as first argument and a context as second argument. It may also return {:error, reason} to stop processing. Notice the received results are in reverse order and must be returned in reverse order too.

The number of elements returned does not need to be the same as the number of elements given.

This is a low-level function for changing the parsed result. On top of this function, other functions are built, such as map/3 if you want to map over each individual element and not worry about ordering, reduce/3 to reduce all elements into a single one, replace/3 if you want to replace the parsed result by a single value and ignore/3 if you want to ignore the parsed result.

Examples

defmodule MyParser do
  import NimbleParsec

  defparsec :letters_to_chars,
            ascii_char([?a..?z])
            |> ascii_char([?a..?z])
            |> ascii_char([?a..?z])
            |> traverse({:join_and_wrap, ["-"]})

  defp join_and_wrap(_rest, args, context, _line, _offset, joiner) do
    {args |> Enum.join(joiner) |> List.wrap(), context}
  end
end

MyParser.letters_to_chars("abc")
#=> {:ok, ["99-98-97"], "", %{}, {1, 0}, 3}

Unwraps and tags the result of the given combinator in to_tag in a tuple with tag as first element.

Examples

defmodule MyParser do
  import NimbleParsec

  defparsec integer(min: 1) |> unwrap_and_tag(:integer)
end

MyParser.integer("1234")
#=> {:ok, [integer: 1234], "", %{}, {1, 0}, 4}

In case the combinator emits more than one token, an error will be raised. See tag/3 for more information.

Defines a single utf8 codepoint in the given ranges.

ranges is a list containing one of:

• a min..max range expressing supported codepoints
• a codepoint integer expressing a supported codepoint
• {:not, min..max} expressing not supported codepoints
• {:not, codepoint} expressing a not supported codepoint

Examples

defmodule MyParser do
  import NimbleParsec

  defparsec :digit_and_utf8,
            empty()
            |> utf8_char([?0..?9])
            |> utf8_char([])
end

MyParser.digit_and_utf8("1é")
#=> {:ok, [?1, ?é], "", %{}, {1, 0}, 2}

MyParser.digit_and_utf8("a1")
#=> {:error, "expected a utf8 codepoint in the range ?0..?9, followed by a utf8 codepoint", "a1", %{}, {1, 0}, 0}

Defines an ascii string combinator with of exact length or min and max codepoint length.

The ranges specify the allowed characters in the ascii string. See ascii_char/2 for more information.

If you want a string of unknown size, use utf8_string(ranges, min: 1). If you want a literal string, use string/2.

Examples

defmodule MyParser do
  import NimbleParsec

  defparsec :two_letters, utf8_string([], 2)
end

MyParser.two_letters("áé")
#=> {:ok, ["áé"], "", %{}, {1, 0}, 3}

Wraps the results of the given combinator in to_wrap in a list.