Ecto.Schema

Indicates a one-to-one association with another model.

The current model belongs to zero or one records of the other model. The other model often has a has_one or a has_many field with the reverse association.

You should use belongs_to in the table that contains the foreign key. Imagine a company <-> manager relationship. If the company contains the manager_id in the underlying database table, we say the company belongs to manager.

In fact, when you invoke this macro, a field with the name of foreign key is automatically defined in the schema for you.

Options

• :foreign_key - Sets the foreign key field name, defaults to the name of the association suffixed by _id. For example, belongs_to :company will define foreign key of :company_id

• :references - Sets the key on the other model to be used for the association, defaults to: :id

• :define_field - When false, does not automatically define a :foreign_key field, implying the user is defining the field manually elsewhere

• :type - Sets the type of automatically defined :foreign_key. Defaults to: :integer and be set per schema via @foreign_key_type

• :defaults - Default values to use when building the association

All other options are forwarded to the underlying foreign key definition and therefore accept the same options as field/3.

Examples

defmodule Comment do
  use Ecto.Model
  schema "comments" do
    belongs_to :post, Post
  end
end

# The post can come preloaded on the comment record
[comment] = Repo.all(from(c in Comment, where: c.id == 42, preload: :post))
comment.post #=> %Post{...}

Polymorphic associations

One common use case for belongs to associations is to handle polymorphism. For example, imagine you have defined a Comment model and you wish to use it for commenting on both tasks and posts.

Some abstractions would force you to define some sort of polymorphic association with two fields in your database:

* commentable_type
* commentable_id

The problem with this approach is that it breaks references in the database. You can’t use foreign keys and it is very inneficient both in terms of query time and storage.

In Ecto, we have two ways to solve this issue. The simplest one is to define multiple fields in the Comment model, one for each association:

* task_id
* post_id

Unless you have dozens of columns, this is simpler for the developer, more DB friendly and more efficient on all aspects.

Alternatively, because Ecto does not tie a model to a given table, we can use separate tables for each association. Let’s start over and define a new Comment model:

defmodule Comment do
  use Ecto.Model
  schema "abstract table: comments" do
    # This will be used by associations on each "concrete" table
    field :assoc_id, :integer
  end
end

Notice we have changed the table name to “abstract table: comments”. You can choose whatever name you want, the point here is that this particular table will never exist.

Now in your Post and Task models:

defmodule Post do
  use Ecto.Model
  schema "posts" do
    has_many :comments, {"posts_comments", Comment}, foreign_key: :assoc_id
  end
end

defmodule Task do
  use Ecto.Model
  schema "tasks" do
    has_many :comments, {"tasks_comments", Comment}, foreign_key: :assoc_id
  end
end

Now each association uses its own specific table, “posts_comments” and “tasks_comments”, which must be created on migrations. The advantage of this approach is that we never store unrelated data together, also ensuring we keep databases references fast and correct.

When using this technique, the only limitation is that you cannot build comments directly. For example, the command below

Repo.insert!(%Comment{})

will attempt to use the abstract table. Instead, one should

Repo.insert!(build(post, :comments))

where build/2 is defined in Ecto.Model. You can also use assoc/2 in both Ecto.Model and in the query syntax to easily retrieve associated comments to a given post or task:

# Fetch all comments associated to the given task
Repo.all(assoc(task, :comments))

Finally, if for some reason you wish to query one of comments table directly, you can also specify the tuple source in the query syntax:

Repo.all from(c in {"posts_comments", Comment}), ...)

Defines an embedded schema.

This function is literally a shortcut for:

@primary_key {:id, :binary_id, autogenerate: true}
  schema "embedded Model" do

Indicates an embedding of many models.

The current model has zero or more records of the other model embedded inside of it, contained in a list. Embedded models have all the things regular models do - callbacks, structured fields, etc.

All typecasting operations are performed recursively on embedded models alongside the operations on the parent model.

Note: embedding is experimental and its API may still change in future releases.

Options

• :on_cast - the default changeset function to call during casting, which can be overridden in Ecto.Changeset.cast/4. It’s an atom representing the function name in the embedded model’s module which will receive the module and the parameters for casting (default: :changeset).

