The application command behaviour specifies the interface that a slash, user, or message command module should implement.

Like regular commands, application command modules are stateless on their own. Implementations of the callbacks defined by this behaviour are invoked from other modules/functions, notably a Nosedrum.Storage.

The types defined in this module reflect the official Application Command docs.

Example Slash Command

This command echos the passed message back to the user.

# In your application command module file, e.g. ./lib/my_app/commands/echo.ex
defmodule MyApp.Commands.Echo do
  @behaviour Nosedrum.ApplicationCommand

  @impl true
  def description() do
    "Echos a message."
  end

  @impl true
  def command(interaction) do
    [%{name: "message", value: message}] = interaction.data.options
    [
      content: message,
      ephemeral?: true
    ]
  end

  @impl true
  def type() do
    :slash
  end

  @impl true
  def options() do
    [
      %{
        type: :string,
        name: "message",
        description: "The message for the bot to echo.",
        required: true
      }
    ]
  end
end

# In your Nostrum.Consumer file, e.g. ./lib/my_app/consumer.ex
defmodule MyApp.Consumer do
  use Nostrum.Consumer

  # ...

  # You may use `:global` instead of a guild id at GUILD_ID_HERE, but note
  # that global commands could take up to an hour to become available.
  def handle_event({:READY, _data, _ws_state}) do
    case Nosedrum.Storage.Dispatcher.add_command("echo", MyApp.Commands.Echo, GUILD_ID_HERE) do
      {:ok, _} -> IO.puts("Registered Echo command.")
      e -> IO.inspect(e, label: "An error occurred registering the Echo command")
    end
  end

  def handle_event({:INTERACTION_CREATE, interaction, _ws_state}) do
    Nosedrum.Storage.Dispatcher.handle_interaction(interaction)
  end
end

You will also need to start the Nosedrum.Storage.Dispatcher as part of your supervision tree, for example, by adding this to your application start function:

# ./lib/my_app/application.ex
defmodule MyApp.Application do
  # ...
  def start(type, args) do
    children = [
      # ...
      {Nosedrum.Storage.Dispatcher, name: Nosedrum.Storage.Dispatcher},
    ]

    options = [strategy: :rest_for_one, name: MyApp.Supervisor]
    Supervisor.start_link(children, options)
  end
end