@spec assign(t(), atom(), term()) :: t()

Assigns a value to a key in the connection.

The "assigns" storage is meant to be used to store values in the connection so that other plugs in your plug pipeline can access them. The assigns storage is a map.

examples

Examples

iex> conn.assigns[:hello]
nil
iex> conn = assign(conn, :hello, :world)
iex> conn.assigns[:hello]
:world

@spec chunk(t(), body()) :: {:ok, t()} | {:error, term()} | no_return()

Sends a chunk as part of a chunked response.

It expects a connection with state :chunked as set by send_chunked/2. It returns {:ok, conn} in case of success, otherwise {:error, reason}.

To stream data use Enum.reduce_while/3 instead of Enum.into/2. Enum.reduce_while/3 allows aborting the execution if chunk/2 fails to deliver the chunk of data.

example

Example

Enum.reduce_while(~w(each chunk as a word), conn, fn (chunk, conn) ->
  case Plug.Conn.chunk(conn, chunk) do
    {:ok, conn} ->
      {:cont, conn}
    {:error, :closed} ->
      {:halt, conn}
  end
end)

@spec clear_session(t()) :: t()

Clears the entire session.

This function removes every key from the session, clearing the session.

Note that, even if clear_session/1 is used, the session is still sent to the client. If the session should be effectively dropped, configure_session/2 should be used with the :drop option set to true.

@spec configure_session(t(), Keyword.t()) :: t()

Configures the session.

options

Options

• :renew - When true, generates a new session id for the cookie
• :drop - When true, drops the session, a session cookie will not be included in the response
• :ignore - When true, ignores all changes made to the session in this request cycle

examples

Examples

configure_session(conn, renew: true)

@spec delete_req_header(t(), binary()) :: t()

Deletes a request header if present.

Raises a Plug.Conn.AlreadySentError if the connection has already been :sent, :chunked or :upgraded.

examples

Examples

Plug.Conn.delete_req_header(conn, "content-type")

@spec delete_resp_cookie(t(), binary(), Keyword.t()) :: t()

Deletes a response cookie.

Deleting a cookie requires the same options as to when the cookie was put. Check put_resp_cookie/4 for more information.

@spec delete_resp_header(t(), binary()) :: t()

Deletes a response header if present.

Raises a Plug.Conn.AlreadySentError if the connection has already been :sent, :chunked or :upgraded.

examples

Examples

Plug.Conn.delete_resp_header(conn, "content-type")

@spec delete_session(t(), String.t() | atom()) :: t()

Deletes key from session.

The key can be a string or an atom, where atoms are automatically converted to strings.

@spec fetch_cookies(t(), Keyword.t()) :: t()

Fetches cookies from the request headers.

options

Options

• :signed - a list of one or more cookies that are signed and must be verified accordingly

• :encrypted - a list of one or more cookies that are encrypted and must be decrypted accordingly

See put_resp_cookie/4 for more information.

@spec fetch_query_params(t(), Keyword.t()) :: t()

Fetches query parameters from the query string.

Params are decoded as "x-www-form-urlencoded" in which key/value pairs are separated by & and keys are separated from values by =.

This function does not fetch parameters from the body. To fetch parameters from the body, use the Plug.Parsers plug.

options

Options

• :length - the maximum query string length. Defaults to 1_000_000 bytes. Keep in mind the webserver you are using may have a more strict limit. For example, for the Cowboy webserver, please read.

• :validate_utf8 - boolean that tells whether or not to validate the keys and values of the decoded query string are UTF-8 encoded. Defaults to true.

@spec fetch_session(t(), Keyword.t()) :: t()

Fetches the session from the session store. Will also fetch cookies.

@spec get_http_protocol(t()) :: Plug.Conn.Adapter.http_protocol()

Returns the HTTP protocol and version.

examples

Examples

iex> get_http_protocol(conn)
:"HTTP/1.1"

@spec get_peer_data(t()) :: Plug.Conn.Adapter.peer_data()

