Main entry point for configuring Joken. This module has two approaches:

Creating a map of Joken.Claim s

If you prefer to avoid using macros, you can create your configuration manually. Joken's configuration is just a map with keys being binaries (the claim name) and the value an instance of Joken.Claim.

Example

%{"exp" => %Joken.Claim{
  generate: fn -> Joken.Config.current_time() + (2 * 60 * 60) end,
  validate: fn val, _claims, _context -> val < Joken.Config.current_time() end
}}

Since this is cumbersome and error prone, you can use this module with a more fluent API, see:

• default_claims/1
• add_claim/4

Automatically load and generate functions (recommended)

Another approach is to just use Joken.Config in a module. This will load a signer configuration (from config.exs) and a map of Joken.Claim s.

Example

defmodule MyAuth do
  use Joken.Config
end

This way, Joken.Config will implement some functions for you:

• generate_claims/1: generates dynamic claims and adds them to the passed map.
• encode_and_sign/2: takes a map of claims, encodes it to JSON and signs it.
• verify/2: check for token tampering using a signer.
• validate/2: takes a claim map and a configuration to run validations.
• generate_and_sign/2: combines generation and signing.
• verify_and_validate/2: combines verification and validation.
• token_config/0: where you customize token generation and validation.

It will also add use Joken.Hooks so you can easily hook into Joken's lifecycle.

Overriding functions

All callbacks in Joken.Config and Joken.Hooks are overridable. This can be used for customizing the token configuration. All that is needed is to override the token_config/0 function returning your map of binary keys to Joken.Claim structs. Example from the benchmark suite:

defmodule MyCustomClaimsAuth do
  use Joken.Config

  @impl true
  def token_config do
    %{} # empty claim map
    |> add_claim("name", fn -> "John Doe" end, &(&1 == "John Doe"))
    |> add_claim("test", fn -> true end, &(&1 == true))
    |> add_claim("age", fn -> 666 end, &(&1 > 18))
    |> add_claim("simple time test", fn -> 1 end, &(Joken.current_time() > &1))
  end
end

Customizing default generated claims

The default claims generation is just a bypass call to default_claims/1. If one would like to customize it, then we need only to override the token_config function:

defmodule MyCustomDefaults do
  use Joken.Config

  def token_config, do: default_claims(default_exp: 60 * 60) # 1 hour
end

Options

You can pass some options to use Joken.Config to ease on your configuration:

• :default_signer: a signer configuration key in config.exs (see Joken.Signer)