Tower is a flexible error tracker for elixir applications.

It listens for errors in an elixir application and informs about them to the configured list of reporters (one or many).

You can either:

• include tower package directly and write your own custom reporter(s)

Or:

• include one (or many) of the following reporters (separate packages) that build on top of and depend on tower:
  • tower_bugsnag
  • tower_email
  • tower_error_tracker
  • tower_honeybadger
  • tower_rollbar
  • tower_sentry
  • tower_slack

Motivation

Decoupled error capturing and error reporting in Elixir.

Say you need to add error tracking to your elixir app:

• You decide what service you will use to send your errors to
• You look for a good elixir library for that service
• You configure it, deploy and start receiving errors there

Normally these libraries have to take care of a few responsibilities:

1. Capturing of errors (specific to language and runtime, i.e. Elixir and BEAM)
   • Automatic capturing via (at least one of):
     • Logger backend
     • Logger handler
     • Error logger handler
     • Telemetry event handler
     • Plugs
   • Manual capturing by providing a few public API functions the programmer to call if needed
2. Transform these errors into some format for the remote service (specific to remote service), e.g.
   • JSON for an HTTP API request
   • Subject and body for an e-mail message
3. Make a remote call (e.g. an HTTP request with the payload) to the remote service (specific to remote service)

Tower, instead, takes care of capturing errors (number 1), giving them a well defined shape (Tower.Event struct) and pass along this event to pre-configured but separate reporters which take care of the error reporting steps (number 2 and 3) depending on which service or remote system they report to.

Consequences of this approach

1. Capture once, report many

You can capture once and report to as many places as you want.

Possibly most will end up with just one reporter. But that doesn't mean you shouldn't be able to easily have many, either temporarily or permanently if you need it.

Maybe you just need to have a backup in case one service goes downs or something unexpected happens.

Maybe you're trying out different providers and you want to report to the two for a while and compare how they work, what features they have and how they display the information for you.

Maybe you're planning to switch, and you want to configure the new one without stopping to report to the old one, at least for a while.

2. Ease of switching services

You can switch from Error Tracking service provider without making any changes to your application error capturing configuration or expect any change or regression with respect with capturing behavior.

You switch the reporter package, but tower still part of your application, and all the configuration specific to tower and error capturing tactics is still valid and unchanged.

3. Response to changes in Elixir and BEAM

Necessary future changes caused by deprecations and/or changes in error handling behavior in the BEAM or Elixir can be just made in Tower without need to change any of the service specific reporters.

Reporters

As explained in the Motivation section, any captured errors by Tower will be passed along to the list of configured reporters, which can be set in

config :tower, :reporters, [...] # Defaults to [Tower.EphemeralReporter]

So, in summary, you can either

• Depend on tower package directly
  • play with the default built-in toy reporter Tower.EphemeralReporter, useful for dev and test
  • at some point for production write your own custom reporter

or

• depend on one (or many) of the following reporters (separate packages) that build on top and depend on tower:
  • TowerBugsnag (tower_bugsnag)
  • TowerEmail (tower_email)
  • TowerErrorTracker (tower_error_tracker)
  • TowerHoneybadger (tower_honeybadger)
  • TowerRollbar (tower_rollbar)
  • TowerSentry (tower_sentry)
  • TowerSlack (tower_slack)
• and properly set the config :tower, :reporters, [...] configuration key

Manual reporting

If either, for whatever reason when using automated exception handling, an exception condition is not reaching Tower handling, or you just need or want to manually handle and report errors, you can manually ask Tower to report exceptions, throws or exits.

try do
  # possibly crashing code
rescue
  exception ->
    Tower.report_exception(exception, __STACKTRACE__)
catch
  :throw, value ->
    Tower.report_throw(value, __STACKTRACE__)
  :exit, reason when not Tower.is_normal_exit(reason) ->
    Tower.report_exit(reason, __STACKTRACE__)
end

or more generally

try do
  # possibly crashing code
catch
  kind, reason ->
    Tower.report(kind, reason, __STACKTRACE__)
end

which will in turn call the appropriate function based on the caught kind and reason values

Writing a custom reporter

# lib/my_app/error_reporter.ex
defmodule MyApp.ErrorReporter do
  @behaviour Tower.Reporter

  @impl true
  def report_event(%Tower.Event{} = event) do
    # do something with event

    # A `Tower.Event` is a struct with the following typespec:
    #
    # %Tower.Event{
    #   id: UUIDv7.t(),
    #   datetime: DateTime.t(),
    #   level: :logger.level(),
    #   kind: :error | :exit | :throw | :message,
    #   reason: Exception.t() | term(),
    #   stacktrace: Exception.stacktrace() | nil,
    #   log_event: :logger.log_event() | nil,
    #   plug_conn: struct() | nil,
    #   metadata: map()
    # }
  end
end

# in some config/*.exs
config :tower, reporters: [MyApp.ErrorReporter]

Configuration

reporters

List of reporters Tower should report events to.

Default: [Tower.EphemeralReporter]

Example:

config :tower, reporters: [TowerEmail]

log_level

Logger messages this level and above will be reported.

Possible values are any of defined Logger levels (https://hexdocs.pm/logger/Logger.html#module-levels) or :none to disable reporting of Logger messages.

Default: :critical

Example:

config :tower, log_level: :error

ignored_exceptions

List of exceptions that Tower should ignore and not report.

Default: []

Example:

config :tower, ignored_exceptions: [DBConnection.ConnectionError]

logger_metadata

List of keys that Tower should pick up from the current process Logger.metadata when reporting events.

Default: []

Example:

A common use case is setting Logger.metadata(user_id: user.id) at the start of your plugs or controller actions and configure Tower:

config :tower, logger_metadata: [:user_id]

so that it's included in the reported exception or message event as extra metadata.

Also if using Phoenix you can

config :tower, logger_metadata: [:request_id]

so that you can co-relate your exceptions reports to the request id in your application logs.

More about Logger metadata:

• https://hexdocs.pm/logger/Logger.html#module-metadata
• https://hexdocs.pm/logger/Logger.html#metadata/1