Indicates a one-to-one or many-to-one association with another schema.

The current schema belongs to zero or one records of the other schema. The other schema often has a has_one or a has_many field with the reverse association.

You should use belongs_to in the table that contains the foreign key. Imagine a company <-> employee relationship. If the employee contains the company_id in the underlying database table, we say the employee belongs to company.

In fact, when you invoke this macro, a field with the name of foreign key is automatically defined in the schema for you.

options

Options

• :foreign_key - Sets the foreign key field name, defaults to the name of the association suffixed by _id. For example, belongs_to :company will define foreign key of :company_id. The associated has_one or has_many field in the other schema should also have its :foreign_key option set with the same value.

• :references - Sets the key on the other schema to be used for the association, defaults to: :id

• :define_field - When false, does not automatically define a :foreign_key field, implying the user is defining the field manually elsewhere

• :type - Sets the type of automatically defined :foreign_key. Defaults to: :integer and can be set per schema via @foreign_key_type

• :on_replace - The action taken on associations when the record is replaced when casting or manipulating parent changeset. May be :raise (default), :mark_as_invalid, :nilify, :update, or :delete. See Ecto.Changeset's section on related data for more info.

• :defaults - Default values to use when building the association. It may be a keyword list of options that override the association schema or a atom/{module, function, args} that receives the struct and the owner as arguments. For example, if you set Comment.belongs_to :post, defaults: [public: true], then when using Ecto.build_assoc(comment, :post), the post will have post.public == true. Alternatively, you can set it to Comment.belongs_to :post, defaults: :update_post, which will invoke Comment.update_post(post, comment), or set it to a MFA tuple such as {Mod, fun, [arg3, arg4]}, which will invoke Mod.fun(post, comment, arg3, arg4)

• :primary_key - If the underlying belongs_to field is a primary key

• :source - Defines the name that is to be used in database for this field

• :where - A filter for the association. See "Filtering associations" in has_many/3.

examples

Examples

defmodule Comment do
  use Ecto.Schema

  schema "comments" do
    belongs_to :post, Post
  end
end

# The post can come preloaded on the comment record
[comment] = Repo.all(from(c in Comment, where: c.id == 42, preload: :post))
comment.post #=> %Post{...}

If you need custom options on the underlying field, you can define the field explicitly and then pass define_field: false to belongs_to:

defmodule Comment do
  use Ecto.Schema

  schema "comments" do
    field :post_id, :integer, ... # custom options
    belongs_to :post, Post, define_field: false
  end
end

polymorphic-associations

Polymorphic associations

One common use case for belongs to associations is to handle polymorphism. For example, imagine you have defined a Comment schema and you wish to use it for commenting on both tasks and posts.

Some abstractions would force you to define some sort of polymorphic association with two fields in your database:

* commentable_type
* commentable_id

The problem with this approach is that it breaks references in the database. You can't use foreign keys and it is very inefficient, both in terms of query time and storage.

In Ecto, we have three ways to solve this issue. The simplest is to define multiple fields in the Comment schema, one for each association:

* task_id
* post_id

Unless you have dozens of columns, this is simpler for the developer, more DB friendly and more efficient in all aspects.

Alternatively, because Ecto does not tie a schema to a given table, we can use separate tables for each association. Let's start over and define a new Comment schema:

defmodule Comment do
  use Ecto.Schema

  schema "abstract table: comments" do
    # This will be used by associations on each "concrete" table
    field :assoc_id, :integer
  end
end

Notice we have changed the table name to "abstract table: comments". You can choose whatever name you want, the point here is that this particular table will never exist.

Now in your Post and Task schemas:

defmodule Post do
  use Ecto.Schema

  schema "posts" do
    has_many :comments, {"posts_comments", Comment}, foreign_key: :assoc_id
  end
end

defmodule Task do
  use Ecto.Schema

  schema "tasks" do
    has_many :comments, {"tasks_comments", Comment}, foreign_key: :assoc_id
  end
end

