Defines the Phoenix.HTML.Form struct.

Its fields are:

• :source - the data structure given to form_for/4 that implements the form data protocol

• :impl - the module with the form data protocol implementation. This is used to avoid multiple protocol dispatches.

• :id - the id to be used when generating input fields

• :index - the index of the struct in the form

• :name - the name to be used when generating input fields

• :data - the field used to store lookup data

• :params - the parameters associated to this form in case they were sent as part of a previous request

• :hidden - a keyword list of fields that are required for submitting the form behind the scenes as hidden inputs

• :options - a copy of the options given when creating the form via form_for/4 without any form data specific key

• :action - the action the form is meant to submit to

• :errors - a keyword list of errors that associated with the form

Generates a checkbox.

This function is useful for sending boolean values to the server.

Examples

# Assuming form contains a User schema
checkbox(form, :famous)
#=> <input name="user[famous]" type="hidden" value="false">
#=> <input checked="checked" id="user_famous" name="user[famous]" type="checkbox" value="true">

Options

• :checked_value - the value to be sent when the checkbox is checked. Defaults to "true"

• :hidden_input - controls if this function will generate a hidden input to submit the unchecked value or not. Defaults to "true"

• :unchecked_value - the value to be sent when the checkbox is unchecked, Defaults to "false"

• :value - the value used to check if a checkbox is checked or unchecked. The default value is extracted from the form data if available

All other options are forwarded to the underlying HTML tag.

Hidden fields

Because an unchecked checkbox is not sent to the server, Phoenix automatically generates a hidden field with the unchecked_value before the checkbox field to ensure the unchecked_value is sent when the checkbox is not marked. Set hidden_input to false If you don't want to send values from unchecked checkbox to the server.

Generates a color input.

Warning: this feature isn't available in all browsers. Check http://caniuse.com/#feat=input-color for further information.

See text_input/3 for example and docs.

Generates a date input.

Warning: this feature isn't available in all browsers. Check http://caniuse.com/#feat=input-datetime for further information.

See text_input/3 for example and docs.

Generates select tags for date.

Check datetime_select/3 for more information on options and supported values.

Generates a datetime-local input.

Warning: this feature isn't available in all browsers. Check http://caniuse.com/#feat=input-datetime for further information.

See text_input/3 for example and docs.

Generates select tags for datetime.

Examples

# Assuming form contains a User schema
datetime_select form, :born_at
#=> <select id="user_born_at_year" name="user[born_at][year]">...</select> /
#=> <select id="user_born_at_month" name="user[born_at][month]">...</select> /
#=> <select id="user_born_at_day" name="user[born_at][day]">...</select> —
#=> <select id="user_born_at_hour" name="user[born_at][hour]">...</select> :
#=> <select id="user_born_at_min" name="user[born_at][minute]">...</select>

If you want to include the seconds field (hidden by default), pass second: []:

# Assuming form contains a User schema
datetime_select form, :born_at, second: []

If you want to configure the years range:

# Assuming form contains a User schema
datetime_select form, :born_at, year: [options: 1900..2100]

You are also able to configure :month, :day, :hour, :minute and :second. All options given to those keys will be forwarded to the underlying select. See select/4 for more information.

For example, if you are using Phoenix with Gettext and you want to localize the list of months, you can pass :options to the :month key:

# Assuming form contains a User schema
datetime_select form, :born_at, month: [
  options: [
    {gettext("January"), "1"},
    {gettext("February"), "2"},
    {gettext("March"), "3"},
    {gettext("April"), "4"},
    {gettext("May"), "5"},
    {gettext("June"), "6"},
    {gettext("July"), "7"},
    {gettext("August"), "8"},
    {gettext("September"), "9"},
    {gettext("October"), "10"},
    {gettext("November"), "11"},
    {gettext("December"), "12"},
  ]
]

You may even provide your own localized_datetime_select/3 built on top of datetime_select/3:

defp localized_datetime_select(form, field, opts \\ []) do
  opts =
    Keyword.put(opts, :month, options: [
      {gettext("January"), "1"},
      {gettext("February"), "2"},
      {gettext("March"), "3"},
      {gettext("April"), "4"},
      {gettext("May"), "5"},
      {gettext("June"), "6"},
      {gettext("July"), "7"},
      {gettext("August"), "8"},
      {gettext("September"), "9"},
      {gettext("October"), "10"},
      {gettext("November"), "11"},
      {gettext("December"), "12"},
    ])

  datetime_select(form, field, opts)