Returns the request peer data if one is present.

@spec get_req_header(t(), binary()) :: [binary()]

Returns the values of the request header specified by key.

examples

Examples

iex> get_req_header(conn, "accept")
["application/json"]

@spec get_resp_header(t(), binary()) :: [binary()]

Returns the values of the response header specified by key.

examples

Examples

iex> conn = %{conn | resp_headers: [{"content-type", "text/plain"}]}
iex> get_resp_header(conn, "content-type")
["text/plain"]

@spec get_session(t()) :: %{optional(String.t()) => any()}

Returns the whole session.

Although get_session/2 and put_session/3 allow atom keys, they are always normalized to strings. So this function always returns a map with string keys.

Raises if the session was not yet fetched.

@spec get_session(t(), String.t() | atom()) :: any()

Returns session value for the given key. If key is not set, nil is returned.

The key can be a string or an atom, where atoms are automatically converted to strings.

@spec halt(t()) :: t()

Halts the Plug pipeline by preventing further plugs downstream from being invoked. See the docs for Plug.Builder for more information on halting a Plug pipeline.

@spec inform(t(), status(), Keyword.t()) :: t()

Sends an informational response to the client.

An informational response, such as an early hint, must happen prior to a response being sent. If an informational request is attempted after a response is sent then a Plug.Conn.AlreadySentError will be raised. Only status codes from 100-199 are valid.

To use inform for early hints send one or more informs with a status of 103.

If the adapter does not support informational responses then this is a noop.

Most HTTP/1.1 clients do not properly support informational responses but some proxies require it to support server push for HTTP/2. You can call get_http_protocol/1 to retrieve the protocol and version.

@spec inform!(t(), status(), Keyword.t()) :: t()

Sends an information response to a client but raises if the adapter does not support inform.

See inform/3 for more information.

@spec merge_assigns(t(), Keyword.t()) :: t()

Assigns multiple values to keys in the connection.

Equivalent to multiple calls to assign/3.

examples

Examples

iex> conn.assigns[:hello]
nil
iex> conn = merge_assigns(conn, hello: :world)
iex> conn.assigns[:hello]
:world

@spec merge_private(t(), Keyword.t()) :: t()

Assigns multiple private keys and values in the connection.

Equivalent to multiple put_private/3 calls.

examples

Examples

iex> conn.private[:my_plug_hello]
nil
iex> conn = merge_private(conn, my_plug_hello: :world)
iex> conn.private[:my_plug_hello]
:world

@spec merge_req_headers(t(), Enum.t()) :: t()

Merges a series of request headers into the connection.

The "host" header will be overridden by conn.host and should not be set with this method. Instead, do %Plug.Conn{conn | host: value}.

Because header keys are case-insensitive in both HTTP/1.1 and HTTP/2, it is recommended for header keys to be in lowercase, to avoid sending duplicate keys in a request. Additionally, requests with mixed-case headers served over HTTP/2 are not considered valid by common clients, resulting in dropped requests. As a convenience, when using the Plug.Adapters.Conn.Test adapter, any headers that aren't lowercase will raise a Plug.Conn.InvalidHeaderError.

example

Example

Plug.Conn.merge_req_headers(conn, [{"accept", "text/plain"}, {"X-1337", "5P34K"}])

@spec merge_resp_headers(t(), Enum.t()) :: t()

Merges a series of response headers into the connection.

It is recommended for header keys to be in lowercase, to avoid sending duplicate keys in a request. Additionally, responses with mixed-case headers served over HTTP/2 are not considered valid by common clients, resulting in dropped responses. As a convenience, when using the Plug.Adapters.Conn.Test adapter, any headers that aren't lowercase will raise a Plug.Conn.InvalidHeaderError.

example

Example

Plug.Conn.merge_resp_headers(conn, [{"content-type", "text/plain"}, {"X-1337", "5P34K"}])

@spec prepend_req_headers(t(), headers()) :: t()

