Telemetry integration for event metrics, logging and error reporting.

Job Events

Oban emits the following telemetry events for each job:

• [:oban, :job, :start] — at the point a job is fetched from the database and will execute
• [:oban, :job, :stop] — after a job succeeds and the success is recorded in the database
• [:oban, :job, :exception] — after a job fails and the failure is recorded in the database

All job events share the same details about the job that was executed. In addition, failed jobs provide the error type, the error itself, and the stacktrace. The following chart shows which metadata you can expect for each event:

For :exception events the metadata includes details about what caused the failure. The :kind value is determined by how an error occurred. Here are the possible kinds:

• :error — from an {:error, error} return value. Some Erlang functions may also throw an :error tuple, which will be reported as :error.
• :exit — from a caught process exit
• :throw — from a caught value, this doesn't necessarily mean that an error occurred and the error value is unpredictable

Circuit Events

All processes that interact with the database have circuit breakers to prevent errors from crashing the entire supervision tree. Processes emit a [:oban, :trip_circuit] event when a circuit is tripped and [:oban, :open_circuit] when the breaker is subsequently opened again.

Metadata

• :error — the error that tripped the circuit, see the error kinds breakdown above
• :name — the registered name of the process that tripped a circuit, i.e. Oban.Notifier
• :message — a formatted error message describing what went wrong
• :stacktrace — exception stacktrace, when available

Default Logger

A default log handler that emits structured JSON is provided, see attach_default_logger/0 for usage. Otherwise, if you would prefer more control over logging or would like to instrument events you can write your own handler.

Examples

A handler that only logs a few details about failed jobs:

defmodule MicroLogger do
  require Logger

  def handle_event([:oban, :job, :exception], %{duration: duration}, meta, nil) do
    Logger.warn("[#{meta.queue}] #{meta.worker} failed in #{duration}")
  end
end

:telemetry.attach("oban-logger", [:oban, :job, :exception], &MicroLogger.handle_event/4, nil)

Another great use of execution data is error reporting. Here is an example of integrating with Honeybadger, but only reporting jobs that have failed 3 times or more:

defmodule ErrorReporter do
  def handle_event([:oban, :job, :exception], _, %{attempt: attempt} = meta, _) do
    if attempt >= 3 do
      context = Map.take(meta, [:id, :args, :queue, :worker])

      Honeybadger.notify(meta.error, context, meta.stack)
    end
  end
end

:telemetry.attach("oban-errors", [:oban, :job, :exception], &ErrorReporter.handle_event/4, [])