@spec assert_error_sent(integer() | atom(), function()) :: {integer(), list(), term()}

Asserts an error was wrapped and sent with the given status.

Useful for testing actions that you expect raise an error and have the response wrapped in an HTTP status, with content usually rendered by your MyAppWeb.ErrorHTML view.

The function accepts a status either as an integer HTTP status or atom, such as 500 or :internal_server_error. The list of allowed atoms is available in Plug.Conn.Status. If an error is raised, a 3-tuple of the wrapped response is returned matching the status, headers, and body of the response:

{500, [{"content-type", "text/html"} | _], "Internal Server Error"}

Examples

assert_error_sent :internal_server_error, fn ->
  get(build_conn(), "/broken/route")
end

response = assert_error_sent 500, fn ->
  get(build_conn(), "/broken/route")
end
assert {500, [_h | _t], "Internal Server Error"} = response

This can also be used to test a route resulted in an error that was translated to a specific response by the Plug.Status protocol, such as Ecto.NoResultsError:

assert_error_sent :not_found, fn ->
  get(build_conn(), "/something-that-raises-no-results-error")
end

Note: for routes that don't raise an error, but instead return a status, you should test the response directly:

conn = get(build_conn(), "/users/not-found")
assert response(conn, 404)

@spec build_conn() :: Plug.Conn.t()

Creates a connection to be used in upcoming requests.

@spec build_conn(atom() | binary(), binary(), binary() | list() | map() | nil) ::
  Plug.Conn.t()

Creates a connection to be used in upcoming requests with a preset method, path and body.

This is useful when a specific connection is required for testing a plug or a particular function.

@spec bypass_through(Plug.Conn.t()) :: Plug.Conn.t()

Calls the Endpoint and Router pipelines.

Useful for unit testing Plugs where Endpoint and/or router pipeline plugs are required for proper setup.

Note the use of get("/") following bypass_through in the examples below. To execute the plug pipelines, you must issue a request against the router. Most often, you can simply send a GET request against the root path, but you may also specify a different method or path which your pipelines may operate against.

Examples

For example, imagine you are testing an authentication plug in isolation, but you need to invoke the Endpoint plugs and router pipelines to set up session and flash related dependencies. One option is to invoke an existing route that uses the proper pipelines. You can do so by passing the connection and the router name to bypass_through:

conn =
  conn
  |> bypass_through(MyAppWeb.Router)
  |> get("/some_url")
  |> MyApp.RequireAuthentication.call([])
assert conn.halted

You can also specify which pipelines you want to run:

conn =
  conn
  |> bypass_through(MyAppWeb.Router, [:browser])
  |> get("/")
  |> MyApp.RequireAuthentication.call([])
assert conn.halted

Alternatively, you could only invoke the Endpoint's plugs:

conn =
  conn
  |> bypass_through()
  |> get("/")
  |> MyApp.RequireAuthentication.call([])

assert conn.halted

@spec bypass_through(Plug.Conn.t(), module()) :: Plug.Conn.t()

Calls the Endpoint and Router pipelines for the current route.

See bypass_through/1.

@spec bypass_through(Plug.Conn.t(), module(), atom() | list()) :: Plug.Conn.t()

Calls the Endpoint and the given Router pipelines.

See bypass_through/1.

@spec clear_flash(Plug.Conn.t()) :: Plug.Conn.t()

Clears up the flash storage.

Dispatches to the current endpoint.

See dispatch/5 for more information.

Dispatches to the current endpoint.

See dispatch/5 for more information.

@spec delete_req_cookie(Plug.Conn.t(), binary()) :: Plug.Conn.t()

Deletes a request cookie.

Dispatches the connection to the given endpoint.

When invoked via get/3, post/3 and friends, the endpoint is automatically retrieved from the @endpoint module attribute, otherwise it must be given as an argument.

The connection will be configured with the given method, path_or_action and params_or_body.

If path_or_action is a string, it is considered to be the request path and stored as so in the connection. If an atom, it is assumed to be an action and the connection is dispatched to the given action.

Parameters and body

This function, as well as get/3, post/3 and friends, accepts the request body or parameters as last argument:

  get(build_conn(), "/", some: "param")
  get(build_conn(), "/", "some=param&url=encoded")

The allowed values are:

• nil - meaning there is no body

• a binary - containing a request body. For such cases, :headers must be given as option with a content-type

• a map or list - containing the parameters which will automatically set the content-type to multipart. The map or list may contain other lists or maps and all entries will be normalized to string keys