Prepends the list of headers to the connection request headers.

Similar to put_req_header this functions adds a new request header (key) but rather than replacing the existing one it prepends another header with the same key.

The "host" header will be overridden by conn.host and should not be set with this method. Instead, do %Plug.Conn{conn | host: value}.

Because header keys are case-insensitive in both HTTP/1.1 and HTTP/2, it is recommended for header keys to be in lowercase, to avoid sending duplicate keys in a request. Additionally, requests with mixed-case headers served over HTTP/2 are not considered valid by common clients, resulting in dropped requests. As a convenience, when using the Plug.Adapters.Conn.Test adapter, any headers that aren't lowercase will raise a Plug.Conn.InvalidHeaderError.

Raises a Plug.Conn.AlreadySentError if the connection has already been :sent, :chunked or :upgraded.

examples

Examples

Plug.Conn.prepend_req_headers(conn, [{"accept", "application/json"}])

@spec prepend_resp_headers(t(), headers()) :: t()

Prepends the list of headers to the connection response headers.

Similar to put_resp_header this functions adds a new response header (key) but rather than replacing the existing one it prepends another header with the same key.

It is recommended for header keys to be in lowercase, to avoid sending duplicate keys in a request. Additionally, responses with mixed-case headers served over HTTP/2 are not considered valid by common clients, resulting in dropped responses. As a convenience, when using the Plug.Adapters.Conn.Test adapter, any headers that aren't lowercase will raise a Plug.Conn.InvalidHeaderError.

Raises a Plug.Conn.AlreadySentError if the connection has already been :sent, :chunked or :upgraded.

Raises a Plug.Conn.InvalidHeaderError if the header value contains control feed (\r) or newline (\n) characters.

examples

Examples

Plug.Conn.prepend_resp_headers(conn, [{"content-type", "application/json"}])

@spec push(t(), String.t(), Keyword.t()) :: t()

Pushes a resource to the client.

Server pushes must happen prior to a response being sent. If a server push is attempted after a response is sent then a Plug.Conn.AlreadySentError will be raised.

If the adapter does not support server push then this is a noop.

Note that certain browsers (such as Google Chrome) will not accept a pushed resource if your certificate is not trusted. In the case of Chrome this means a valid cert with a SAN. See https://www.chromestatus.com/feature/4981025180483584

@spec push!(t(), String.t(), Keyword.t()) :: t()

Pushes a resource to the client but raises if the adapter does not support server push.

@spec put_private(t(), atom(), term()) :: t()

Assigns a new private key and value in the connection.

This storage is meant to be used by libraries and frameworks to avoid writing to the user storage (the :assigns field). It is recommended for libraries/frameworks to prefix the keys with the library name.

For example, if a plug called my_plug needs to store a :hello key, it would store it as :my_plug_hello:

iex> conn.private[:my_plug_hello]
nil
iex> conn = put_private(conn, :my_plug_hello, :world)
iex> conn.private[:my_plug_hello]
:world

@spec put_req_header(t(), binary(), binary()) :: t()

Adds a new request header (key) if not present, otherwise replaces the previous value of that header with value.

The "host" header will be overridden by conn.host and should not be set with this method. Instead, do %Plug.Conn{conn | host: value}.

Because header keys are case-insensitive in both HTTP/1.1 and HTTP/2, it is recommended for header keys to be in lowercase, to avoid sending duplicate keys in a request. Additionally, requests with mixed-case headers served over HTTP/2 are not considered valid by common clients, resulting in dropped requests. As a convenience, when using the Plug.Adapters.Conn.Test adapter, any headers that aren't lowercase will raise a Plug.Conn.InvalidHeaderError.

Raises a Plug.Conn.AlreadySentError if the connection has already been :sent, :chunked or :upgraded.

examples

Examples

Plug.Conn.put_req_header(conn, "accept", "application/json")

@spec put_resp_content_type(t(), binary(), binary() | nil) :: t()

