The Notifier coordinates listening for and publishing notifications for events in predefined channels.

Every Oban supervision tree contains a notifier process, registered as Oban.Notifier, which must be an implementation of the Oban.Notifier behaviour. The default implementation is uses the LISTEN/NOTIFY operations built into Postgres.

All incoming notifications are relayed through the notifier to other processes.

channels

Channels

Internally, Oban uses a variety of predefined channels with distinct responsibilities:

• insert — as jobs are inserted into the database an event is published on the insert channel. Processes such as queue producers use this as a signal to dispatch new jobs.

• leader — messages regarding node leadership exchanged between peers

• signal — instructions to take action, such as scale a queue or kill a running job, are sent through the signal channel

• gossip — arbitrary communication for coordination between nodes

• stager — messages regarding job staging, e.g. notifying queues that jobs are ready for execution

examples

Examples

Broadcasting after a job is completed:

defmodule MyApp.Worker do
  use Oban.Worker

  @impl Oban.Worker
  def perform(job) do
    :ok = MyApp.do_work(job.args)

    Oban.Notifier.notify(Oban, :my_app_jobs, %{complete: job.id})

    :ok
  end
end

Listening for job complete events from another process:

def insert_and_listen(args) do
  :ok = Oban.Notifier.listen([:my_app_jobs])

  {:ok, %{id: job_id} = job} =
    args
    |> MyApp.Worker.new()
    |> Oban.insert()

  receive do
    {:notification, :my_app_jobs, %{"complete" => ^job_id}} ->
      IO.puts("Other job complete!")
  after
    30_000 ->
      IO.puts("Other job didn't finish in 30 seconds!")
  end
end