• :strategy - the strategy for storing models in the database. Ecto supports only the :replace strategy out of the box which is the default. Read strategy section below for more info.

Examples

defmodule Order do
  use Ecto.Model
  schema "orders" do
    embeds_many :items, Item
  end
end

defmodule Item do
  use Ecto.model

  # embedded_schema is a shorcut for:
  #
  #   @primary_key {:id, :binary_id, autogenerate: true}
  #   schema "embedded Item" do
  #
  embedded_schema do
    field :name
  end
end

# The items are loaded with the order
[order] = Repo.all(from(o in Order, where: p.id == 42))
order.items #=> [%Item{...}, ...]

Strategy

A strategy configures how modules should be inserted, updated and deleted from the database. Changing the strategy may affect how items are stored in the database, although embeds_many will always have them as a list in the model.

Ecto supports only the :replace strategy out of the box which is the default. This means all embeds in the model always fully replace the entries in the database.

For example, if you have a collection with a 100 items, the 100 items will be sent whenever any of them change. The approach is useful when you need the parent and embeds to always be consistent.

Other databases may support different strategies, like one that only changes the embeds that have effectively changed, also reducing the amount of data send to the database. This is specially common in NoSQL databases.

Please check your adapter documentation in case it supports other strategies.

Indicates an embedding of one model.

The current model has zero or one records of the other model embedded inside of it. It uses a field similar to the :map type for storage, but allows embedded models to have all the things regular models can - callbacks, structured fields, etc. All typecasting operations are performed on an embedded model alongside the operations on the parent model.

Usage requires support for :map type from the database.

Note: embedding is experimental and its API may still change in future releases.

Options

• :on_cast - the default changeset function to call during casting, which can be overridden in Ecto.Changeset.cast/4. It’s an atom representing the function name in the embedded model’s module which will receive the module and the parameters for casting (default: :changeset).

• :strategy - the strategy for storing models in the database. Ecto supports only the :replace strategy out of the box which is the default. Read the strategy in embeds_many/3 for more info.

Examples

defmodule Order do
  use Ecto.Model
  schema "orders" do
    embeds_one :item, Item
  end
end

defmodule Item do
  use Ecto.model

  # A required field for all embedded documents
  @primary_key {:id, :binary_id, autogenerate: true}
  schema "" do
    field :name
  end
end

# The item is loaded with the order
[order] = Repo.all(from(o in Order, where: p.id == 42))
order.item #=> %Item{...}

Defines a field on the model schema with given name and type.

Options

• :default - Sets the default value on the schema and the struct. The default value is calculated at compilation time, so don’t use expressions like Ecto.DateTime.local or Ecto.UUID.generate as they would then be the same for all records

• :autogenerate - Annotates the field to be autogenerated before insertion if not value is set.

• :read_after_writes - When true, the field only sent on insert if not nil and always read back from the repository during inserts and updates.

  For relational databases, this means the RETURNING option of those statements are used. For this reason, MySQL does not support this option and will raise an error if a model is inserted/updated with read after writes fields.

• :virtual - When true, the field is not persisted to the database. Notice virtual fields do not support :autogenerate nor :read_after_writes.

Indicates a one-to-many association with another model.

The current model has zero or more records of the other model. The other model often has a belongs_to field with the reverse association.

Options

• :foreign_key - Sets the foreign key, this should map to a field on the other model, defaults to the underscored name of the current model suffixed by _id

• :references - Sets the key on the current model to be used for the association, defaults to the primary key on the model

• :through - If this association must be defined in terms of existing associations. Read below for more information

• :on_delete - The action taken on associations when model is deleted. May be :nothing (default), :nilify_all, :delete_all or :fetch_and_delete. See Ecto.Model.Dependent for more info.

• :defaults - Default values to use when building the association

Examples

defmodule Post do
  use Ecto.Model
  schema "posts" do
    has_many :comments, Comment
  end
end

# Get all comments for a given post
post = Repo.get(Post, 42)
comments = Repo.all assoc(post, :comments)

