Provides router macros to simplify the exposing of Electric shape streams within your Phoenix or Plug application.

Phoenix Integration

When using within a Phoenix application, you should just import the macros defined here in your Phoenix.Router module:

defmodule MyAppWeb.Router do
  use Phoenix.Router

  import Elixir.Phoenix.Sync.Router

  scope "/shapes" do
    sync "/all-todos", MyApp.Todos.Todo

    sync "/pending-todos", MyApp.Todos.Todo,
      where: "completed = false"
  end
end

Plug Integration

Within your Plug.Router module, use Elixir.Phoenix.Sync.Router and then add your sync routes:

defmodule MyApp.Plug.Router do
  use Plug.Router, copy_opts_to_assign: :options
  use Elixir.Phoenix.Sync.Router

  plug :match
  plug :dispatch

  sync "/shapes/all-todos", MyApp.Todos.Todo

  sync "/shapes/pending-todos", MyApp.Todos.Todo,
    where: "completed = false"
end

You must use the copy_opts_to_assign option in Plug.Router in order for the sync macro to get the configuration defined in your application.ex start/2 callback.

Transforms

You can add a transform function to your shapes as explained in Phoenix.Sync.shape/2 but, because sync/2 and sync/3 are macros, you need to use the {module, function, args} form when declaring the transform function.

  defmodule MyApp.Router do
    use Plug.Router, copy_opts_to_assign: :options

    # ...

    sync "/shapes/pending-todos", MyApp.Todos.Todo,
      where: "completed = false",
      transform: {MyApp.Router, :transform_todo, ["[PENDING]"]}

    def transform_todo(msg, prefix) do
      Map.update!(msg, "values", fn todo ->
        Map.put(todo, "title", prefix <> " " <> todo["title"])
      end)
    end
  end