end

Options

• :value - the value used to select a given option. The default value is extracted from the form data if available

• :default - the default value to use when none was given in :value and none is available in the form data

• :year, :month, :day, :hour, :minute, :second - options passed to the underlying select. See select/4 for more information. The available values can be given in :options.

• :builder - specify how the select can be build. It must be a function that receives a builder that should be invoked with the select name and a set of options. See builder below for more information.

Builder

The generated datetime_select can be customized at will by providing a builder option. Here is an example from EEx:

<%= datetime_select form, :born_at, builder: fn b -> %>
  Date: <%= b.(:day, []) %> / <%= b.(:month, []) %> / <%= b.(:year, []) %>
  Time: <%= b.(:hour, []) %> : <%= b.(:minute, []) %>
<% end %>

Although we have passed empty lists as options (they are required), you could pass any option there and it would be given to the underlying select input.

In practice, we recommend you to create your own helper with your default builder:

def my_datetime_select(form, field, opts \\ []) do
  builder = fn b ->
    assigns = %{b: b}

    ~H"""
    Date: <%= @b.(:day, []) %> / <%= @b.(:month, []) %> / <%= @b.(:year, []) %>
    Time: <%= @b.(:hour, []) %> : <%= @b.(:minute, []) %>
    """
  end

  datetime_select(form, field, [builder: builder] ++ opts)
end

Then you are able to use your own datetime_select throughout your whole application.

Supported date values

The following values are supported as date:

• a map containing the year, month and day keys (either as strings or atoms)
• a tuple with three elements: {year, month, day}
• a string in ISO 8601 format
• nil

Supported time values

The following values are supported as time:

• a map containing the hour and minute keys and an optional second key (either as strings or atoms)
• a tuple with three elements: {hour, min, sec}
• a tuple with four elements: {hour, min, sec, usec}
• nil

Generates an email input.

See text_input/3 for example and docs.

Generates a file input.

It requires the given form to be configured with multipart: true when invoking form_for/4, otherwise it fails with ArgumentError.

See text_input/3 for example and docs.

Specs

form_for(Phoenix.HTML.FormData.t(), String.t(), Keyword.t()) :: t()

form_for(Phoenix.HTML.FormData.t(), String.t(), (t() -> Phoenix.HTML.unsafe())) ::
  Phoenix.HTML.safe()

Generates a form tag with a form builder without an anonymous function.

This functionality exists mostly for integration with Phoenix.LiveView that replaces the anonymous function for explicit closing of the <form> tag:

<%= f = form_for @changeset, Routes.user_path(@conn, :create), opts %>
  Name: <%= text_input f, :name %>
</form>

See the Phoenix.LiveView integration section in module documentation for examples of using this function.

See form_for/4 for the available options.

Specs

form_for(
  Phoenix.HTML.FormData.t(),
  String.t(),
  Keyword.t(),
  (t() -> Phoenix.HTML.unsafe())
) ::
  Phoenix.HTML.safe()

Generates a form tag with a form builder and an anonymous function.

<%= form_for @changeset, Routes.user_path(@conn, :create), fn f -> %>
  Name: <%= text_input f, :name %>
<% end %>

See the module documentation for examples of using this function.

Options

• :as - the server side parameter in which all params for this form will be collected (i.e. as: :user_params would mean all fields for this form will be accessed as conn.params.user_params server side). Automatically inflected when a changeset is given.

• :method - the HTTP method. If the method is not "get" nor "post", an input tag with name _method is generated along-side the form tag. Defaults to "post".

• :multipart - when true, sets enctype to "multipart/form-data". Required when uploading files

• :csrf_token - for "post" requests, the form tag will automatically include an input tag with name _csrf_token. When set to false, this is disabled

• :errors - use this to manually pass a keyword list of errors to the form (for example from conn.assigns[:errors]). This option is only used when a connection is used as the form source and it will make the errors available under f.errors

• :id - the ID of the form attribute. If an ID is given, all form inputs will also be prefixed by the given ID

All other options will be passed as html attributes, such as class: "foo".

Generates a hidden input.

See text_input/3 for example and docs.

Specs

hidden_inputs_for(t()) :: [Phoenix.HTML.safe()]