Sets the value of the "content-type" response header taking into account the charset.

If charset is nil, the value of the "content-type" response header won't specify a charset.

examples

Examples

iex> conn = put_resp_content_type(conn, "application/json")
iex> get_resp_header(conn, "content-type")
["application/json; charset=utf-8"]

@spec put_resp_cookie(t(), binary(), any(), Keyword.t()) :: t()

Puts a response cookie in the connection.

If the :sign or :encrypt flag are given, then the cookie value can be any term.

If the cookie is not signed nor encrypted, then the value must be a binary. Note the value is not automatically escaped. Therefore if you want to store values with non-alphanumeric characters, you must either sign or encrypt the cookie or consider explicitly escaping the cookie value by using a function such as Base.encode64(value, padding: false) when writing and Base.decode64(encoded, padding: false) when reading the cookie. It is important for padding to be disabled since = is not a valid character in cookie values.

signing-and-encrypting-cookies

Signing and encrypting cookies

This function allows you to automatically sign and encrypt cookies. When signing or encryption is enabled, then any Elixir value can be stored in the cookie (except anonymous functions for security reasons). Once a value is signed or encrypted, you must also call fetch_cookies/2 with the name of the cookies that are either signed or encrypted.

To sign, you would do:

put_resp_cookie(conn, "my-cookie", %{user_id: user.id}, sign: true)

and then:

fetch_cookies(conn, signed: ~w(my-cookie))

To encrypt, you would do:

put_resp_cookie(conn, "my-cookie", %{user_id: user.id}, encrypt: true)

and then:

fetch_cookies(conn, encrypted: ~w(my-cookie))

By default a signed or encrypted cookie is only valid for a day, unless a :max_age is specified.

The signing and encryption keys are derived from the connection's secret_key_base using a salt that is built by appending "_cookie" to the cookie name. Care should be taken not to derive other keys using this value as the salt. Similarly do not use the same cookie name to store different values with distinct purposes.

options

Options

• :domain - the domain the cookie applies to
• :max_age - the cookie max-age, in seconds. Providing a value for this option will set both the max-age and expires cookie attributes. Unset by default, which means the browser will default to a session cookie.
• :path - the path the cookie applies to
• :http_only - when false, the cookie is accessible beyond HTTP
• :secure - if the cookie must be sent only over https. Defaults to true when the connection is HTTPS
• :extra - string to append to cookie. Use this to take advantage of non-standard cookie attributes.
• :sign - when true, signs the cookie
• :encrypt - when true, encrypts the cookie
• :same_site - set the cookie SameSite attribute to a string value. If no string value is set, the attribute is omitted.

@spec put_resp_header(t(), binary(), binary()) :: t()

Adds a new response header (key) if not present, otherwise replaces the previous value of that header with value.

Because header keys are case-insensitive in both HTTP/1.1 and HTTP/2, it is recommended for header keys to be in lowercase, to avoid sending duplicate keys in a request. Additionally, responses with mixed-case headers served over HTTP/2 are not considered valid by common clients, resulting in dropped responses. As a convenience, when using the Plug.Adapters.Conn.Test adapter, any headers that aren't lowercase will raise a Plug.Conn.InvalidHeaderError.

Raises a Plug.Conn.AlreadySentError if the connection has already been :sent, :chunked or :upgraded.

Raises a Plug.Conn.InvalidHeaderError if the header value contains control feed (\r) or newline (\n) characters.

examples

Examples

Plug.Conn.put_resp_header(conn, "content-type", "application/json")

@spec put_session(t(), String.t() | atom(), any()) :: t()

Puts the specified value in the session for the given key.

The key can be a string or an atom, where atoms are automatically converted to strings. Can only be invoked on unsent conns. Will raise otherwise.

@spec put_status(t(), status()) :: t()

Stores the given status code in the connection.

The status code can be nil, an integer, or an atom. The list of allowed atoms is available in Plug.Conn.Status.