# The comments can come preloaded on the post struct
[post] = Repo.all(from(p in Post, where: p.id == 42, preload: :comments))
post.comments #=> [%Comment{...}, ...]

has_many/has_one :through

Ecto also supports defining associations in terms of other associations via the :through option. Let’s see an example:

defmodule Post do
  use Ecto.Model
  schema "posts" do
    has_many :comments, Comment
    has_one :permalink, Permalink

    # In the has_many :through example below, in the list
    # `[:comments, :author]` the `:comments` refers to the
    # `has_many :comments` in the Post model's own schema
    # and the `:author` refers to the `belongs_to :author`
    # of the Comment module's schema (the module below).
    # (see the description below for more details)
    has_many :comments_authors, through: [:comments, :author]

    # Specify the association with custom source
    has_many :tags, {"posts_tags", Tag}
  end
end

defmodule Comment do
  use Ecto.Model
  schema "comments" do
    belongs_to :author, Author
    belongs_to :post, Post
    has_one :post_permalink, through: [:post, :permalink]
  end
end

In the example above, we have defined a has_many :through association named :comments_authors. A :through association always expect a list and the first element of the list must be a previously defined association in the current module. For example, :comments_authors first points to :comments in the same module (Post), which then points to :author in the next model Comment.

This :through associations will return all authors for all comments that belongs to that post:

# Get all comments for a given post
post = Repo.get(Post, 42)
authors = Repo.all assoc(post, :comments_authors)

:through associations are read-only as they are useful to avoid repetition allowing the developer to easily retrieve data that is often seem together but stored across different tables.

:through associations can also be preloaded. In such cases, not only the :through association is preloaded but all intermediate steps are preloaded too:

[post] = Repo.all(from(p in Post, where: p.id == 42, preload: :comments_authors))
post.comments_authors #=> [%Author{...}, ...]

# The comments for each post will be preloaded too
post.comments #=> [%Comment{...}, ...]

# And the author for each comment too
hd(post.comments).authors #=> [%Author{...}, ...]

Finally, :through can be used with multiple associations (not only 2) and with associations of any kind, including belongs_to and others :through associations. When the :through association is expected to return one or no item, has_one :through should be used instead, as in the example at the beginning of this section:

# How we defined the association above
has_one :post_permalink, through: [:post, :permalink]

# Get a preloaded comment
[comment] = Repo.all(Comment) |> Repo.preload(:post_permalink)
comment.post_permalink #=> %Permalink{...}

Indicates a one-to-one association with another model.

The current model has zero or one records of the other model. The other model often has a belongs_to field with the reverse association.

Options

• :foreign_key - Sets the foreign key, this should map to a field on the other model, defaults to the underscored name of the current model suffixed by _id

• :references - Sets the key on the current model to be used for the association, defaults to the primary key on the model

• :through - If this association must be defined in terms of existing associations. Read the section in has_many/3 for more information

• :on_delete - The action taken on associations when model is deleted. May be :nothing (default), :nilify_all, :delete_all or :fetch_and_delete. See Ecto.Model.Dependent for more info.

• :defaults - Default values to use when building the association

Examples

defmodule Post do
  use Ecto.Model
  schema "posts" do
    has_one :permalink, Permalink

    # Specify the association with custom source
    has_one :category, {"posts_categories", Category}
  end
end

# The permalink can come preloaded on the post struct
[post] = Repo.all(from(p in Post, where: p.id == 42, preload: :permalink))
post.permalink #=> %Permalink{...}

Defines a schema with a source name and field definitions.

Generates :inserted_at and :updated_at timestamp fields.

When using Ecto.Model, the fields generated by this macro will automatically be set to the current time when inserting and updating values in a repository.

Options

• :type - the timestamps type, defaults to Ecto.DateTime.
• :usec - boolean, sets whether microseconds are used in timestamps. Microseconds will be 0 if false. Defaults to false.
• :inserted_at - the name of the column for insertion times or false
• :updated_at - the name of the column for update times or false

All options can be pre-configured by setting @timestamps_opts.