Now each association uses its own specific table, "posts_comments" and "tasks_comments", which must be created on migrations. The advantage of this approach is that we never store unrelated data together, also ensuring we keep database references fast and correct.

When using this technique, the only limitation is that you cannot build comments directly. For example, the command below

Repo.insert!(%Comment{})

will attempt to use the abstract table. Instead, one should use

Repo.insert!(build_assoc(post, :comments))

leveraging the Ecto.build_assoc/3 function. You can also use Ecto.assoc/2 or pass a tuple in the query syntax to easily retrieve associated comments to a given post or task:

# Fetch all comments associated with the given task
Repo.all(Ecto.assoc(task, :comments))

Or all comments in a given table:

Repo.all from(c in {"posts_comments", Comment}), ...)

The third and final option is to use many_to_many/3 to define the relationships between the resources. In this case, the comments table won't have the foreign key, instead there is an intermediary table responsible for associating the entries:

defmodule Comment do
  use Ecto.Schema
  schema "comments" do
    # ...
  end
end

In your posts and tasks:

defmodule Post do
  use Ecto.Schema

  schema "posts" do
    many_to_many :comments, Comment, join_through: "posts_comments"
  end
end

defmodule Task do
  use Ecto.Schema

  schema "tasks" do
    many_to_many :comments, Comment, join_through: "tasks_comments"
  end
end

See many_to_many/3 for more information on this particular approach.

Defines an embedded schema with the given field definitions.

An embedded schema is either embedded into another schema or kept exclusively in memory. For this reason, an embedded schema does not require a source name and it does not include a metadata field.

Embedded schemas by default set the primary key type to :binary_id but such can be configured with the @primary_key attribute.

Indicates an embedding of many schemas.

The current schema has zero or more records of the other schema embedded inside of it. Embeds have all the things regular schemas have.

It is recommended to declare your embeds_many/3 field with type :map in your migrations, instead of using {:array, :map}. Ecto can work with both maps and arrays as the container for embeds (and in most databases map are represented as JSON which allows Ecto to choose what works best).

The embedded may or may not have a primary key. Ecto uses the primary keys to detect if an embed is being updated or not. If a primary is not present and you still want the list of embeds to be updated, :on_replace must be set to :delete, forcing all current embeds to be deleted and replaced by new ones whenever a new list of embeds is set.

For encoding and decoding of embeds, please read the docs for embeds_one/3.

options

Options

• :on_replace - The action taken on associations when the embed is replaced when casting or manipulating parent changeset. May be :raise (default), :mark_as_invalid, or :delete. See Ecto.Changeset's section on related data for more info.

• :source - Defines the name that is to be used in database for this field. This is useful when attaching to an existing database. The value should be an atom.

examples

Examples

defmodule Order do
  use Ecto.Schema

  schema "orders" do
    embeds_many :items, Item
  end
end

defmodule Item do
  use Ecto.Schema

  embedded_schema do
    field :title
  end
end

# The items are loaded with the order
order = Repo.get!(Order, 42)
order.items #=> [%Item{...}, ...]

Adding and removal of embeds can only be done via the Ecto.Changeset API so Ecto can properly track the embed life-cycle:

# Order has no items
order = Repo.get!(Order, 42)
order.items
# => []

items  = [%Item{title: "Soap"}]

# Generate a changeset
changeset = Ecto.Changeset.change(order)

# Put a one or more new items
changeset = Ecto.Changeset.put_embed(changeset, :items, items)

# Update the order and fetch items
items = Repo.update!(changeset).items

# Items are generated with a unique identification
items
# => [%Item{id: "20a97d94-f79b-4e63-a875-85deed7719b7", title: "Soap"}]

Updating of embeds must be done using a changeset for each changed embed.

# Order has an existing items
order = Repo.get!(Order, 42)
order.items
# => [%Item{id: "20a97d94-f79b-4e63-a875-85deed7719b7", title: "Soap"}]

# Generate a changeset
changeset = Ecto.Changeset.change(order)

# Put the updated item as a changeset
current_item = List.first(order.items)
item_changeset = Ecto.Changeset.change(current_item, title: "Mujju's Soap")
order_changeset = Ecto.Changeset.put_embed(changeset, :items, [item_changeset])

