Provides runtime information about functions and macros defined by the module, enables docstring extraction, etc.

Each module gets an __info__/1 function when it’s compiled. The function takes one of the following atoms:

• :functions - keyword list of public functions along with their arities

• :macros - keyword list of public macros along with their arities

• :module - module name (Module == Module.__info__(:module))

In addition to the above, you may also pass to __info__/1 any atom supported by Erlang’s module_info function which also gets defined for each compiled module. See http://erlang.org/doc/reference_manual/modules.html#id69430 for more information.

Attaches documentation to a given function or type. It expects the module the function/type belongs to, the line (a non negative integer), the kind (def or defmacro), a tuple representing the function and its arity, the function signature (the signature should be omitted for types) and the documentation, which should be either a binary or a boolean.

Examples

defmodule MyModule do
  Module.add_doc(__MODULE__, __ENV__.line + 1, :def, {:version, 0}, [], "Manually added docs")
  def version, do: 1
end

Concatenates a list of aliases and returns a new alias.

Examples

iex> Module.concat([Foo, Bar])
Foo.Bar

iex> Module.concat([Foo, "Bar"])
Foo.Bar

Concatenates two aliases and returns a new alias.

Examples

iex> Module.concat(Foo, Bar)
Foo.Bar

iex> Module.concat(Foo, "Bar")
Foo.Bar

Creates a module with the given name and defined by the given quoted expressions.

The line where the module is defined and its file must be passed as options.

Examples

contents =
  quote do
    def world, do: true
  end

Module.create(Hello, contents, Macro.Env.location(__ENV__))

Hello.world #=> true

Differences from defmodule

Module.create works similarly to defmodule and return the same results. While one could also use defmodule to define modules dynamically, this function is preferred when the module body is given by a quoted expression.

Another important distinction is that Module.create allows you to control the environment variables used when defining the module, while defmodule automatically shares the same environment.

Checks if the module defines the given function or macro. Use defines?/3 to assert for a specific type.

Examples

defmodule Example do
  Module.defines? __MODULE__, {:version, 0} #=> false
  def version, do: 1
  Module.defines? __MODULE__, {:version, 0} #=> true
end

Checks if the module defines a function or macro of the given kind. kind can be any of :def, :defp, :defmacro or :defmacrop.

Examples

defmodule Example do
  Module.defines? __MODULE__, {:version, 0}, :defp #=> false
  def version, do: 1
  Module.defines? __MODULE__, {:version, 0}, :defp #=> false
end

Return all functions defined in module.

Examples

defmodule Example do
  def version, do: 1
  Module.definitions_in __MODULE__ #=> [{:version,0}]
end

Returns all functions defined in module, according to its kind.

Examples

defmodule Example do
  def version, do: 1
  Module.definitions_in __MODULE__, :def  #=> [{:version,0}]
  Module.definitions_in __MODULE__, :defp #=> []
end

Deletes all attributes that match the given key.

Examples

defmodule MyModule do
  Module.put_attribute __MODULE__, :custom_threshold_for_lib, 10
  Module.delete_attribute __MODULE__, :custom_threshold_for_lib
end

Evaluates the quoted contents in the given module’s context.

A list of environment options can also be given as argument. See Code.eval_string/3 for more information.

Raises an error if the module was already compiled.

Examples

defmodule Foo do
  contents = quote do: (def sum(a, b), do: a + b)
  Module.eval_quoted __MODULE__, contents
end

Foo.sum(1, 2) #=> 3

For convenience, you can my pass __ENV__ as argument and all options will be automatically extracted from the environment:

defmodule Foo do
  contents = quote do: (def sum(a, b), do: a + b)
  Module.eval_quoted __MODULE__, contents, [], __ENV__
end

Foo.sum(1, 2) #=> 3

Gets the given attribute from a module. If the attribute was marked with accumulate with Module.register_attribute/3, a list is always returned.

The @ macro compiles to a call to this function. For example, the following code:

@foo

Expands close to:

Module.get_attribute(__MODULE__, :foo)

Examples

defmodule Foo do
  Module.put_attribute __MODULE__, :value, 1
  Module.get_attribute __MODULE__, :value #=> 1

  Module.register_attribute __MODULE__, :value, accumulate: true
  Module.put_attribute __MODULE__, :value, 1
  Module.get_attribute __MODULE__, :value #=> [1]
end

Makes the given functions in module overridable. An overridable function is lazily defined, allowing a developer to customize it. See Kernel.defoverridable/1 for more information and documentation.

Check if a module is open, i.e. it is currently being defined and its attributes and functions can be modified.

Returns true if tuple in module is marked as overridable.

Puts an Erlang attribute to the given module with the given key and value. The semantics of putting the attribute depends if the attribute was registered or not via register_attribute/3.

Examples

defmodule MyModule do
  Module.put_attribute __MODULE__, :custom_threshold_for_lib, 10
end

Registers an attribute. By registering an attribute, a developer is able to customize how Elixir will store and accumulate the attribute values.

Options

When registering an attribute, two options can be given:

• :accumulate - several calls to the same attribute will accumulate instead of override the previous one. New attributes are always added to the top of the accumulated list.

• :persist - the attribute will be persisted in the Erlang Abstract Format. Useful when interfacing with Erlang libraries.

By default, both options are false.

Examples

defmodule MyModule do
  Module.register_attribute __MODULE__,
    :custom_threshold_for_lib,
    accumulate: true, persist: false

  @custom_threshold_for_lib 10
  @custom_threshold_for_lib 20
  @custom_threshold_for_lib #=> [20, 10]
end

Concatenates a list of aliases and returns a new alias only if the alias was already referenced. If the alias was not referenced yet, fails with ArgumentError. It handles char lists, binaries and atoms.

Examples

iex> Module.safe_concat([Unknown, Module])
** (ArgumentError) argument error

iex> Module.safe_concat([List, Chars])
List.Chars

Concatenates two aliases and returns a new alias only if the alias was already referenced. If the alias was not referenced yet, fails with ArgumentError. It handles char lists, binaries and atoms.

Examples

iex> Module.safe_concat(Unknown, Module)
** (ArgumentError) argument error

iex> Module.safe_concat(List, Chars)
List.Chars

Split the given module name into binary parts.

Examples

Module.split Very.Long.Module.Name.And.Even.Longer
#=> ["Very", "Long", "Module", "Name", "And", "Even", "Longer"]