Generates hidden inputs for the given form.

Converts an attribute/form field into its humanize version.

iex> humanize(:username)
"Username"
iex> humanize(:created_at)
"Created at"
iex> humanize("user_id")
"User"

Specs

input_id(t() | atom(), field()) :: String.t()

Returns an id of a corresponding form field.

The form should either be a Phoenix.HTML.Form emitted by form_for or an atom.

Specs

input_id(t() | atom(), field(), Phoenix.HTML.Safe.t()) :: String.t()

Returns an id of a corresponding form field and value attached to it.

Useful for radio buttons and inputs like multiselect checkboxes.

Specs

input_name(t() | atom(), field()) :: String.t()

Returns a name of a corresponding form field.

The first argument should either be a Phoenix.HTML.Form emitted by form_for or an atom.

Examples

iex> Phoenix.HTML.Form.input_name(:user, :first_name)
"user[first_name]"

Gets the input type for a given field.

If the underlying input type is a :text_field, a mapping could be given to further inflect the input type based solely on the field name. The default mapping is:

%{"url"      => :url_input,
  "email"    => :email_input,
  "search"   => :search_input,
  "password" => :password_input}

Specs

input_validations(t(), field()) :: Keyword.t()

Returns the HTML5 validations that would apply to the given field.

Specs

input_value(t() | atom(), field()) :: term()

Returns a value of a corresponding form field.

The form should either be a Phoenix.HTML.Form emitted by form_for or an atom.

When a form is given, it will lookup for changes and then fallback to parameters and finally fallback to the default struct/map value.

Since the function looks up parameter values too, there is no guarantee that the value will have a certain type. For example, a boolean field will be sent as "false" as a parameter, and this function will return it as is. If you need to normalize the result of input_value, the best option is to call html_escape on it and compare the resulting string.

Specs

inputs_for(t(), field()) :: [t()]

Same as inputs_for(form, field, []).

Specs

inputs_for(t(), field(), Keyword.t()) :: [t()]

inputs_for(t(), field(), (t() -> Phoenix.HTML.unsafe())) :: Phoenix.HTML.safe()

Generate a new form builder for the given parameter in form without an anonymous function.

This functionality exists mostly for integration with Phoenix.LiveView that replaces the anonymous function for returning the generated forms instead.

Keep in mind that this function does not generate hidden inputs automatically like inputs_for/4. To generate them you need to explicit do it by yourself.

<%= f = form_for @changeset, Routes.user_path(@conn, :create), opts %>
  Name: <%= text_input f, :name %>

  <%= for friend_form <- inputs_for(f, :friends) do %>
    # for generating hidden inputs.
    <%= hidden_inputs_for(friend_form) %>
    <%= text_input friend_form, :name %>
  <% end %>
</form>

See inputs_for/4 for the available options.

Specs

inputs_for(t(), field(), Keyword.t(), (t() -> Phoenix.HTML.unsafe())) ::
  Phoenix.HTML.safe()

Generate a new form builder for the given parameter in form.

See the module documentation for examples of using this function.

Options

• :id - the id to be used in the form, defaults to the concatenation of the given field to the parent form id

• :as - the name to be used in the form, defaults to the concatenation of the given field to the parent form name

• :default - the value to use if none is available

• :prepend - the values to prepend when rendering. This only applies if the field value is a list and no parameters were sent through the form.

• :append - the values to append when rendering. This only applies if the field value is a list and no parameters were sent through the form.

• :skip_hidden - skip the automatic rendering of hidden fields to allow for more tight control over the generated markup. You can access form.hidden to generate them manually within the supplied callback.

Generates a label tag.

Useful when wrapping another input inside a label.

Examples

label do
  radio_button :user, :choice, "Choice"
end
#=> <label>...</label>

label class: "control-label" do
  radio_button :user, :choice, "Choice"
end
#=> <label class="control-label">...</label>

Generates a label tag for the given field.

The form should either be a Phoenix.HTML.Form emitted by form_for or an atom.

All given options are forwarded to the underlying tag. A default value is provided for for attribute but can be overridden if you pass a value to the for option. Text content would be inferred from field if not specified as either a function argument or string value in a block.

To wrap a label around an input, see label/1.

Examples

# Assuming form contains a User schema
label(form, :name, "Name")
#=> <label for="user_name">Name</label>