# Update the order and fetch items
items = Repo.update!(order_changeset).items

# Item has the updated title
items
# => [%Item{id: "20a97d94-f79b-4e63-a875-85deed7719b7", title: "Mujju's Soap"}]

inline-embedded-schema

Inline embedded schema

The schema module can be defined inline in the parent schema in simple cases:

defmodule Parent do
  use Ecto.Schema

  schema "parents" do
    field :name, :string

    embeds_many :children, Child do
      field :name, :string
      field :age,  :integer
    end
  end
end

Primary keys are automatically set up for embedded schemas as well, defaulting to {:id, :binary_id, autogenerate: true}. You can customize it by passing a :primary_key option with the same arguments as @primary_key (see the Schema attributes section for more info).

Defining embedded schema in such a way will define a Parent.Child module with the appropriate struct. In order to properly cast the embedded schema. When casting the inline-defined embedded schemas you need to use the :with option of cast_embed/3 to provide the proper function to do the casting. For example:

def changeset(schema, params) do
  schema
  |> cast(params, [:name])
  |> cast_embed(:children, with: &child_changeset/2)
end

defp child_changeset(schema, params) do
  schema
  |> cast(params, [:name, :age])
end

Indicates an embedding of many schemas.

For options and examples see documentation of embeds_many/3.

Indicates an embedding of a schema.

The current schema has zero or one records of the other schema embedded inside of it. It uses a field similar to the :map type for storage, but allows embeds to have all the things regular schema can.

You must declare your embeds_one/3 field with type :map at the database level.

The embedded may or may not have a primary key. Ecto uses the primary keys to detect if an embed is being updated or not. If a primary key is not present, :on_replace should be set to either :update or :delete if there is a desire to either update or delete the current embed when a new one is set.

options

Options

• :on_replace - The action taken on associations when the embed is replaced when casting or manipulating parent changeset. May be :raise (default), :mark_as_invalid, :update, or :delete. See Ecto.Changeset's section on related data for more info.

• :source - Defines the name that is to be used in database for this field. This is useful when attaching to an existing database. The value should be an atom.

examples

Examples

defmodule Order do
  use Ecto.Schema

  schema "orders" do
    embeds_one :item, Item
  end
end

defmodule Item do
  use Ecto.Schema

  embedded_schema do
    field :title
  end
end

# The item is loaded with the order
order = Repo.get!(Order, 42)
order.item #=> %Item{...}

Adding and removal of embeds can only be done via the Ecto.Changeset API so Ecto can properly track the embed life-cycle:

order = Repo.get!(Order, 42)
item  = %Item{title: "Soap"}

# Generate a changeset
changeset = Ecto.Changeset.change(order)

# Put a new embed to the changeset
changeset = Ecto.Changeset.put_embed(changeset, :item, item)

# Update the order, and fetch the item
item = Repo.update!(changeset).item

# Item is generated with a unique identification
item
# => %Item{id: "20a97d94-f79b-4e63-a875-85deed7719b7", title: "Soap"}

inline-embedded-schema

Inline embedded schema

The schema module can be defined inline in the parent schema in simple cases:

defmodule Parent do
  use Ecto.Schema

  schema "parents" do
    field :name, :string

    embeds_one :child, Child do
      field :name, :string
      field :age,  :integer
    end
  end
end

Options should be passed before the do block like this:

embeds_one :child, Child, on_replace: :delete do
  field :name, :string
  field :age,  :integer
end

Primary keys are automatically set up for embedded schemas as well, defaulting to {:id, :binary_id, autogenerate: true}. You can customize it by passing a :primary_key option with the same arguments as @primary_key (see the Schema attributes section for more info).

Defining embedded schema in such a way will define a Parent.Child module with the appropriate struct. In order to properly cast the embedded schema. When casting the inline-defined embedded schemas you need to use the :with option of Ecto.Changeset.cast_embed/3 to provide the proper function to do the casting. For example:

def changeset(schema, params) do
  schema
  |> cast(params, [:name])
  |> cast_embed(:child, with: &child_changeset/2)
end

defp child_changeset(schema, params) do
  schema
  |> cast(params, [:name, :age])
end

encoding-and-decoding

Encoding and decoding

Because many databases do not support direct encoding and decoding of embeds, it is often emulated by Ecto by using specific encoding and decoding rules.

For example, PostgreSQL will store embeds on top of JSONB columns, which means types in embedded schemas won't go through the usual dump->DB->load cycle but rather encode->DB->decode->cast. This means that, when using embedded schemas with databases like PG or MySQL, make sure all of your types can be JSON encoded/decoded correctly. Ecto provides this guarantee for all built-in types.

Indicates an embedding of a schema.

For options and examples see documentation of embeds_one/3.

Defines a field on the schema with given name and type.

The field name will be used as is to read and write to the database by all of the built-in adapters unless overridden with the :source option.

options

Options

• :default - Sets the default value on the schema and the struct.

  The default value is calculated at compilation time, so don't use expressions like DateTime.utc_now or Ecto.UUID.generate as they would then be the same for all records: in this scenario you can use the :autogenerate option to generate at insertion time.

  The default value is validated against the field's type at compilation time and it will raise an ArgumentError if there is a type mismatch. If you cannot infer the field's type at compilation time, you can use the :skip_default_validation option on the field to skip validations.

  Once a default value is set, if you send changes to the changeset that contains the same value defined as default, validations will not be performed since there are no changes after all.

• :source - Defines the name that is to be used in database for this field. This is useful when attaching to an existing database. The value should be an atom.

• :autogenerate - a {module, function, args} tuple for a function to call to generate the field value before insertion if value is not set. A shorthand value of true is equivalent to {type, :autogenerate, []}.

• :read_after_writes - When true, the field is always read back from the database after insert and updates.

  For relational databases, this means the RETURNING option of those statements is used. For this reason, MySQL does not support this option and will raise an error if a schema is inserted/updated with read after writes fields.

• :virtual - When true, the field is not persisted to the database. Notice virtual fields do not support :autogenerate nor :read_after_writes.

• :primary_key - When true, the field is used as part of the composite primary key.

• :load_in_query - When false, the field will not be loaded when selecting the whole struct in a query, such as from p in Post, select: p. Defaults to true.

• :redact - When true, it will display a value of **redacted** when inspected in changes inside a Ecto.Changeset and be excluded from inspect on the schema. Defaults to false.

• :skip_default_validation - When true, it will skip the type validation step at compile time.

Indicates a one-to-many association with another schema.

The current schema has zero or more records of the other schema. The other schema often has a belongs_to field with the reverse association.

options

Options

• :foreign_key - Sets the foreign key, this should map to a field on the other schema, defaults to the underscored name of the current schema suffixed by _id

• :references - Sets the key on the current schema to be used for the association, defaults to the primary key on the schema

• :through - Allow this association to be defined in terms of existing associations. Read the section on :through associations for more info

• :on_delete - The action taken on associations when parent record is deleted. May be :nothing (default), :nilify_all and :delete_all. Using this option is DISCOURAGED for most relational databases. Instead, in your migration, set references(:parent_id, on_delete: :delete_all). Opposite to the migration option, this option cannot guarantee integrity and it is only triggered for Ecto.Repo.delete/2 (and not on Ecto.Repo.delete_all/2) and it never cascades. If posts has many comments, which has many tags, and you delete a post, only comments will be deleted. If your database does not support references, cascading can be manually implemented by using Ecto.Multi or Ecto.Changeset.prepare_changes/2.

• :on_replace - The action taken on associations when the record is replaced when casting or manipulating parent changeset. May be :raise (default), :mark_as_invalid, :nilify, or :delete. See Ecto.Changeset's section about ":on_replace" for more info.