Raises a Plug.Conn.AlreadySentError if the connection has already been :sent, :chunked or :upgraded.

examples

Examples

Plug.Conn.put_status(conn, :not_found)
Plug.Conn.put_status(conn, 200)

@spec read_body(t(), Keyword.t()) ::
  {:ok, binary(), t()} | {:more, binary(), t()} | {:error, term()}

Reads the request body.

This function reads a chunk of the request body up to a given length (specified by the :length option). If there is more data to be read, then {:more, partial_body, conn} is returned. Otherwise {:ok, body, conn} is returned. In case of an error reading the socket, {:error, reason} is returned as per :gen_tcp.recv/2.

Like all functions in this module, the conn returned by read_body must be passed to the next stage of your pipeline and should not be ignored.

In order to, for instance, support slower clients you can tune the :read_length and :read_timeout options. These specify how much time should be allowed to pass for each read from the underlying socket.

Because the request body can be of any size, reading the body will only work once, as Plug will not cache the result of these operations. If you need to access the body multiple times, it is your responsibility to store it. Finally keep in mind some plugs like Plug.Parsers may read the body, so the body may be unavailable after being accessed by such plugs.

This function is able to handle both chunked and identity transfer-encoding by default.

options

Options

• :length - sets the maximum number of bytes to read from the body on every call, defaults to 8_000_000 bytes
• :read_length - sets the amount of bytes to read at one time from the underlying socket to fill the chunk, defaults to 1_000_000 bytes
• :read_timeout - sets the timeout for each socket read, defaults to 15_000 milliseconds

The values above are not meant to be exact. For example, setting the length to 8_000_000 may end up reading some hundred bytes more from the socket until we halt.

examples

Examples

{:ok, body, conn} = Plug.Conn.read_body(conn, length: 1_000_000)

@spec read_part_body(t(), Keyword.t()) ::
  {:ok, binary(), t()} | {:more, binary(), t()} | {:done, t()}

Reads the body of a multipart request.

Returns {:ok, body, conn} if all body has been read, {:more, binary, conn} otherwise, and {:done, conn} if there is no more body.

It accepts the same options as read_body/2.

@spec read_part_headers(t(), Keyword.t()) :: {:ok, headers(), t()} | {:done, t()}

Reads the headers of a multipart request.

It returns {:ok, headers, conn} with the headers or {:done, conn} if there are no more parts.

Once read_part_headers/2 is invoked, you may call read_part_body/2 to read the body associated to the headers. If read_part_headers/2 is called instead, the body is automatically skipped until the next part headers.

options

Options

• :length - sets the maximum number of bytes to read from the body for each chunk, defaults to 64_000 bytes
• :read_length - sets the amount of bytes to read at one time from the underlying socket to fill the chunk, defaults to 64_000 bytes
• :read_timeout - sets the timeout for each socket read, defaults to 5_000 milliseconds

@spec register_before_send(t(), (t() -> t())) :: t()

Registers a callback to be invoked before the response is sent.

Callbacks are invoked in the reverse order they are defined (callbacks defined first are invoked last).

examples

Examples

To log the status of response being sent:

require Logger

Plug.Conn.register_before_send(conn, fn conn ->
  Logger.info("Sent a #{conn.status} response")
  conn
end)

Returns the full request URL.

@spec resp(t(), status(), body()) :: t()

Sets the response to the given status and body.

It sets the connection state to :set (if not already :set) and raises Plug.Conn.AlreadySentError if it was already :sent, :chunked or :upgraded.

If you also want to send the response, use send_resp/1 after this or use send_resp/3.

The status can be an integer, an atom, or nil. See Plug.Conn.Status for more information.

examples

Examples

Plug.Conn.resp(conn, 404, "Not found")

@spec send_chunked(t(), status()) :: t() | no_return()

Sends the response headers as a chunked response.

It expects a connection that has not been :sent or :upgraded yet and sets its state to :chunked afterwards. Otherwise, raises Plug.Conn.AlreadySentError. After send_chunked/2 is called, chunks can be sent to the client via the chunk/2 function.