label(:user, :email, "Email")
#=> <label for="user_email">Email</label>

label(:user, :email)
#=> <label for="user_email">Email</label>

label(:user, :email, class: "control-label")
#=> <label for="user_email" class="control-label">Email</label>

label :user, :email do
  "E-mail Address"
end
#=> <label for="user_email">E-mail Address</label>

label :user, :email, "E-mail Address", class: "control-label"
#=> <label class="control-label" for="user_email">E-mail Address</label>

label :user, :email, class: "control-label" do
  "E-mail Address"
end
#=> <label class="control-label" for="user_email">E-mail Address</label>

See label/2.

See label/2.

Generates a select tag with the given options.

Values are expected to be an Enumerable containing two-item tuples (like maps and keyword lists) or any Enumerable where the element will be used both as key and value for the generated select.

Examples

# Assuming form contains a User schema
multiple_select(form, :roles, ["Admin": 1, "Power User": 2])
#=> <select id="user_roles" name="user[roles][]">
#=>   <option value="1">Admin</option>
#=>   <option value="2">Power User</option>
#=> </select>

multiple_select(form, :roles, ["Admin": 1, "Power User": 2], selected: [1])
#=> <select id="user_roles" name="user[roles][]">
#=>   <option value="1" selected="selected">Admin</option>
#=>   <option value="2">Power User</option>
#=> </select>

When working with structs, associations and embeds, you will need to tell Phoenix how to extract the value out of the collection. For example, imagine user.roles is a list of %Role{} structs. You must call it as:

multiple_select(form, :roles, ["Admin": 1, "Power User": 2],
                selected: Enum.map(@user.roles, &(&1.id))

The :selected option will mark the given IDs as selected unless the form is being resubmitted. When resubmitted, it uses the form params as values.

Options

• :selected - the default options to be marked as selected. The values on this list are ignored in case ids have been set as parameters.

All other options are forwarded to the underlying HTML tag.

Generates a number input.

See text_input/3 for example and docs.

Returns options to be used inside a select.

This is useful when building the select by hand. It expects all options and one or more select values.

Examples

options_for_select(["Admin": "admin", "User": "user"], "admin")
#=> <option value="admin" selected="selected">Admin</option>
#=> <option value="user">User</option>

Groups are also supported:

options_for_select(["Europe": ["UK", "Sweden", "France"], ...], nil)
#=> <optgroup label="Europe">
#=>   <option>UK</option>
#=>   <option>Sweden</option>
#=>   <option>France</option>
#=> </optgroup>

Generates a password input.

For security reasons, the form data and parameter values are never re-used in password_input/3. Pass the value explicitly if you would like to set one.

See text_input/3 for example and docs.

Generates a radio button.

Invoke this function for each possible value you want to be sent to the server.

Examples

# Assuming form contains a User schema
radio_button(form, :role, "admin")
#=> <input id="user_role_admin" name="user[role]" type="radio" value="admin">

Options

All options are simply forwarded to the underlying HTML tag.

Generates a range input.

See text_input/3 for example and docs.

Generates a reset input to reset all the form fields to their original state.

All options are forwarded to the underlying input tag.

Examples

reset "Reset"
#=> <input type="reset" value="Reset">

reset "Reset", class: "btn"
#=> <input type="reset" value="Reset" class="btn">

Generates a search input.

See text_input/3 for example and docs.

Generates a select tag with the given options.

options are expected to be an enumerable which will be used to generate each respective option. The enumerable may have:

• keyword lists - each keyword list is expected to have the keys :key and :value. Additional keys such as :disabled may be given to customize the option

• two-item tuples - where the first element is an atom, string or integer to be used as the option label and the second element is an atom, string or integer to be used as the option value

• atom, string or integer - which will be used as both label and value for the generated select

Optgroups

If options is map or keyword list where the first element is a string, atom or integer and the second element is a list or a map, it is assumed the key will be wrapped in an <optgroup> and the value will be used to generate <options> nested under the group.

Examples

# Assuming form contains a User schema
select(form, :age, 0..120)
#=> <select id="user_age" name="user[age]">
#=>   <option value="0">0</option>
#=>   ...
#=>   <option value="120">120</option>
#=> </select>

select(form, :role, ["Admin": "admin", "User": "user"])
#=> <select id="user_role" name="user[role]">
#=>   <option value="admin">Admin</option>
#=>   <option value="user">User</option>
#=> </select>

select(form, :role, [[key: "Admin", value: "admin", disabled: true],
                     [key: "User", value: "user"]])
#=> <select id="user_role" name="user[role]">
#=>   <option value="admin" disabled="disabled">Admin</option>
#=>   <option value="user">User</option>
#=> </select>

You can also pass a prompt:

select(form, :role, ["Admin": "admin", "User": "user"], prompt: "Choose your role")
#=> <select id="user_role" name="user[role]">
#=>   <option value="">Choose your role</option>
#=>   <option value="admin">Admin</option>
#=>   <option value="user">User</option>
#=> </select>

And customize the prompt as any other entry:

select(form, :role, ["Admin": "admin", "User": "user"], prompt: [key: "Choose your role", disabled: true])
#=> <select id="user_role" name="user[role]">
#=>   <option value="" disabled="">Choose your role</option>
#=>   <option value="admin">Admin</option>
#=>   <option value="user">User</option>
#=> </select>

If you want to select an option that comes from the database, such as a manager for a given project, you may write:

select(form, :manager_id, Enum.map(@managers, &{&1.name, &1.id}))
#=> <select id="manager_id" name="project[manager_id]">
#=>   <option value="1">Mary Jane</option>
#=>   <option value="2">John Doe</option>
#=> </select>

Finally, if the values are a list or a map, we use the keys for grouping:

select(form, :country, ["Europe": ["UK", "Sweden", "France"]], ...)
#=> <select id="user_country" name="user[country]">
#=>   <optgroup label="Europe">
#=>     <option>UK</option>
#=>     <option>Sweden</option>
#=>     <option>France</option>
#=>   </optgroup>
#=>   ...
#=> </select>

Options

• :prompt - an option to include at the top of the options. It may be a string or a keyword list of attributes and the :key

• :selected - the default value to use when none was sent as parameter

Be aware that a :multiple option will not generate a correctly functioning multiple select element. Use multiple_select/4 instead.

All other options are forwarded to the underlying HTML tag.

Generates a submit button to send the form.

Examples

submit do: "Submit"
#=> <button type="submit">Submit</button>

Generates a submit button to send the form.

All options are forwarded to the underlying button tag. When called with a do: block, the button tag options come first.

Examples

submit "Submit"
#=> <button type="submit">Submit</button>

submit "Submit", class: "btn"
#=> <button class="btn" type="submit">Submit</button>

submit [class: "btn"], do: "Submit"
#=> <button class="btn" type="submit">Submit</button>

Generates a telephone input.

See text_input/3 for example and docs.

Generates a text input.

The form should either be a Phoenix.HTML.Form emitted by form_for or an atom.

All given options are forwarded to the underlying input, default values are provided for id, name and value if possible.

Examples

# Assuming form contains a User schema
text_input(form, :name)
#=> <input id="user_name" name="user[name]" type="text" value="">

text_input(:user, :name)
#=> <input id="user_name" name="user[name]" type="text" value="">

Generates a textarea input.

All given options are forwarded to the underlying input, default values are provided for id, name and textarea content if possible.

Examples

# Assuming form contains a User schema
textarea(form, :description)
#=> <textarea id="user_description" name="user[description]"></textarea>

New lines

Notice the generated textarea includes a new line after the opening tag. This is because the HTML spec says new lines after tags must be ignored and all major browser implementations do that.

So in order to avoid new lines provided by the user from being ignored when the form is resubmitted, we automatically add a new line before the text area value.

Generates a time input.

Warning: this feature isn't available in all browsers. Check http://caniuse.com/#feat=input-datetime for further information.

Options

• :precision - Allowed values: :minute, :second, :millisecond. Defaults to :minute.

All other options are forwarded. See text_input/3 for example and docs.

Examples

time_input form, :time
#=> <input id="form_time" name="form[time]" type="time" value="23:00">

time_input form, :time, precision: :second
#=> <input id="form_time" name="form[time]" type="time" value="23:00:00">

time_input form, :time, precision: :millisecond
#=> <input id="form_time" name="form[time]" type="time" value="23:00:00.000">

Generates select tags for time.

Check datetime_select/3 for more information on options and supported values.

Generates an url input.

See text_input/3 for example and docs.