• :defaults - Default values to use when building the association. It may be a keyword list of options that override the association schema or a atom/{module, function, args} that receives the struct and the owner as arguments. For example, if you set Post.has_many :comments, defaults: [public: true], then when using Ecto.build_assoc(post, :comments), the comment will have comment.public == true. Alternatively, you can set it to Post.has_many :comments, defaults: :update_comment, which will invoke Post.update_comment(comment, post), or set it to a MFA tuple such as {Mod, fun, [arg3, arg4]}, which will invoke Mod.fun(comment, post, arg3, arg4)

• :where - A filter for the association. See "Filtering associations" below. It does not apply to :through associations.

• :preload_order - Sets the default order_by of the association. It is used when the association is preloaded. For example, if you set Post.has_many :comments, preload_order: [asc: :content], whenever the :comments associations is preloaded, the comments will be order by the :content field. See Ecto.Query.order_by/3 for more examples.

examples

Examples

defmodule Post do
  use Ecto.Schema
  schema "posts" do
    has_many :comments, Comment
  end
end

# Get all comments for a given post
post = Repo.get(Post, 42)
comments = Repo.all assoc(post, :comments)

# The comments can come preloaded on the post struct
[post] = Repo.all(from(p in Post, where: p.id == 42, preload: :comments))
post.comments #=> [%Comment{...}, ...]

has_many can be used to define hierarchical relationships within a single schema, for example threaded comments.

defmodule Comment do
  use Ecto.Schema
  schema "comments" do
    field :content, :string
    field :parent_id, :integer
    belongs_to :parent, Comment, foreign_key: :parent_id, references: :id, define_field: false
    has_many :children, Comment, foreign_key: :parent_id, references: :id
  end
end

filtering-associations

Filtering associations

It is possible to specify a :where option that will filter the records returned by the association. Querying, joining or preloading the association will use the given conditions as shown next:

defmodule Post do
  use Ecto.Schema

  schema "posts" do
    has_many :public_comments, Comment,
      where: [public: true]
  end
end

The :where option expects a keyword list where the key is an atom representing the field and the value is either:

• nil - which specifies the field must be nil
• {:not, nil} - which specifies the field must not be nil
• {:in, list} - which specifies the field must be one of the values in a list
• {:fragment, expr} - which specifies a fragment string as the filter (see Ecto.Query.API.fragment/1) with the field's value given to it as the only argument
• or any other value which the field is compared directly against

Note the values above are distinctly different from the values you would pass to where when building a query. For example, if you attempt to build a query such as

from Post, where: [id: nil]

it will emit an error. This is because queries can be built dynamically, and therefore passing nil can lead to security errors. However, the :where values for an association are given at compile-time, which is less dynamic and cannot leverage the full power of Ecto queries, which explains why they have different APIs.

Important! Please use this feature only when strictly necessary, otherwise it is very easy to end-up with large schemas with dozens of different associations polluting your schema and affecting your application performance. For instance, if you are using associations only for different querying purposes, then it is preferable to build and compose queries. For instance, instead of having two associations, one for comments and another for deleted comments, you might have a single comments association and filter it instead:

posts
|> Ecto.assoc(:comments)
|> Comment.deleted()

Or when preloading:

from posts, preload: [comments: ^Comment.deleted()]

has_many-has_one-through

has_many/has_one :through

Ecto also supports defining associations in terms of other associations via the :through option. Let's see an example:

defmodule Post do
  use Ecto.Schema

  schema "posts" do
    has_many :comments, Comment
    has_one :permalink, Permalink

    # In the has_many :through example below, the `:comments`
    # in the list [:comments, :author] refers to the
    # `has_many :comments` in the Post own schema and the
    # `:author` refers to the `belongs_to :author` of the
    # Comment's schema (the module below).
    # (see the description below for more details)
    has_many :comments_authors, through: [:comments, :author]

    # Specify the association with custom source
    has_many :tags, {"posts_tags", Tag}
  end
end

defmodule Comment do
  use Ecto.Schema

  schema "comments" do
    belongs_to :author, Author
    belongs_to :post, Post
    has_one :post_permalink, through: [:post, :permalink]
  end
end