HTTP/2 does not support chunking and will instead stream the response without a transfer encoding. When using HTTP/1.1, the Cowboy adapter will stream the response instead of emitting chunks if the content-length header has been set before calling send_chunked/2.

@spec send_file(
  t(),
  status(),
  filename :: binary(),
  offset :: integer(),
  length :: integer() | :all
) ::
  t() | no_return()

Sends a file as the response body with the given status and optionally starting at the given offset until the given length.

If available, the file is sent directly over the socket using the operating system sendfile operation.

It expects a connection that has not been :sent, :chunked or :upgraded yet and sets its state to :file afterwards. Otherwise raises Plug.Conn.AlreadySentError.

examples

Examples

Plug.Conn.send_file(conn, 200, "README.md")

@spec send_resp(t()) :: t() | no_return()

Sends a response to the client.

It expects the connection state to be :set, otherwise raises an ArgumentError for :unset connections or a Plug.Conn.AlreadySentError for already :sent, :chunked or :upgraded connections.

At the end sets the connection state to :sent.

Note that this function does not halt the connection, so if subsequent plugs try to send another response, it will error out. Use halt/1 after this function if you want to halt the plug pipeline.

examples

Examples

conn
|> Plug.Conn.resp(404, "Not found")
|> Plug.Conn.send_resp()

@spec send_resp(t(), status(), body()) :: t() | no_return()

Sends a response with the given status and body.

This is equivalent to setting the status and the body and then calling send_resp/1.

Note that this function does not halt the connection, so if subsequent plugs try to send another response, it will error out. Use halt/1 after this function if you want to halt the plug pipeline.

examples

Examples

Plug.Conn.send_resp(conn, 404, "Not found")

@spec update_req_header(t(), binary(), binary(), (binary() -> binary())) :: t()

Updates a request header if present, otherwise it sets it to an initial value.

Raises a Plug.Conn.AlreadySentError if the connection has already been :sent, :chunked or :upgraded.

Only the first value of the header key is updated if present.

examples

Examples

Plug.Conn.update_req_header(
  conn,
  "accept",
  "application/json; charset=utf-8",
  &(&1 <> "; charset=utf-8")
)

@spec update_resp_header(t(), binary(), binary(), (binary() -> binary())) :: t()

Updates a response header if present, otherwise it sets it to an initial value.

Raises a Plug.Conn.AlreadySentError if the connection has already been :sent, :chunked or :upgraded.

Only the first value of the header key is updated if present.

examples

Examples

Plug.Conn.update_resp_header(
  conn,
  "content-type",
  "application/json; charset=utf-8",
  &(&1 <> "; charset=utf-8")
)

@spec upgrade_adapter(t(), atom(), term()) :: t()

Request a protocol upgrade from the underlying adapter.

The precise semantics of an upgrade are deliberately left unspecified here in order to support arbitrary upgrades, even to protocols which may not exist today. The primary intent of this function is solely to allow an application to issue an upgrade request, not to manage how a given protocol upgrade takes place or what APIs the application must support in order to serve this updated protocol. For details in this regard, consult the documentation of the underlying adapter (such a Plug.Cowboy or Bandit).

Takes an argument describing the requested upgrade (for example, :websocket), and an argument which contains arbitrary data which the underlying adapter is expected to interpret in the context of the requested upgrade.

If the upgrade is accepted by the adapter, the returned Plug.Conn will have a state of :upgraded. This state is considered equivalently to a 'sent' state, and is subject to the same limitation on subsequent mutating operations. Note that there is no guarantee or expectation that the actual upgrade process has succeeded, or event that it is undertaken within this function; it is entirely possible (likely, even) that the server will only do the actual upgrade later in the connection lifecycle.

If the adapter does not support the requested protocol this function will raise an ArgumentError. The underlying adapter may also signal errors in the provided arguments by raising; consult the corresponding adapter documentation for details.