Behavior and struct for content providers that display information about vertices.

Content providers decide whether they should be displayed for a given vertex and lens, and can provide either static content (markdown, mermaid, graphviz) or implement a full LiveView for interactive content.

Static Content Providers

Static content providers implement the render_static/2 callback:

defmodule MyApp.CustomContent do
  @behaviour Clarity.Content

  @impl Clarity.Content
  def name, do: "Custom Analysis"

  @impl Clarity.Content
  def description, do: "Provides custom analysis for resources"

  @impl Clarity.Content
  def applies?(%Vertex.Ash.Resource{}, _lens), do: true
  def applies?(_vertex, _lens), do: false

  @impl Clarity.Content
  def render_static(vertex, _lens) do
    {:markdown, "# Analysis for #{inspect(vertex)}"}
  end
end

LiveView Content Providers

Content providers can also be LiveView modules. Simply implement Phoenix.LiveView alongside the Clarity.Content behavior:

defmodule MyApp.InteractiveContent do
  use Phoenix.LiveView
  @behaviour Clarity.Content

  @impl Clarity.Content
  def name, do: "Interactive Dashboard"

  @impl Clarity.Content
  def description, do: "Interactive visualization"

  @impl Clarity.Content
  def applies?(%Vertex.Ash.Resource{}, _lens), do: true
  def applies?(_vertex, _lens), do: false

  @impl Phoenix.LiveView
  def mount(_params, session, socket) do
    vertex = session["vertex"]
    lens = session["lens"]
    {:ok, assign(socket, vertex: vertex, lens: lens)}
  end

  @impl Phoenix.LiveView
  def render(assigns) do
    ~H"""
    <div>Interactive content for {@vertex}</div>
    """
  end
end

Configuration

Content provider configuration is managed by Clarity.Config. See the documentation for Clarity.Config for detailed configuration options and examples.