In the example above, we have defined a has_many :through association named :comments_authors. A :through association always expects a list and the first element of the list must be a previously defined association in the current module. For example, :comments_authors first points to :comments in the same module (Post), which then points to :author in the next schema, Comment.

This :through association will return all authors for all comments that belongs to that post:

# Get all comments authors for a given post
post = Repo.get(Post, 42)
authors = Repo.all assoc(post, :comments_authors)

:through associations can also be preloaded. In such cases, not only the :through association is preloaded but all intermediate steps are preloaded too:

[post] = Repo.all(from(p in Post, where: p.id == 42, preload: :comments_authors))
post.comments_authors #=> [%Author{...}, ...]

# The comments for each post will be preloaded too
post.comments #=> [%Comment{...}, ...]

# And the author for each comment too
hd(post.comments).author #=> %Author{...}

When the :through association is expected to return one or zero items, has_one :through should be used instead, as in the example at the beginning of this section:

# How we defined the association above
has_one :post_permalink, through: [:post, :permalink]

# Get a preloaded comment
[comment] = Repo.all(Comment) |> Repo.preload(:post_permalink)
comment.post_permalink #=> %Permalink{...}

Note :through associations are read-only. For example, you cannot use Ecto.Changeset.cast_assoc/3 to modify through associations.

Indicates a one-to-one association with another schema.

The current schema has zero or one records of the other schema. The other schema often has a belongs_to field with the reverse association.

options

Options

• :foreign_key - Sets the foreign key, this should map to a field on the other schema, defaults to the underscored name of the current module suffixed by _id

• :references - Sets the key on the current schema to be used for the association, defaults to the primary key on the schema

• :through - If this association must be defined in terms of existing associations. Read the section in has_many/3 for more information

• :on_delete - The action taken on associations when parent record is deleted. May be :nothing (default), :nilify_all and :delete_all. Using this option is DISCOURAGED for most relational databases. Instead, in your migration, set references(:parent_id, on_delete: :delete_all). Opposite to the migration option, this option cannot guarantee integrity and it is only triggered for Ecto.Repo.delete/2 (and not on Ecto.Repo.delete_all/2) and it never cascades. If posts has many comments, which has many tags, and you delete a post, only comments will be deleted. If your database does not support references, cascading can be manually implemented by using Ecto.Multi or Ecto.Changeset.prepare_changes/2

• :on_replace - The action taken on associations when the record is replaced when casting or manipulating parent changeset. May be :raise (default), :mark_as_invalid, :nilify, :update, or :delete. See Ecto.Changeset's section on related data for more info.

• :defaults - Default values to use when building the association. It may be a keyword list of options that override the association schema or as a atom/{module, function, args} that receives the struct and the owner as arguments. For example, if you set Post.has_one :banner, defaults: [public: true], then when using Ecto.build_assoc(post, :banner), the banner will have banner.public == true. Alternatively, you can set it to Post.has_one :banner, defaults: :update_banner, which will invoke Post.update_banner(banner, post), or set it to a MFA tuple such as {Mod, fun, [arg3, arg4]}, which will invoke Mod.fun(banner, post, arg3, arg4)

• :where - A filter for the association. See "Filtering associations" in has_many/3. It does not apply to :through associations.

examples

Examples

defmodule Post do
  use Ecto.Schema

  schema "posts" do
    has_one :permalink, Permalink

    # Specify the association with custom source
    has_one :category, {"posts_categories", Category}
  end
end

# The permalink can come preloaded on the post struct
[post] = Repo.all(from(p in Post, where: p.id == 42, preload: :permalink))
post.permalink #=> %Permalink{...}

Indicates a many-to-many association with another schema.

The association happens through a join schema or source, containing foreign keys to the associated schemas. For example, the association below:

# from MyApp.Post
many_to_many :tags, MyApp.Tag, join_through: "posts_tags"

is backed by relational databases through a join table as follows:

[Post] <-> [posts_tags] <-> [Tag]
  id   <--   post_id
              tag_id    -->  id

More information on the migration for creating such a schema is shown below.

options

Options