• a struct - unlike other maps, a struct will be passed through as-is without normalizing its entries

@spec ensure_recycled(Plug.Conn.t()) :: Plug.Conn.t()

Ensures the connection is recycled if it wasn't already.

See recycle/1 for more information.

@spec fetch_flash(Plug.Conn.t()) :: Plug.Conn.t()

Fetches the flash storage.

Dispatches to the current endpoint.

See dispatch/5 for more information.

@spec get_flash(Plug.Conn.t()) :: map()

Gets the whole flash storage.

@spec get_flash(Plug.Conn.t(), term()) :: term()

Gets the given key from the flash storage.

Dispatches to the current endpoint.

See dispatch/5 for more information.

@spec html_response(Plug.Conn.t(), status :: integer() | atom()) :: String.t()

Asserts the given status code, that we have an html response and returns the response body if one was set or sent.

Examples

assert html_response(conn, 200) =~ "<html>"

@spec init_test_session(Plug.Conn.t(), map() | keyword()) :: Plug.Conn.t()

Inits a session used exclusively for testing.

@spec json_response(Plug.Conn.t(), status :: integer() | atom()) :: term()

Asserts the given status code, that we have a json response and returns the decoded JSON response if one was set or sent.

Examples

body = json_response(conn, 200)
assert "can't be blank" in body["errors"]

Dispatches to the current endpoint.

See dispatch/5 for more information.

Dispatches to the current endpoint.

See dispatch/5 for more information.

@spec path_params(Plug.Conn.t(), String.t()) :: map()

Returns the matched params of the URL for the %Plug.Conn{}'s router.

Useful for extracting path params out of returned URLs, such as those returned by Phoenix.LiveViewTest's redirected results.

Examples

assert {:error, {:redirect, %{to: "/posts/123" = to}}} = live(conn, "/path")
assert %{id: "123"} = path_params(conn, to)

Dispatches to the current endpoint.

See dispatch/5 for more information.

Dispatches to the current endpoint.

See dispatch/5 for more information.

@spec put_flash(Plug.Conn.t(), term(), term()) :: Plug.Conn.t()

Puts the given value under key in the flash storage.

@spec put_req_cookie(Plug.Conn.t(), binary(), binary()) :: Plug.Conn.t()

Puts a request cookie.

@spec recycle(Plug.Conn.t(), [String.t()]) :: Plug.Conn.t()

Recycles the connection.

Recycling receives a connection and returns a new connection, containing cookies and relevant information from the given one.

This emulates behaviour performed by browsers where cookies returned in the response are available in following requests.

By default, only the headers "accept", "accept-language", and "authorization" are recycled. However, a custom set of headers can be specified by passing a list of strings representing its names as the second argument of the function.

Note recycle/1 is automatically invoked when dispatching to the endpoint, unless the connection has already been recycled.

@spec redirected_params(Plug.Conn.t(), status :: non_neg_integer()) :: map()

Returns the matched params from the URL the connection was redirected to.

Uses the provided %Plug.Conn{}s router matched in the previous request. Raises if the response's location header is not set or if the response does not match the redirect status code (defaults to 302).

Examples

assert redirected_to(conn) =~ "/posts/123"
assert %{id: "123"} = redirected_params(conn)
assert %{id: "123"} = redirected_params(conn, 303)

@spec redirected_to(Plug.Conn.t(), status :: non_neg_integer()) :: String.t()

Returns the location header from the given redirect response.

Raises if the response does not match the redirect status code (defaults to 302).

Examples

assert redirected_to(conn) =~ "/foo/bar"
assert redirected_to(conn, 301) =~ "/foo/bar"
assert redirected_to(conn, :moved_permanently) =~ "/foo/bar"

@spec response(Plug.Conn.t(), status :: integer() | atom()) :: binary()

Asserts the given status code and returns the response body if one was set or sent.

Examples

conn = get(build_conn(), "/")
assert response(conn, 200) =~ "hello world"

@spec response_content_type(Plug.Conn.t(), atom()) :: String.t()

Returns the content type as long as it matches the given format.

Examples

# Assert we have an html response with utf-8 charset
assert response_content_type(conn, :html) =~ "charset=utf-8"

@spec text_response(Plug.Conn.t(), status :: integer() | atom()) :: String.t()

Asserts the given status code, that we have a text response and returns the response body if one was set or sent.

Examples

assert text_response(conn, 200) =~ "hello"

Dispatches to the current endpoint.

See dispatch/5 for more information.