Macro used to define a process manager.

A process manager is responsible for coordinating one or more aggregates. It handles events and dispatches commands in response. Process managers have state that can be used to track which aggregates are being orchestrated.

Process managers can be used to implement long-running transactions by following the saga pattern. This is a sequence of commands and their compensating commands which can be used to rollback on failure.

Use the Commanded.ProcessManagers.ProcessManager macro in your process manager module and implement the callback functions defined in the behaviour:

• interested?/1
• interested?/2
• handle/2
• handle/3
• apply/2
• after_command/2
• after_command/3
• error/3

Please read the Process managers guide for more detail.

Example

defmodule ExampleProcessManager do
  use Commanded.ProcessManagers.ProcessManager,
    application: ExampleApp,
    name: "ExampleProcessManager"

  defstruct []

  def interested?(%AnEvent{uuid: uuid}), do: {:start, uuid}

  def interested?(%AnotherEvent{}, metadata),
    do: {:continue, Map.fetch!(metadata, :correlation_id)}

  def handle(%ExampleProcessManager{}, %ExampleEvent{}) do
    [
      %ExampleCommand{}
    ]
  end

  def handle(%ExampleProcessManager{}, %AnotherEvent{}, _metadata) do
    [
      %AnotherCommand{}
    ]
  end

  def after_command(%ExampleProcessManager{}, %ExampleCommand{}) do
    :continue
  end

  def after_command(%ExampleProcessManager{}, %AnotherCommand{}, _metadata) do
    :stop
  end

  def error({:error, failure}, %ExampleEvent{}, _failure_context) do
    # Retry, skip, ignore, or stop process manager on error handling event
    :skip
  end

  def error({:error, failure}, %ExampleCommand{}, _failure_context) do
    # Retry, skip, ignore, or stop process manager on error dispatching command
    :skip
  end
end

Start the process manager (or configure as a worker inside a Supervisor)

{:ok, process_manager} = ExampleProcessManager.start_link()

init/1 callback

An init/1 function can be defined in your process manager which is used to provide runtime configuration. This callback function must return {:ok, config} with the updated config.

Example

The init/1 function is used to define the process manager's application and name based upon a value provided at runtime:

defmodule ExampleProcessManager do
  use Commanded.ProcessManagers.ProcessManager

  def init(config) do
    {tenant, config} = Keyword.pop!(config, :tenant)

    config =
      config
      |> Keyword.put(:application, Module.concat([ExampleApp, tenant]))
      |> Keyword.put(:name, Module.concat([__MODULE__, tenant]))

    {:ok, config}
  end
end

Usage:

{:ok, _pid} = ExampleProcessManager.start_link(tenant: :tenant1)

Error handling

You can define an error/3 callback function to handle any errors or exceptions during event handling or returned by commands dispatched from your process manager. The function is passed the error (e.g. {:error, :failure}), the failed event or command, and a failure context. See Commanded.ProcessManagers.FailureContext for details.

Use pattern matching on the error and/or failed event/command to explicitly handle certain errors, events, or commands. You can choose to retry, skip, ignore, or stop the process manager after a command dispatch error.

The default behaviour, if you don't provide an error/3 callback, is to stop the process manager using the exact error reason returned from the event handler function or command dispatch. You should supervise your process managers to ensure they are restarted on error.

Example

defmodule ExampleProcessManager do
  use Commanded.ProcessManagers.ProcessManager,
    application: ExampleApp,
    name: "ExampleProcessManager"

  # stop process manager after three failures
  def error({:error, _failure}, _failed_command, %{context: %{failures: failures}})
    when failures >= 2
  do
    {:stop, :too_many_failures}
  end

  # retry command, record failure count in context map
  def error({:error, _failure}, _failed_command, %{context: context}) do
    context = Map.update(context, :failures, 1, fn failures -> failures + 1 end)

    {:retry, context}
  end
end

Idle process timeouts

Each instance of a process manager will run indefinitely once started. To reduce memory usage you can configure an idle timeout, in milliseconds, after which the process will be shutdown.

The process will be restarted whenever another event is routed to it and its state will be rehydrated from the instance snapshot.

Example

defmodule ExampleProcessManager do
  use Commanded.ProcessManagers.ProcessManager,
    application: ExampleApp,
    name: "ExampleProcessManager"
    idle_timeout: :timer.minutes(10)
end

Event handling timeout

You can configure a timeout for event handling to ensure that events are processed in a timely manner without getting stuck.

An event_timeout option, defined in milliseconds, may be provided when using the Commanded.ProcessManagers.ProcessManager macro at compile time:

defmodule TransferMoneyProcessManager do
  use Commanded.ProcessManagers.ProcessManager,
    application: ExampleApp,
    name: "TransferMoneyProcessManager",
    router: BankRouter,
    event_timeout: :timer.minutes(10)
end

Or may be configured when starting a process manager:

{:ok, _pid} = TransferMoneyProcessManager.start_link(
  event_timeout: :timer.hours(1)
)

After the timeout has elapsed, indicating the process manager has not processed an event within the configured period, the process manager is stopped. The process manager will be restarted if supervised and will retry the event, this should help resolve transient problems.

Consistency

For each process manager you can define its consistency, as one of either :strong or :eventual.

This setting is used when dispatching commands and specifying the consistency option.

When you dispatch a command using :strong consistency, after successful command dispatch the process will block until all process managers configured to use :strong consistency have processed the domain events created by the command.

The default setting is :eventual consistency. Command dispatch will return immediately upon confirmation of event persistence, not waiting for any process managers.

Example

Define a process manager with :strong consistency:

defmodule ExampleProcessManager do
  use Commanded.ProcessManagers.ProcessManager,
    application: ExampleApp,
    name: "ExampleProcessManager",
    consistency: :strong
end

Dynamic application

A process manager's application can be provided as an option to start_link/1. This can be used to start the same process manager multiple times, each using a separate Commanded application and event store.

Example

Start an process manager for each tenant in a multi-tenanted app, guaranteeing that the data and processing remains isolated between tenants.

for tenant <- [:tenant1, :tenant2, :tenant3] do
  {:ok, _app} = MyApp.Application.start_link(name: tenant)
  {:ok, _handler} = ExampleProcessManager.start_link(application: tenant)
end

Typically you would start the event handlers using a supervisor:

children =
  for tenant <- [:tenant1, :tenant2, :tenant3] do
    {ExampleProcessManager, application: tenant}
  end

Supervisor.start_link(children, strategy: :one_for_one)

The above example requires three named Commanded applications to have already been started.

Telemetry

• [:commanded, :process_manager, :handle, :start]

  • Description: Emitted when a process manager starts handling an event
  • Measurements: %{system_time: integer()}
  • Metadata: %{application: Commanded.Application.t(), process_manager_name: String.t() | Inspect.t(), process_manager_module: module(), process_state: term(), process_uuid: String.t()}

• [:commanded, :process_manager, :handle, :stop]

  • Description: Emitted when a process manager stops handling an event
  • Measurements: %{duration: non_neg_integer()}
  • Metadata: %{application: Commanded.Application.t(), commands: [struct()], error: nil | any(), process_manager_name: String.t() | Inspect.t(), process_manager_module: module(), process_state: term(), process_uuid: String.t()}

• [:commanded, :process_manager, :handle, :exception]

  • Description: Emitted when a process manager raises an exception
  • Measurements: %{duration: non_neg_integer()}
  • Metadata: %{application: Commanded.Application.t(), process_manager_name: String.t() | Inspect.t(), process_manager_module: module(), process_state: term(), process_uuid: String.t(), kind: :throw | :error | :exit, reason: any(), stacktrace: list()}