• :join_through - Specifies the source of the associated data. It may be a string, like "posts_tags", representing the underlying storage table or an atom, like MyApp.PostTag, representing a schema. This option is required.

• :join_keys - Specifies how the schemas are associated. It expects a keyword list with two entries, the first being how the join table should reach the current schema and the second how the join table should reach the associated schema. In the example above, it defaults to: [post_id: :id, tag_id: :id]. The keys are inflected from the schema names.

• :on_delete - The action taken on associations when the parent record is deleted. May be :nothing (default) or :delete_all. Using this option is DISCOURAGED for most relational databases. Instead, in your migration, set references(:parent_id, on_delete: :delete_all). Opposite to the migration option, this option cannot guarantee integrity and it is only triggered for Ecto.Repo.delete/2 (and not on Ecto.Repo.delete_all/2). This option can only remove data from the join source, never the associated records, and it never cascades.

• :on_replace - The action taken on associations when the record is replaced when casting or manipulating parent changeset. May be :raise (default), :mark_as_invalid, or :delete. :delete will only remove data from the join source, never the associated records. See Ecto.Changeset's section on related data for more info.

• :defaults - Default values to use when building the association. It may be a keyword list of options that override the association schema or a atom/{module, function, args} that receives the struct and the owner as arguments. For example, if you set Post.many_to_many :tags, defaults: [public: true], then when using Ecto.build_assoc(post, :tags), the tag will have tag.public == true. Alternatively, you can set it to Post.many_to_many :tags, defaults: :update_tag, which will invoke Post.update_tag(tag, post), or set it to a MFA tuple such as {Mod, fun, [arg3, arg4]}, which will invoke Mod.fun(tag, post, arg3, arg4)

• :join_defaults - The same as :defaults but it applies to the join schema instead. This option will raise if it is given and the :join_through value is not a schema.

• :unique - When true, checks if the associated entries are unique whenever the association is cast or changed via the parent record. For instance, it would verify that a given tag cannot be attached to the same post more than once. This exists mostly as a quick check for user feedback, as it does not guarantee uniqueness at the database level. Therefore, you should also set a unique index in the database join table, such as: create unique_index(:posts_tags, [:post_id, :tag_id])

• :where - A filter for the association. See "Filtering associations" in has_many/3

• :join_where - A filter for the join table. See "Filtering associations" in has_many/3

• :preload_order - Sets the default order_by of the association. It is used when the association is preloaded. For example, if you set Post.many_to_many :tags, Tag, join_through: "posts_tags", preload_order: [asc: :foo], whenever the :tags associations is preloaded, the tags will be order by the :foo field. See Ecto.Query.order_by/3 for more examples.

using-ecto-assoc-2

Using Ecto.assoc/2

One of the benefits of using many_to_many is that Ecto will avoid loading the intermediate whenever possible, making your queries more efficient. For this reason, developers should not refer to the join table of many_to_many in queries. The join table is accessible in few occasions, such as in Ecto.assoc/2. For example, if you do this:

post
|> Ecto.assoc(:tags)
|> where([t, _pt, p], p.public == t.public)

It may not work as expected because the posts_tags table may not be included in the query. You can address this problem in multiple ways. One option is to use ...:

post
|> Ecto.assoc(:tags)
|> where([t, ..., p], p.public == t.public)

Another and preferred option is to rewrite to an explicit join, which ellide the intermediate bindings as they are resolved only later on:

# keyword syntax
from t in Tag,
  join: p in assoc(t, :post), on: p.id == ^post.id

# pipe syntax
Tag
|> join([t], :inner, p in assoc(t, :post), on: p.id == ^post.id)

If you need to access the join table, then you likely want to use has_many/3 with the :through option instead.

removing-data

Removing data

If you attempt to remove associated many_to_many data, Ecto will always remove data from the join schema and never from the target associations be it by setting :on_replace to :delete, :on_delete to :delete_all or by using changeset functions such as Ecto.Changeset.put_assoc/3. For example, if a Post has a many to many relationship with Tag, setting :on_delete to :delete_all will only delete entries from the "posts_tags" table in case Post is deleted.

migration

Migration

How your migration should be structured depends on the value you pass in :join_through. If :join_through is simply a string, representing a table, you may define a table without primary keys and you must not include any further columns, as those values won't be set by Ecto:

create table(:posts_tags, primary_key: false) do
  add :post_id, references(:posts)
  add :tag_id, references(:tags)
end

However, if your :join_through is a schema, like MyApp.PostTag, your join table may be structured as any other table in your codebase, including timestamps:

create table(:posts_tags) do
  add :post_id, references(:posts)
  add :tag_id, references(:tags)
  timestamps()
end

Because :join_through contains a schema, in such cases, autogenerated values and primary keys will be automatically handled by Ecto.

examples

Examples

defmodule Post do
  use Ecto.Schema
  schema "posts" do
    many_to_many :tags, Tag, join_through: "posts_tags"
  end
end

# Let's create a post and a tag
post = Repo.insert!(%Post{})
tag = Repo.insert!(%Tag{name: "introduction"})

# We can associate at any time post and tags together using changesets
post
|> Repo.preload(:tags) # Load existing data
|> Ecto.Changeset.change() # Build the changeset
|> Ecto.Changeset.put_assoc(:tags, [tag]) # Set the association
|> Repo.update!

# In a later moment, we may get all tags for a given post
post = Repo.get(Post, 42)
tags = Repo.all(assoc(post, :tags))

# The tags may also be preloaded on the post struct for reading
[post] = Repo.all(from(p in Post, where: p.id == 42, preload: :tags))
post.tags #=> [%Tag{...}, ...]

join-schema-example

Join Schema Example

You may prefer to use a join schema to handle many_to_many associations. The decoupled nature of Ecto allows us to create a "join" struct which belongs_to both sides of the many to many association.

In our example, a User has and belongs to many Organizations:

defmodule MyApp.Repo.Migrations.CreateUserOrganization do
  use Ecto.Migration

  def change do
    create table(:users_organizations) do
      add :user_id, references(:users)
      add :organization_id, references(:organizations)

      timestamps()
    end
  end
end

defmodule UserOrganization do
  use Ecto.Schema

  @primary_key false
  schema "users_organizations" do
    belongs_to :user, User
    belongs_to :organization, Organization
    timestamps() # Added bonus, a join schema will also allow you to set timestamps
  end

  def changeset(struct, params \\ %{}) do
    struct
    |> Ecto.Changeset.cast(params, [:user_id, :organization_id])
    |> Ecto.Changeset.validate_required([:user_id, :organization_id])
    # Maybe do some counter caching here!
  end
end

defmodule User do
  use Ecto.Schema

  schema "users" do
    many_to_many :organizations, Organization, join_through: UserOrganization
  end
end

defmodule Organization do
  use Ecto.Schema

  schema "organizations" do
    many_to_many :users, User, join_through: UserOrganization
  end
end

# Then to create the association, pass in the ID's of an existing
# User and Organization to UserOrganization.changeset
changeset = UserOrganization.changeset(%UserOrganization{}, %{user_id: id, organization_id: id})

case Repo.insert(changeset) do
  {:ok, assoc} -> # Assoc was created!
  {:error, changeset} -> # Handle the error
end

Defines a schema struct with a source name and field definitions.

An additional field called __meta__ is added to the struct for storing internal Ecto state. This field always has a Ecto.Schema.Metadata struct as value and can be manipulated with the Ecto.put_meta/2 function.

Generates :inserted_at and :updated_at timestamp fields.

The fields generated by this macro will automatically be set to the current time when inserting and updating values in a repository.

options

Options

• :inserted_at - the Ecto schema name of the field for insertion times or false
• :updated_at - the Ecto schema name of the field for update times or false
• :inserted_at_source - the name of the database column for insertion times or false
• :updated_at_source - the name of the database column for update times or false
• :type - the timestamps type, defaults to :naive_datetime.
• :autogenerate - a module-function-args tuple used for generating both inserted_at and updated_at timestamps

All options can be pre-configured by setting @timestamps_opts.